I_SUPPLIER
Supplier
I_SUPPLIER is a CDS View in S/4HANA. Supplier. It contains 120 fields. 150 CDS views read from this table.
CDS Views using this table (150)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| /VSCEW/I_MRPAreaSubcontractor | view_entity | from | MRP Area Subcontractor | |
| A_SeasonPurchasePeriod | view | left_outer | COMPOSITE | API view for season mm periods |
| A_Supplier | view | from | BASIC | Supplier |
| C_APItemSupplier | view_entity | from | CONSUMPTION | Supplier Data for Supplier Line Items |
| C_AR_StRpVATForm731ItemC | view | left_outer | CONSUMPTION | Argentina VAT Form 731 |
| C_AR_StRpVATForm731ItemLogC | view | left_outer | CONSUMPTION | Argentina VAT Form 731 with Rptd item log data |
| C_BankPaymentBatchItemSupplier | view_entity | from | CONSUMPTION | Bank Payment Batch Item - Supplier Info |
| C_CashFlowItemSupplier | view_entity | from | CONSUMPTION | Supplier of Cash Flow Item |
| C_CL_StRpPurchaseLedgerCube | view_entity | inner | CONSUMPTION | Chile Purchase Ledger - Cube |
| C_CN_TaxInvcSupplier | view | from | CONSUMPTION | China Tax Supplier |
| C_CntrlPurContrSuplrValueHelp | view_entity | from | CONSUMPTION | Cnsmpn Vw for Supplier Val Help in CCTR |
| C_CorrespondenceSupplierVH | view | from | CONSUMPTION | Correspondence Supplier Value Help |
| C_Customersuppliercompanycode | view | union_all | CONSUMPTION | Customer/Supplier/Company Code Information |
| C_CustRetRecmdnDataset | view_entity | inner | CONSUMPTION | Dataset for Input Recommendation for Customer Return |
| C_CustRetRecmdnDataset_2 | view_entity | inner | CONSUMPTION | Customer Return Recommendation Dataset |
| C_DiffntAltvPyeAllwdSuplr | view | from | CONSUMPTION | Supplier with payee in document enabled |
| C_GRC_SupplierChangeLog | view | inner | CONSUMPTION | Supplier change log |
| C_HU_ECSlsLstMatlDocCsgnmtC | view_entity | inner | CONSUMPTION | Hungarian ECSL Consignment - Cube |
| C_InspLotSuplrValHelp | view_entity | from | CONSUMPTION | Supplier Value Help |
| C_JITOutbSupplierVH | view | from | CONSUMPTION | Value Help for Supplier |
| C_JournalEntrySupplierCard | view | from | CONSUMPTION | Journal Entry Supplier Contact Card |
| C_LCMSupplierValueHelp | view | from | CONSUMPTION | Supplier Value Help |
| C_MassUpdtSupplierVH | view | from | CONSUMPTION | Supplier Value Help |
| C_MM_SupplierValueHelp | view | from | CONSUMPTION | Supplier |
| C_MstrProjSuplrCntctCard | view | from | CONSUMPTION | Master Project Supplier Contact Card |
| C_NoCompanyCodeSupplier | view | from | CONSUMPTION | No Company Code Assignment Supplier |
| C_PaymentRequestSupplierVH | view_entity | from | CONSUMPTION | Supplier Value Help for Payment Request |
| C_PE_StRpPurLdgrDmstcSuplrC | view | inner | CONSUMPTION | Purchase Ledger Domestic - Cube |
| C_ProcmtHubSuplrDeliveryAddrVH | view | from | CONSUMPTION | Supplier Delivery Addr Value Help from Connected System |
| C_PurchaseOrderWorkflowEmail | view | left_outer | CONSUMPTION | Purchase Order Details for Workflow Deadline Email |
| C_PurDocListInvoiceDetails | view | left_outer | CONSUMPTION | Invoice Details |
| C_PurgInfoRecdMassUpdtSuplrVH | view | from | CONSUMPTION | Supplier Value Help |
| C_PurgInfoRecordSupplierVH | view | from | CONSUMPTION | Supplier Value Help |
| C_PurOrdMaintainCtrItemValHelp | view | left_outer | CONSUMPTION | Contract Item Value Help |
| C_PurOrdMaintainOutlAIValHelp | view | left_outer | CONSUMPTION | PO Maintenance: Value Help for Outline Agreement Items |
| C_PurOrdMaintainSuplrValHelp | view | from | CONSUMPTION | PO Maintenance: Value Help for Supplier |
| C_RO_StRpDomesticSlsPurListC | view | left_outer | CONSUMPTION | Romania Domestic Sales and Purchase List - Cube |
| C_RO_StRpTaxItemWithEUTaxClfnC | view | left_outer | CONSUMPTION | EU Sales Tax Item View for RO |
| C_SuplrActySuplrValueHelp | view | left_outer | CONSUMPTION | Suppliers Affected by Activity |
| C_SuplrAltvPayeeVHTemp | view | from | CONSUMPTION | Supplier Alternative Payee |
| C_SupplierByPurchasingCat | view | from | CONSUMPTION | Supplier |
| C_SupplierDetails | view | from | CONSUMPTION | Consumption view for Supplier Details |
| C_SupplierFs | view | from | CONSUMPTION | Supplier |
| C_SupplierList | view_entity | from | CONSUMPTION | Display Supplier List |
| C_SupplierListSupplierVH | view | from | CONSUMPTION | Supplier on Supplier List |
| C_SupplierReturnToAddressVH | view | from | CONSUMPTION | Supplier Return-To Address |
| C_SupplierValHelp | view | from | CONSUMPTION | Supplier Value Help |
| C_SupplierValueHelp | view | from | CONSUMPTION | Supplier Value Help |
| C_SupplierVATRegistration | view_entity | from | CONSUMPTION | Supplier without VAT Registration |
| C_WrntySupplierValueHelp | view_entity | from | CONSUMPTION | Value Help for Warranty Supplier |
| ESH_N_SUPPLIERS_M | view | from | Anchor view -SUPPLIERS_M | |
| FAC_DART_Z3_S_BP_ADDRESS | view | from | Business Partner Address for Supplier | |
| FAC_DART_Z3_VENDOR | view | left_outer | Vendor Master Data | |
| FAC_SUPPLIERVH | view | from | Value help for supplier | |
| FARMLVD_APAR_ACCDOC | view_entity | left_outer | Cleared Receivable Item Information | |
| I_AR_StRpTaxItem | view | left_outer | COMPOSITE | Argentina VAT Tax Line Item Calculation |
| I_ARunSupSelRulePurOrdSuplrVH | view | from | BASIC | Supply Selection Rule Purchase Order Supplier |
| I_AU_StRpTPARInvoiceLineItems | view | inner | COMPOSITE | Australia TPAR Invoice Line Items |
| I_BalanceAuditTrail | view | left_outer | COMPOSITE | Line Items for Balance Audit Trail |
| I_BPAdditionalSupplierTP | view | from | TRANSACTIONAL | BO view for Additional Supplier of BP |
| I_BPAddlSuplrEmailAddressTP | view | inner | TRANSACTIONAL | BO view for email for MLTAS suppliers |
| I_BPAddlSuplrFaxNumberTP | view | inner | TRANSACTIONAL | BO view for fax num for MLTAS suppliers |
| I_BPAddlSuplrMblPhNumberTP | view | inner | TRANSACTIONAL | BO view for Mobile nos of MLTAS Suppliers |
| I_BPAddlSuplrTelNmbrTP | view | inner | TRANSACTIONAL | BO view for Tel nos of MLTAS Suppliers |
| I_BPAddlSuplrWebsiteURLTP | view | inner | TRANSACTIONAL | BO view for Website URL of MLTAS Suppliers |
| I_BPSupplierGov | view_entity | union_all | COMPOSITE | BP Supplier Data Governance |
| I_BPSupplierGovernanceVH | view_entity | from | BASIC | BP Supplier Governance |
| I_BR_NFPartner_VendCust | view | from | COMPOSITE | Brazil Nota Fiscal Customer and Supplier |
| I_BusinessPartnerSupplier | view | from | BASIC | Business Partner Supplier |
| I_BusinessPartnerSupplierDEX | view_entity | from | BASIC | Data Extraction for BP Supplier |
| I_CacheSupplierVH | view_entity | from | COMPOSITE | Cache Suppliers without a Master Key |
| I_CnsldtnMasterData | view | union_all | COMPOSITE | Consolidation - Combined Master Data |
| I_CO_BPRelationshipRole | view_entity | inner | COMPOSITE | Provides Business Partners Roles |
| I_ElectronicDocCockpitSuplrEml | view | from | COMPOSITE | Electronic Document: Supplier and Email |
| I_EmlTmplCustSuplrCompanyCode | view | union_all | COMPOSITE | Email Template Data Provider |
| I_EngagementProjectSupplier | view_entity | from | COMPOSITE | Basic Details of Supplier |
| I_FldLogsSuplrItmSuplrVH | view | from | COMPOSITE | Value Help for Supplier |
| I_IN_StRpGSTRet | view | left_outer | COMPOSITE | Tax Item Details for GST Returns |
| I_IN_SubcontractorStdVH | view | from | COMPOSITE | Value Help for Subcontractor |
| I_KnbnCtrlCycSuplrBizPurpose | view_entity | inner | BASIC | Biz Purpose for Control Cycle Supplier |
| I_LU_SAFTGenLedgerDocumentBP | view_entity | inner | COMPOSITE | Business Partner Document for SAFT LU |
| I_MaterialSampleDetails | view | left_outer | COMPOSITE | CDS View for Material Sample Details |
| I_MX_BPRelationshipRole | view_entity | inner | COMPOSITE | Provides Business Partners Roles |
| I_NO_SAFTSupplierMasterData | view_entity | inner | COMPOSITE | Master data of suppliers for SAFT |
| I_NO_SAFTSuppliersInPeriod | view_entity | inner | COMPOSITE | List of all customers in report period |
| I_PartnerCompanySupplierAuthzn | view_entity | from | BASIC | Supplier Authorization in Company |
| I_PaytReceiptSupplierVH | view | inner | COMPOSITE | Payment Receipt Supplier |
| I_PH_SuplrCustJournalCube | view | left_outer | COMPOSITE | PH CAS Supplier Customer Journal Cube |
| I_PurchasingCategorySupplier | view | inner | COMPOSITE | Purchasing Category Supplier |
| I_ReceivablesFinancingFunder | view_entity | from | COMPOSITE | Receivables Financing Funder |
| I_SAFTGeneralLedgerSupplier | view | inner | COMPOSITE | SAF-T Gen Ledger Supplier |
| I_SrlNumberHistoryStockOwnerVH | view_entity | from | COMPOSITE | Owner of Stock |
| I_SrlNumberHistorySupplierVH | view_entity | from | COMPOSITE | Supplier |
| I_Ssp_Suppliervh | view | from | COMPOSITE | Basic view for supplier |
| I_SuplrInvcEmailParameter | view_entity | inner | TRANSACTIONAL | Parameters for Supplier Invoice Email Template |
| I_Supplier_VH | view | from | BASIC | Supplier |
| I_SupplierActivitySuplrParty | view | left_outer | COMPOSITE | Supplier Activity Supplier Party |
| I_SupplierActivityTaskSupplier | view | left_outer | COMPOSITE | Supplier Activity Task Supplier |
| I_SupplierChangeLog | view | inner | COMPOSITE | Supplier Change Log |
| I_SupplierEvalRespSuplrParty | view | inner | COMPOSITE | Supplier Evaluation Response Supplier Party |
| P_APLineItem_5 | view | from | BASIC | Created from DDL source P_APLineItem_5 |
| P_APLineItemMixedAccount | view | inner | BASIC | Supplier Accounts belonging to mixed accounts |
| P_AR_BPRelationshipRole | view_entity | inner | COMPOSITE | Argentina BP Relationship Role |
| P_AR_PurchaseImportDispSuplr | view | inner | CONSUMPTION | Argentina Purchase Documents with Import Dispatch Supplier |
| P_AR_PurchaseTaxItem | view | inner | CONSUMPTION | Argentina Purchase Tax Item |
| P_AR_PurchaseVATRateDetail2 | view | inner | CONSUMPTION | Argentina Purchase - VAT Rate Details |
| P_AR_PurchaseVATRateSupplier | view | inner | CONSUMPTION | Argentina Purchase VAT Rate - Supplier |
| P_AR_SupplierPayable | view | inner | CONSUMPTION | Argentina Supplier Payable |
| P_AR_SupplierPaymentBPDetail | view_entity | inner | CONSUMPTION | Argentina Supplier Payment with Business Partner Detail |
| P_AR_VATPrintPurchaseDetail | view | inner | CONSUMPTION | Argentina VAT Print Purchase Detail |
| P_Arbsitmopenitem | view_entity | left_outer | COMPOSITE | Open Receivable Items |
| P_AU_StRpTPARCrrtnPhseSuplrDet | view | inner | COMPOSITE | AU TPAR Correction Phase Supplier Detail |
| P_AU_StRpTPARSupplierDetails | view | inner | COMPOSITE | AU TPAR Supplier Details |
| P_BG_SAFTSupplier | view_entity | inner | CONSUMPTION | Supplier Data for BG SAFT |
| P_BPPartnerFunctionNumber | view | union | COMPOSITE | Union view of various partner types |
| P_CN_CADESupplier | view | inner | CONSUMPTION | CADE Supplier |
| P_CnsldtnSupplier | view | from | COMPOSITE | Consolidation Combined Supplier |
| P_CnsldtnSupplierT | view | from | COMPOSITE | Consolidation Combined Supplier Text |
| P_CO_DIANMinXrefSupplier | view | from | CONSUMPTION | All Formats - Supplier XREF |
| P_CustomerSupplierSH | view_entity | union_all | COMPOSITE | Search Help View for Customers and Suppliers for Country |
| P_DRFEWMSupplier | view | from | BASIC | DRF EWM integration of supplier |
| P_EG_StRpTaxItem | view | left_outer | COMPOSITE | Tax Item view for Egypt Statutory Reporting |
| P_Fiarcn_Bp_Suplr | view | from | CONSUMPTION | Supplier and Business Partner |
| P_IN_SuplrGSTHlthChk | view_entity | inner | COMPOSITE | Supplier GST India Health Check |
| P_IsSupplierEUMember | view_entity | from | CONSUMPTION | Is Supplier European Union Member |
| P_LU_SAFTJournalItemBP | view | inner | COMPOSITE | SAFT LU Journal Item Business Partner |
| P_MY_TxItmWithSlsDeductionAmt | view | left_outer | COMPOSITE | Tax Item with Sales Deduction Amount |
| P_NO_SAFTJournalCustSup | view | inner | COMPOSITE | SAF-T Norway Customers and Suppliers |
| P_OffsettingAccount | view_entity | from | COMPOSITE | Private union view for OffsettingAccount |
| P_OffsettingAccountVH | view_entity | union_all | COMPOSITE | Private view for Offsetting Account Value Help |
| P_Ph_StRpTaxItemQ | view | left_outer | COMPOSITE | Tax Item Statutory Reporting for PH |
| P_ProdAllocPlngBusPartners | view | union | COMPOSITE | Product Allocation Planning Business Partners |
| P_PT_SAFTTAXLANDSUP | view | inner | COMPOSITE | SAFT PT Tax Land for Suppliers |
| P_PurOrdMaintainHeaderActAddr | view | left_outer | CONSUMPTION | PO Maintenance: Address of Purchase Order Header |
| P_PurOrdMaintainSupplierAddr | view | from | CONSUMPTION | PO Maintenance: Address of Supplier |
| P_RO_SAFTSupplier | view | inner | CONSUMPTION | Supplier Data for RO SAFT |
| P_RU_SupplierData1 | view | from | COMPOSITE | RU Supplier Data - 1 |
| P_StRpTaxItmWithEUTaxClass7 | view | left_outer | COMPOSITE | EU Sales tax Item View for Statutory Reporting |
| P_SupplierAsCustomer | view | from | COMPOSITE | All suppliers in customer role |
| P_SupplierBusinessPartner | view | from | CONSUMPTION | Supplier Business Partner |
| P_SupplierWithCompanyCode | view | from | COMPOSITE | Supplier extended by Company Code |
| P_TH_SUPPLIER_ADDR_D | view_entity | right_outer | COMPOSITE | Supplier's Default Address for TH VAT Report |
| P_TH_SUPPLIER_ADDR_T | view_entity | right_outer | COMPOSITE | Supplier's Thailand Address for TH VAT Report |
| P_TotalNumberOfSuppliers | view | from | CONSUMPTION | Available Suppliers |
| P_TW_TaxItem | view | left_outer | COMPOSITE | Tax Item Information for TaiWan |
| P_WLF_CDS_LFA1_BG | view | from | BASIC | Help View: provides field BEGRU |
| R_SuplrListBusPartnerDetails | view | from | BASIC | Business Partner Details for Suplr List |
| SDM_GLO_RO_ROFI_BPTY_BPNUM | view_entity | inner | SDM View for ROFI_BPTY - Romania | |
| SHSM_M_CMLF | view | left_outer | Claims Relating to a Vendor | |
| SHSM_SHP_VIEW_ROGR | view | inner | CDS-based Value Help Selection Method SHP_VIEW_ROGR |
Fields (120)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | AddressID | AddressID | 12 |
| KEY | Supplier | ARunSupplySelRuleAttribVal,BR_NFPartner,Subcontractor,Supplier,SupplierForEdit,vendor_account | 48 |
| _AddressRepresentation | _AddressRepresentation | 1 | |
| _CorrespondingCustomer | _CorrespondingCustomer | 2 | |
| _Industry | _Industry | 2 | |
| _ProcurementBlock | _ProcurementBlock | 2 | |
| _QualityManagementSystem | _QualityManagementSystem | 2 | |
| _StandardAddress | _StandardAddress | 2 | |
| _SupplierAccountGroup | _SupplierAccountGroup | 2 | |
| _SupplierAccountGroupText | _SupplierAccountGroupText | 2 | |
| _SupplierBankDetails | _SupplierBankDetails | 3 | |
| _SupplierCompany | _SupplierCompany | 3 | |
| _SupplierIndustryText | _SupplierIndustryText | 2 | |
| _SupplierPurchasingOrg | _SupplierPurchasingOrg | 2 | |
| _SupplierToBusinessPartner | _SupplierToBusinessPartner | 2 | |
| AccountIsBlockedForPosting | AccountIsBlockedForPosting | 4 | |
| AlternativePayeeAccountNumber | AlternativePayeeAccountNumber,SupplierAlternativePayee | 6 | |
| AlternativePayeeIsAllowed | AlternativePayeeIsAllowed | 3 | |
| AuthorizationGroup | AuthorizationGroup,BEGRU,SupplierBasicAuthorizationGrp,vendor_begru | 45 | |
| BirthDate | BirthDate | 2 | |
| BPAddrCityName | BPAddrCityName,CityName | 6 | |
| BPAddrStreetName | BPAddrStreetName,StreetName | 3 | |
| BPIsEqualizationTaxSubject | BPIsEqualizationTaxSubject | 2 | |
| BPSupplierFullName | BPSupplierFullName,BusinessPartnerFullName,FullName | 6 | |
| BPSupplierName | BPSupplierName | 14 | |
| BR_TaxIsSplit | BR_TaxIsSplit | 3 | |
| BRSpcfcTaxBasePercentageCode | BRSpcfcTaxBasePercentageCode | 2 | |
| BusinessPartner | BusinessPartner | 1 | |
| BusinessPartnerName1 | BusinessPartnerName1,SupplierName | 8 | |
| BusinessPartnerName2 | BusinessPartnerName2 | 5 | |
| BusinessPartnerName3 | BusinessPartnerName3 | 1 | |
| BusinessPartnerName4 | BusinessPartnerName4 | 1 | |
| BusinessPartnerPanNumber | BusinessPartnerPanNumber | 2 | |
| BusinessPartnerUUID | BusinessPartnerUUID | 1 | |
| BusinessType | BusinessType | 1 | |
| CityName | CityName | 8 | |
| ConcatenatedInternationalLocNo | ConcatenatedInternationalLocNo | 2 | |
| Country | Country,SupplierCountry | 12 | |
| CreatedByUser | CreatedByUser | 9 | |
| CreationDate | CreationDate | 9 | |
| Customer | Customer,Debtor | 8 | |
| DataController1 | DataController1 | 30 | |
| DataController10 | DataController10 | 30 | |
| DataController2 | DataController2 | 30 | |
| DataController3 | DataController3 | 30 | |
| DataController4 | DataController4 | 30 | |
| DataController5 | DataController5 | 30 | |
| DataController6 | DataController6 | 30 | |
| DataController7 | DataController7 | 30 | |
| DataController8 | DataController8 | 30 | |
| DataController9 | DataController9 | 30 | |
| DataControllerSet | DataControllerSet | 31 | |
| DataExchangeInstructionKey | DataExchangeInstructionKey | 2 | |
| DataMediumExchangeIndicator | DataMediumExchangeIndicator | 2 | |
| DeletionIndicator | DeletionIndicator | 6 | |
| FactoryCalendar | FactoryCalendar | 2 | |
| FaxNumber | FaxNumber | 3 | |
| FiscalAddress | FiscalAddress | 4 | |
| FormOfAddress | FormOfAddress,TitleSupplier | 4 | |
| GLAccount | GLAccount | 1 | |
| IN_GSTSupplierClassification | IN_GSTSupplierClassification | 2 | |
| Industry | Industry | 5 | |
| IndustryType | IndustryType | 1 | |
| InternationalLocationNumber1 | InternationalLocationNumber1 | 6 | |
| InternationalLocationNumber2 | InternationalLocationNumber2 | 6 | |
| InternationalLocationNumber3 | InternationalLocationNumber3 | 6 | |
| IsBusinessPurposeCompleted | IsBusinessPurposeCompleted | 21 | |
| IsNaturalPerson | IsNaturalPerson | 2 | |
| IsOneTimeAccount | IsOneTimeAccount | 19 | |
| IsToBeAcceptedAtOrigin | IsToBeAcceptedAtOrigin | 2 | |
| OrganizationBPName1 | OrganizationBPName1,SupplierName | 9 | |
| OrganizationBPName2 | OrganizationBPName2 | 7 | |
| PaymentIsBlockedForSupplier | PaymentIsBlockedForSupplier | 4 | |
| PaymentReason | PaymentReason | 2 | |
| PaytSlipWthRefSubscriber | PaytSlipWthRefSubscriber | 2 | |
| PhoneNumber1 | PhoneNumber,PhoneNumber1 | 7 | |
| PhoneNumber2 | PhoneNumber2 | 2 | |
| PostalCode | PostalCode | 8 | |
| PostingIsBlocked | AccountIsBlockedForPosting,PostingIsBlocked | 10 | |
| PurchasingIsBlocked | PurchasingIsBlocked | 9 | |
| ReferenceAccountGroup | ReferenceAccountGroup | 4 | |
| Region | Region | 3 | |
| ResponsibleType | ResponsibleType | 5 | |
| SortField | SearchTerm,SortField,SupplierName,SupplierSearchText | 7 | |
| StreetName | StreetName | 4 | |
| SuplrProofOfDelivRlvtCode | SuplrProofOfDelivRlvtCode | 2 | |
| SuplrQltyInProcmtCertfnValidTo | SuplrQltyInProcmtCertfnValidTo | 4 | |
| SuplrQualityManagementSystem | SuplrQualityManagementSystem | 4 | |
| SuplrTaxAuthorityAccountNumber | SuplrTaxAuthorityAccountNumber | 1 | |
| SupplierAccountGroup | ReferenceAccountGroup,SupplierAccountGroup | 33 | |
| SupplierCentralDeletionIsBlock | SupplierCentralDeletionIsBlock | 2 | |
| SupplierCorporateGroup | SupplierCorporateGroup | 7 | |
| SupplierFullName | FullName,SupplierFullName | 7 | |
| SupplierIsPlantRelevant | SupplierIsPlantRelevant | 2 | |
| SupplierIsSubRangeRelevant | SupplierIsSubRangeRelevant | 2 | |
| SupplierLanguage | SupplierLanguage | 2 | |
| SupplierName | ARunSupplySelRuleAttribValDesc,Name,supplier_name,SupplierName | 31 | |
| SupplierPlant | SupplierPlant | 2 | |
| SupplierProcurementBlock | SupplierProcurementBlock | 4 | |
| TaxInvoiceRepresentativeName | TaxInvoiceRepresentativeName | 1 | |
| TaxJurisdiction | TaxJurisdiction | 5 | |
| TaxNumber1 | SupplierTaxID1,TaxNumber1 | 11 | |
| TaxNumber2 | SupplierTaxID2,TaxNumber2 | 9 | |
| TaxNumber3 | SupplierTaxID3,TaxNumber3 | 4 | |
| TaxNumber4 | SupplierTaxID4,TaxNumber4 | 4 | |
| TaxNumber5 | SupplierTaxID5,TaxNumber5 | 4 | |
| TaxNumberResponsible | TaxNumberResponsible | 6 | |
| TaxNumberType | TaxNumberType | 6 | |
| TradingPartner | PartnerCompany,TradingPartner | 3 | |
| TrainStationName | TrainStationName | 2 | |
| TranspServiceAgentStstcGrp | TranspServiceAgentStstcGrp | 2 | |
| UK_CompanyRegistrationNumber | UK_CompanyRegistrationNumber | 2 | |
| UK_ContractorBusinessType | UK_ContractorBusinessType | 2 | |
| UK_PartnerTaxReference | UK_PartnerTaxReference | 2 | |
| UK_PartnerTradingName | UK_PartnerTradingName | 2 | |
| UK_VerificationNumber | UK_VerificationNumber | 2 | |
| UK_VerificationStatus | UK_VerificationStatus | 2 | |
| UK_VerifiedTaxStatus | UK_VerifiedTaxStatus | 2 | |
| VATLiability | VATLiability | 4 | |
| VATRegistration | VATRegistration | 7 |
@AbapCatalog.sqlViewName: 'I_SUPPLIER_CDS'
@AbapCatalog.preserveKey:true
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.personalData.blockingIndicator: 'IsBusinessPurposeCompleted'
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: ['_AddressDefaultRepresentation','_AddressRepresentation']
@Analytics: {
dataCategory: #DIMENSION,
dataExtraction: {
enabled: true,
delta.changeDataCapture: {
mapping:[
{
table: 'LFA1', role: #MAIN,
viewElement: ['Supplier'],
tableElement: ['lifnr']
},
{
table: 'ADRC', role: #LEFT_OUTER_TO_ONE_JOIN,
viewElement: ['AddressID'],
tableElement: ['Addrnumber']
} ]
}
}
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Supplier'
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE,
#CDS_MODELING_DATA_SOURCE,
#CDS_MODELING_ASSOCIATION_TARGET,
#ANALYTICAL_DIMENSION,
#EXTRACTION_DATA_SOURCE]
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.representativeKey: 'Supplier'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MASTER
@VDM.viewType: #BASIC
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
@ObjectModel.sapObjectNodeType.name: 'Supplier'
define view I_Supplier
as select from lfa1
//private associations
association [1..1] to I_SupplierToBusinessPartner as _SupplierToBusinessPartner on $projection.Supplier = _SupplierToBusinessPartner.Supplier
association [0..1] to bp1020 as _FiscalData on lfa1.lifnr = _FiscalData.partnr // technically wrong for lifnr<>but000.partner, but usage of $projection.BusinessPartner is not allowed. H
//public composition associations
association [0..*] to I_SupplierCompany as _SupplierCompany on $projection.Supplier = _SupplierCompany.Supplier
association [0..*] to I_SupplierPurchasingOrg as _SupplierPurchasingOrg on $projection.Supplier = _SupplierPurchasingOrg.Supplier
association [0..*] to I_SupplierBankDetails as _SupplierBankDetails on $projection.Supplier = _SupplierBankDetails.Supplier
//public value helps
association [0..1] to I_SupplierAccountGroup as _SupplierAccountGroup on $projection.SupplierAccountGroup = _SupplierAccountGroup.SupplierAccountGroup
association [0..*] to I_Industries as _Industry on $projection.Industry = _Industry.IndustrySector
//public foreign key associations
association [0..1] to I_Customer as _CorrespondingCustomer on $projection.Customer = _CorrespondingCustomer.Customer
////public texts
association [0..*] to I_SupplierAccountGroupText as _SupplierAccountGroupText on $projection.SupplierAccountGroup = _SupplierAccountGroupText.SupplierAccountGroup
association [0..*] to I_SupplierIndustryText as _SupplierIndustryText on $projection.Industry = _SupplierIndustryText.SupplierIndustry
////public foreign key associations
//quality management
association [0..1] to I_ProcurementBlock as _ProcurementBlock on $projection.SupplierProcurementBlock = _ProcurementBlock.ProcurementBlock
association [0..1] to I_QualityManagementSystem as _QualityManagementSystem on $projection.SuplrQualityManagementSystem = _QualityManagementSystem.QualityManagementSystem
association [1..1] to I_Address as _StandardAddress on $projection.AddressID = _StandardAddress.AddressID
// association [1..1] to I_BusinessPartnerAddress as _BusinessPartnerAddress on $projection.BusinessPartner = _BusinessPartnerAddress.BusinessPartner
// and $projection.AddressID = _BusinessPartnerAddress.AddressNumber
association [0..1] to E_Supplier as _SupplierExt on $projection.Supplier = _SupplierExt.Supplier
// association added for I_ADDRESS_2 adoption
association [0..1] to I_OrganizationAddress as _AddressDefaultRepresentation on $projection.AddressID = _AddressDefaultRepresentation.AddressID
and _AddressDefaultRepresentation.AddressRepresentationCode is initial
association [0..1] to I_Address_2 as _AddressRepresentation on $projection.AddressID = _AddressRepresentation.AddressID
and _AddressRepresentation.AddressRepresentationCode is initial
and _AddressRepresentation.AddressPersonID is initial
//Adoption from I_Address_2
association [0..*] to I_AddressEmailAddress_2 as _EmailAddress on _EmailAddress.AddressID = $projection.AddressID
and _EmailAddress.AddressPersonID is initial
association [0..1] to I_AddrCurDefaultEmailAddress as _CurrentDfltEmailAddress on _CurrentDfltEmailAddress.AddressID = $projection.AddressID
and _CurrentDfltEmailAddress.AddressPersonID is initial
association [0..*] to I_AddressPhoneNumber_2 as _PhoneNumber on _PhoneNumber.AddressID = $projection.AddressID
and _PhoneNumber.AddressPersonID is initial
association [0..1] to I_AddrCurDfltLandlinePhoneNmbr as _CurrentDfltLandlinePhoneNmbr on _CurrentDfltLandlinePhoneNmbr.AddressID = $projection.AddressID
and _CurrentDfltLandlinePhoneNmbr.AddressPersonID is initial
association [0..1] to I_AddrCurDfltMobilePhoneNumber as _CurrentDfltMobilePhoneNumber on _CurrentDfltMobilePhoneNumber.AddressID = $projection.AddressID
and _CurrentDfltMobilePhoneNumber.AddressPersonID is initial
association [0..*] to I_AddressFaxNumber_2 as _FaxNumber on _FaxNumber.AddressID = $projection.AddressID
and _FaxNumber.AddressPersonID is initial
association [0..1] to I_AddrCurDefaultFaxNumber as _CurrentDfltFaxNumber on _CurrentDfltFaxNumber.AddressID = $projection.AddressID
and _CurrentDfltFaxNumber.AddressPersonID is initial
association [0..*] to I_AddressURI as _UniformResourceIdentifier on _UniformResourceIdentifier.AddressID = $projection.AddressID
and _UniformResourceIdentifier.AddressPersonID is initial
association [0..1] to I_AddressMainWebsiteURL as _MainWebsiteURL on _MainWebsiteURL.AddressID = $projection.AddressID
and _MainWebsiteURL.AddressPersonID is initial
{
@ObjectModel.text.element: ['SupplierName']
@Consumption.labelElement: 'SupplierName'
key cast(lfa1.lifnr as lifnr preserving type) as Supplier,
// _SupplierToBusinessPartner._BusinessPartner.BusinessPartner as BusinessPartner,
@EndUserText.label: 'Account Group'
ktokk as SupplierAccountGroup,
@Semantics.text: true
cast(substring(rtrim(replace(concat(name1, concat(' &@', name2)), '&@', ''),' '),1,80) as md_supplier_name) as SupplierName,
cast(concat( concat( concat( concat( concat( concat_with_space( anred, name1, 1 ), name2 ), name3 ), name4 ), '/' ),
concat_with_space( pstlz, ort01 , 1 ) ) as md_supplier_full_name) as SupplierFullName,
// // For increase in field length
//@Semantics.text: true
@EndUserText.label: 'Business Partner - Supplier Name'
cast(substring(rtrim(replace(concat(_AddressDefaultRepresentation.AddresseeName1, concat(' &@', _AddressDefaultRepresentation.AddresseeName2)), '&@', ''),' '),1,81) as suppliername_2) as BPSupplierName,
@EndUserText.label: 'Business Partner - Supplier Full Name'
cast(concat( concat_with_space( concat_with_space( concat_with_space(_AddressDefaultRepresentation.AddresseeName1, _AddressDefaultRepresentation.AddresseeName2,1 ), _AddressDefaultRepresentation.AddresseeName3,1 ), _AddressDefaultRepresentation.AddresseeName4,1 ), ' ' ) as supplierfullname_2) as BPSupplierFullName,
// _AddressRepresentation.OrganizationName1 as BusinessPartnerName1,
// _AddressRepresentation.OrganizationName2 as BusinessPartnerName2,
// _AddressRepresentation.OrganizationName3 as BusinessPartnerName3,
// _AddressRepresentation.OrganizationName4 as BusinessPartnerName4,
//Adoption of Name and Address fields
@EndUserText.label: 'Business Partner Organization - Name 1'
_AddressDefaultRepresentation.AddresseeName1 as BusinessPartnerName1,
@EndUserText.label: 'Business Partner Organization - Name 2'
_AddressDefaultRepresentation.AddresseeName2 as BusinessPartnerName2,
@EndUserText.label: 'Business Partner Organization - Name 3'
_AddressDefaultRepresentation.AddresseeName3 as BusinessPartnerName3,
@EndUserText.label: 'Business Partner Organization - Name 4'
_AddressDefaultRepresentation.AddresseeName4 as BusinessPartnerName4,
@EndUserText.label: 'Business Partner Address – City'
_AddressDefaultRepresentation.CityName as BPAddrCityName,
@EndUserText.label: 'Business Partner Address – Street'
_AddressDefaultRepresentation.StreetName as BPAddrStreetName,
@EndUserText.label: 'Business Partner Address - Search Term 1'
_AddressDefaultRepresentation.AddressSearchTerm1 as AddressSearchTerm1,
@EndUserText.label: 'Business Partner Address - Search Term 2'
_AddressDefaultRepresentation.AddressSearchTerm2 as AddressSearchTerm2,
@EndUserText.label: 'Business Partner Address – District'
_AddressDefaultRepresentation.DistrictName as DistrictName,
@EndUserText.label: 'Business Partner Address - PO Box Deviating City'
_AddressDefaultRepresentation.POBoxDeviatingCityName as POBoxDeviatingCityName,
@EndUserText.label: 'Business Partner - Form of Address'
_AddressDefaultRepresentation.FormOfAddress as BusinessPartnerFormOfAddress,
lfa1.cvp_xblck as IsBusinessPurposeCompleted,
@EndUserText.label: 'Created By'
ernam as CreatedByUser,
erdat as CreationDate,
xcpdk as IsOneTimeAccount,
begru as AuthorizationGroup,
stceg as VATRegistration,
@EndUserText.label: 'Posting Block(Deprecated)'
@API.element.releaseState: #DEPRECATED
@API.element.successor: 'PostingIsBlocked'
sperr as AccountIsBlockedForPosting,
txjcd as TaxJurisdiction,
scacd as SupplierStandardCarrierAccess,
sfrgr as SupplierFwdAgentFreightGroup,
dlgrp as SupplierAgentProcedureGroup,
regss as SupplIsSocialInsuranceRegtrd,
actss as SocialInsuranceActivityCode,
@EndUserText.label: 'Group Key'
konzs as SupplierCorporateGroup, //to be used
kunnr as Customer,
brsch as Industry, // siehe Anmerkung
stcd1 as TaxNumber1, // tax number 1&2: siehe Anmerkung
stcd2 as TaxNumber2,
stcd3 as TaxNumber3,
stcd4 as TaxNumber4,
stcd5 as TaxNumber5,
stcd6 as TaxNumber6,
sperr as PostingIsBlocked,
@EndUserText.label: 'Purch. Block'
sperm as PurchasingIsBlocked,
@EndUserText.quickInfo: 'International Location Number (Part 1)'
bbbnr as InternationalLocationNumber1,
@EndUserText.quickInfo: 'International Location Number (Part 2)'
bbsnr as InternationalLocationNumber2,
@EndUserText.label: 'Check Digit'
bubkz as InternationalLocationNumber3,
adrnr as AddressID,
lfa1.regio as Region,
lfa1.name1 as OrganizationBPName1,
lfa1.name2 as OrganizationBPName2,
lfa1.ort01 as CityName,
lfa1.pstlz as PostalCode,
lfa1.stras as StreetName,
lfa1.land1 as Country,
cast((concat(concat(bbbnr,concat(' & ', bbsnr)),concat(' & ',bubkz))) as md_international_loc ) as ConcatenatedInternationalLocNo,
//quality management
sperq as SupplierProcurementBlock,
qssys as SuplrQualityManagementSystem,
qssysdat as SuplrQltyInProcmtCertfnValidTo,
//globalization
lfa1.spras as SupplierLanguage,
lfa1.lnrza as AlternativePayeeAccountNumber,
lfa1.telf1 as PhoneNumber1,
lfa1.telfx as FaxNumber,
lfa1.stkzn as IsNaturalPerson,
lfa1.stenr as TaxNumberResponsible,
lfa1.categ as UK_ContractorBusinessType,
lfa1.partner_name as UK_PartnerTradingName,
lfa1.partner_utr as UK_PartnerTaxReference,
lfa1.status as UK_VerificationStatus,
lfa1.vfnum as UK_VerificationNumber,
lfa1.crn as UK_CompanyRegistrationNumber,
lfa1.vfnid as UK_VerifiedTaxStatus,
lfa1.anred as FormOfAddress,
lfa1.ktock as ReferenceAccountGroup,
lfa1.stkzu as VATLiability,
//GS
@EndUserText.label: 'Tax Type'
lfa1.fityp as ResponsibleType,
@EndUserText.label: 'Tax Number Type'
lfa1.stcdt as TaxNumberType,
@EndUserText.label: 'Fiscal Address'
lfa1.fiskn as FiscalAddress,
lfa1.j_1kftbus as BusinessType,
lfa1.gbdat as BirthDate,
lfa1.kraus as CreditorInformationNumber,
@EndUserText.label: 'Payment Block'
lfa1.sperz as PaymentIsBlockedForSupplier,
@EndUserText.label: 'Search Term'
lfa1.sortl as SortField,
lfa1.telf2 as PhoneNumber2,
lfa1.loevm as DeletionIndicator,
//GS FIN
j_1kfrepre as TaxInvoiceRepresentativeName,
j_1kftind as IndustryType,
lfa1.ven_class as IN_GSTSupplierClassification,
lfa1.podkzb as SuplrProofOfDelivRlvtCode,
lfa1.vbund as TradingPartner,
@EndUserText.label: 'Tax Split'
lfa1.ipisp as BR_TaxIsSplit,
lfa1.au_carrying_ent as AU_PayerIsPayingToCarryOnEnt,
lfa1.au_ind_under_18 as AU_IndividualIsUnder18,
@EndUserText.label: 'Payment Does not Exc'
lfa1.au_payment_not_exceed_75 as AU_PaymentIsExceeding75,
lfa1.au_wholly_inp_taxed as AU_PaymentIsWhollyInputTaxed,
@EndUserText.label: 'Individual w/o Gain'
lfa1.au_partner_without_gain as AU_PartnerIsSupplyWithoutGain,
lfa1.au_not_entitled_abn as AU_SupplierIsEntitledToABN,
lfa1.au_payment_exempt as AU_PaymentIsIncomeExempted,
lfa1.au_private_hobby as AU_SupplyIsMadeAsPrivateHobby,
lfa1.au_domestic_nature as AU_SupplyMadeIsOfDmstcNature,
lfa1.weora as IsToBeAcceptedAtOrigin,
// newly added fields
cast (stkza as xfeld preserving type) as BPIsEqualizationTaxSubject,
lfa1.taxbs as BRSpcfcTaxBasePercentageCode,
lfa1.profs as SupplierProfession,
lfa1.emnfr as SuplrManufacturerExternalName,
lfa1.dtams as DataMediumExchangeIndicator,
lfa1.dtaws as DataExchangeInstructionKey,
@EndUserText.label: 'VSR Relevant'
lfa1.ltsna as SupplierIsSubRangeRelevant,
@EndUserText.label: 'Train Station'
lfa1.bahns as TrainStationName,
lfa1.xzemp as AlternativePayeeIsAllowed,
lfa1.esrnr as PaytSlipWthRefSubscriber,
@EndUserText.label: 'Stat. Grp, Agent'
lfa1.stgdl as TranspServiceAgentStstcGrp,
@EndUserText.label: 'Plant Level Relevant'
lfa1.werkr as SupplierIsPlantRelevant,
lfa1.fisku as SuplrTaxAuthorityAccountNumber,
@Semantics.booleanIndicator: true
carrier_conf as SuplrCarrierConfirmIsExpected,
lfa1.werks as SupplierPlant,
lfa1.plkal as FactoryCalendar,
lfa1.paytrsn as PaymentReason,
@EndUserText.label: 'Central Del. Block'
lfa1.nodel as SupplierCentralDeletionIsBlock,
//added only for DCL check
@UI.hidden: true
@Consumption.filter.hidden: true
lfa1.xdcset as DataControllerSet,
//added only for DCL check
@UI.hidden: true
@Consumption.filter.hidden: true
lfa1.data_ctrlr1 as DataController1,
//added only for DCL check
@UI.hidden: true
@Consumption.filter.hidden: true
lfa1.data_ctrlr2 as DataController2,
//added only for DCL check
@UI.hidden: true
@Consumption.filter.hidden: true
lfa1.data_ctrlr3 as DataController3,
//added only for DCL check
@UI.hidden: true
@Consumption.filter.hidden: true
lfa1.data_ctrlr4 as DataController4,
//added only for DCL check
@UI.hidden: true
@Consumption.filter.hidden: true
lfa1.data_ctrlr5 as DataController5,
//added only for DCL check
@UI.hidden: true
@Consumption.filter.hidden: true
lfa1.data_ctrlr6 as DataController6,
//added only for DCL check
@UI.hidden: true
@Consumption.filter.hidden: true
lfa1.data_ctrlr7 as DataController7,
//added only for DCL check
@UI.hidden: true
@Consumption.filter.hidden: true
lfa1.data_ctrlr8 as DataController8,
//added only for DCL check
@UI.hidden: true
@Consumption.filter.hidden: true
lfa1.data_ctrlr9 as DataController9,
//added only for DCL check
@UI.hidden: true
@Consumption.filter.hidden: true
lfa1.data_ctrlr10 as DataController10,
lfa1.transport_chain as SupplierTransportationChain,
lfa1.staging_time as SupplierStagingTimeInDays,
lfa1.scheduling_type as SupplierSchedulingProcedure,
lfa1.submi_relevant as CollectiveNumberingIsRelevant,
lfa1.j_1ipanno as BusinessPartnerPanNumber,
lfa1.j_1ipanref as BPPanReferenceNumber,
lfa1.j_1ipanvaldt as BPPanValidFromDate,
//
_SupplierCompany,
_SupplierPurchasingOrg,
_SupplierBankDetails,
_SupplierAccountGroup,
_SupplierAccountGroupText, // OBSOLETE to be deleted
_SupplierIndustryText, // OBSOLETE to be deleted
_Industry,
_StandardAddress,
// _Address removed, use _StandardAddress instead
_CorrespondingCustomer,
_SupplierToBusinessPartner,
//quality management
_ProcurementBlock,
_QualityManagementSystem,
_AddressDefaultRepresentation,
_AddressRepresentation,
// _BusinessPartnerAddress
// _SupplierUnprotectedAddr
_EmailAddress,
_CurrentDfltEmailAddress,
_PhoneNumber,
_CurrentDfltLandlinePhoneNmbr,
_CurrentDfltMobilePhoneNumber,
_FaxNumber,
_CurrentDfltFaxNumber,
_UniformResourceIdentifier,
_MainWebsiteURL
}
//TESTING