I_BPAddlSuplrEmailAddressTP

@AbapCatalog.sqlViewName: 'IBPADDSEATP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'BO view for email for MLTAS suppliers'


@VDM.viewType: #TRANSACTIONAL
@ObjectModel.writeEnabled: true
@ObjectModel.createEnabled

@ObjectModel.deleteEnabled
@ObjectModel.updateEnabled
@Search.searchable: true
@ObjectModel.semanticKey: ['BusinessPartner', 'Supplier', 'AddressID', 'OrdinalNumber' ]
@AccessControl.personalData.blocking: #REQUIRED

@ObjectModel.writeDraftPersistence: 'BPADDSEA_D'
@ObjectModel.draftEnabled:true

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view I_BPAddlSuplrEmailAddressTP
  as select from I_BPEmailAddress       as BPEmailAddress
    inner join   I_BPMultipleAssignment as BPMultipleAssignment on BPEmailAddress.AddressID = BPMultipleAssignment.AddressNumber
    inner join   I_Supplier             as Supplier             on BPMultipleAssignment.BPObjectID = Supplier.Supplier

  association [1..1] to I_BusinessPartnerTP      as _BusinessPartner      on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [1..1] to I_BPAdditionalSupplierTP as _BPAdditionalSupplier on  $projection.BusinessPartner = _BPAdditionalSupplier.BusinessPartner
                                                                          and $projection.Supplier        = _BPAdditionalSupplier.Supplier

{
  key BPMultipleAssignment.BusinessPartner,
  key Supplier.Supplier                                                  as Supplier,
  key BPEmailAddress.AddressID,
  key BPEmailAddress.OrdinalNumber,
      BPEmailAddress.IsDefaultEmailAddress,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      BPEmailAddress.EmailAddress,
      BPEmailAddress.IsHomeEmailAddress,
      BPEmailAddress._AddressCommunicationRemark.CommunicationRemarkText as AddressCommunicationRemarkText,
      //  cast('' as ad_remark2 ) as AddressCommunicationRemarkText,

      Supplier.SupplierName,

      //    For increased field length

      Supplier.BPSupplierName,

      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT]
      _BusinessPartner,
      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT]
      _BPAdditionalSupplier

}
where
      BPMultipleAssignment.IsStandardAssignment <> 'X'
  and BPMultipleAssignment.BPAssignmentCategory =  'SUPPL'