I_MX_BPRelationshipRole

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl:{
  authorizationCheck: #MANDATORY,
  personalData.blocking: #REQUIRED
}
@EndUserText.label: 'Provides Business Partners Roles'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #MIXED
}
@VDM.viewType: #COMPOSITE
define view entity I_MX_BPRelationshipRole
  with parameters
    @EndUserText.label: 'Company Code'
    P_CompanyCode : fis_bukrs

  as select from I_CompanyCode               as CompanyCode
    inner join   I_CustomerCompany           as CustomerCompany on CustomerCompany.CompanyCode = CompanyCode.CompanyCode
    inner join   I_CustomerToBusinessPartner as BusinessPartner on BusinessPartner.Customer = CustomerCompany.Customer
    inner join   I_Customer                  as Customer        on Customer.Customer = CustomerCompany.Customer
{
  key cast( CustomerCompany.CompanyCode as fis_bukrs preserving type ) as CompanyCode,
  key BusinessPartner.BusinessPartnerUUID,
  key cast( 'D' as gkoar preserving type )                             as OffsettingAccountType,
  key cast( BusinessPartner.Customer as gkont preserving type )        as OffsettingAccount,
  key CompanyCode.Language,
      cast( Customer.CustomerAccountGroup as ktokd preserving type )   as ReferenceAccountGroup,
      CustomerCompany.AuthorizationGroup                               as CoCodeSpcfcAuthorizationGroup,
      Customer.IsOneTimeAccount,
      Customer.TaxNumberType,
      Customer.AddressID,
      Customer.TaxNumber1,
      Customer.PostalCode,
      cast( '' as stenr )                                               as TaxNumberResponsible
}
where
      CompanyCode.Country         = 'MX'
  and CustomerCompany.CompanyCode = $parameters.P_CompanyCode

union all

select from  I_CompanyCode               as CompanyCode
  inner join I_SupplierCompany           as SupplierCompany on SupplierCompany.CompanyCode = CompanyCode.CompanyCode
  inner join I_SupplierToBusinessPartner as BusinessPartner on BusinessPartner.Supplier = SupplierCompany.Supplier
  inner join I_Supplier                  as Supplier        on Supplier.Supplier = SupplierCompany.Supplier
{
  key cast( SupplierCompany.CompanyCode as fis_bukrs preserving type ) as CompanyCode,
  key BusinessPartner.BusinessPartnerUUID,
  key cast( 'K' as gkoar preserving type )                             as OffsettingAccountType,
  key cast( BusinessPartner.Supplier as gkont preserving type )        as OffsettingAccount,
  key CompanyCode.Language,      
      cast( Supplier.SupplierAccountGroup as ktokd preserving type )   as ReferenceAccountGroup,
      SupplierCompany.AuthorizationGroup                               as CoCodeSpcfcAuthorizationGroup,
      Supplier.IsOneTimeAccount,
      Supplier.TaxNumberType,
      Supplier.AddressID,
      Supplier.TaxNumber1,
      Supplier.PostalCode,
      Supplier.TaxNumberResponsible
}
where
      CompanyCode.Country         = 'MX'
  and SupplierCompany.CompanyCode = $parameters.P_CompanyCode