P_Arbsitmopenitem

//@AbapCatalog.sqlViewName: 'PARBSITMOI'

@VDM.viewType: #COMPOSITE
@VDM.private:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
//@ClientHandling.algorithm: #SESSION_VARIABLE 

@ObjectModel.usageType.sizeCategory: #XXL 
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass: #MIXED
define view entity P_Arbsitmopenitem
    with parameters
        P_FinAccTyp     : koart
 as select from I_ReceivablesPayablesItem as OpenItem
 left outer join I_Customer as cust
        on OpenItem.Debtor = cust.Customer
    left outer join I_Supplier as supl
        on OpenItem.Creditor = supl.Supplier
    left outer join adrc as Address on ( Address.addrnumber = cust.AddressID or Address.addrnumber = supl.AddressID ) and Address.nation = 'I'
    left outer join P_ARBSITMCOMPANY as CompanyCtryKey
        on OpenItem.CompanyCode = CompanyCtryKey.CompanyCode  {
    OpenItem.CompanyCode,
    CompanyCtryKey.CountryKey,
    OpenItem.FiscalYear,
    OpenItem.AccountingDocument,
    OpenItem.AccountingDocumentItem,
    OpenItem.AccountingDocumentType,
    OpenItem.PostingDate,
    OpenItem._JournalEntry.DocumentReferenceID,
    OpenItem.AssignmentReference,
    OpenItem.PaymentReference,
    OpenItem.BillingDocument,
    OpenItem.ClearingDocFiscalYear,
    OpenItem.ClearingAccountingDocument,
    OpenItem.ClearingDate,
    OpenItem.CompanyCodeCurrency,
    OpenItem.TransactionCurrency,
    OpenItem.AmountInCompanyCodeCurrency,
    OpenItem.AmountInTransactionCurrency,
    OpenItem.TaxAmountInCoCodeCrcy,
    OpenItem.TaxAmount,
    OpenItem.CashDiscountAmtInCoCodeCrcy,
    OpenItem.CashDiscountAmount,
    OpenItem.DebitCreditCode,
    OpenItem.DocumentItemText,
    OpenItem.FinancialAccountType,
    OpenItem.InvoiceReference,
    OpenItem.InvoiceReferenceFiscalYear,
    OpenItem.InvoiceItemReference,
    OpenItem.FollowOnDocumentType,
    case when OpenItem.FinancialAccountType='K' then OpenItem.Creditor else OpenItem.Debtor end as Debtor,
    case when OpenItem.FinancialAccountType='K' then OpenItem._Supplier.OrganizationBPName1 else OpenItem._Customer.OrganizationBPName1 end as OrganizationBPName1,
    case when OpenItem.FinancialAccountType='K' then OpenItem._Supplier.OrganizationBPName2 else OpenItem._Customer.OrganizationBPName2 end as OrganizationBPName2,
    '' as OrganizationBPName3,
    '' as OrganizationBPName4,
    case when OpenItem.FinancialAccountType='K' then OpenItem._Supplier.CityName else OpenItem._Customer.CityName end as CityName,
    case when OpenItem.FinancialAccountType='K' then OpenItem._Supplier.Country else OpenItem._Customer.Country end as Country,
    OpenItem._JournalEntry.AccountingDocumentHeaderText,
    OpenItem.PartnerCompany,
    OpenItem.NetDueDate,
    OpenItem.CashDiscount1Percent,
    OpenItem.CashDiscount1DueDate,
    OpenItem.CashDiscount2Percent,
    OpenItem.CashDiscount2DueDate,
    OpenItem.Reference1IDByBusinessPartner,
    OpenItem.Reference2IDByBusinessPartner,
    OpenItem.Reference3IDByBusinessPartner,
    OpenItem.SpecialGLCode,
    cast('' as abap.sstring( 64)) as ReceivableKey,
    Address.nation,
    Address.name1,
    Address.name2,
    Address.name3,
    Address.name4,
    cust.CustomerFullName
}       
where OpenItem.ClearingAccountingDocument = ''
  and OpenItem.FinancialAccountType = $parameters.P_FinAccTyp