P_AR_BPRelationshipRole

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl:{
  authorizationCheck: #MANDATORY,
  personalData.blocking: #REQUIRED
}
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  dataClass: #MIXED,
  serviceQuality: #P,
  sizeCategory: #L
}
@VDM:{
  private: true,
  viewType: #COMPOSITE
}
define view entity P_AR_BPRelationshipRole

  as select from I_CompanyCode     as CompanyCode
    inner join   I_CustomerCompany as CustomerCompany on CustomerCompany.CompanyCode = CompanyCode.CompanyCode
    inner join   I_Customer        as Customer        on Customer.Customer = CustomerCompany.Customer
{
  key CompanyCode.CompanyCode,
  key cast( 'D' as fis_gkoar preserving type )                       as OffsettingAccountType,
  key cast( CustomerCompany.Customer as fis_gkont preserving type )  as OffsettingAccount,
      Customer.BPCustomerFullName                                    as BusinessPartnerFullName,
      cast( Customer.TaxNumberType as j_1atoid preserving type )     as TaxNumberType,
      Customer.TaxNumber1,
      Customer.IsOneTimeAccount,
      Customer.AuthorizationGroup                                    as AuthorizationGroup,
      cast( Customer.CustomerAccountGroup as ktokd preserving type ) as ReferenceAccountGroup,
      CustomerCompany.AuthorizationGroup                             as CoCodeSpcfcAuthorizationGroup
}
where
  CompanyCode.Country = 'AR'

union all

select from  I_CompanyCode     as CompanyCode
  inner join I_SupplierCompany as SupplierCompany on SupplierCompany.CompanyCode = CompanyCode.CompanyCode
  inner join I_Supplier        as Supplier        on Supplier.Supplier = SupplierCompany.Supplier
{
  key CompanyCode.CompanyCode,
  key cast( 'K' as fis_gkoar preserving type )                       as OffsettingAccountType,
  key cast( SupplierCompany.Supplier as fis_gkont preserving type )  as OffsettingAccount,
      Supplier.BPSupplierFullName                                    as BusinessPartnerFullName,
      cast( Supplier.TaxNumberType as j_1atoid preserving type )     as TaxNumberType,
      Supplier.TaxNumber1,
      Supplier.IsOneTimeAccount,
      Supplier.AuthorizationGroup                                    as AuthorizationGroup,
      cast( Supplier.SupplierAccountGroup as ktokd preserving type ) as ReferenceAccountGroup,
      SupplierCompany.AuthorizationGroup                             as CoCodeSpcfcAuthorizationGroup
}
where
  CompanyCode.Country = 'AR'