I_SAFTGeneralLedgerSupplier

@AbapCatalog.sqlViewName: 'ISAFTGLSUP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@EndUserText.label: 'SAF-T Gen Ledger Supplier'
define view I_SAFTGeneralLedgerSupplier
  as select distinct from I_JournalEntryItem  as a

    inner join            P_SAFTGLMaxSupplier as GLMaxSupplier on  GLMaxSupplier.SourceLedger       = a.SourceLedger
                                                               and GLMaxSupplier.CompanyCode        = a.CompanyCode
                                                               and GLMaxSupplier.FiscalYear         = a.FiscalYear
                                                               and GLMaxSupplier.AccountingDocument = a.AccountingDocument
                                                               and GLMaxSupplier.LedgerGLLineItem   = a.LedgerGLLineItem
                                                               and GLMaxSupplier.Ledger             = a.Ledger

    inner join            I_Supplier          as b             on  a.Supplier         = b.Supplier
                                                               and b.IsOneTimeAccount = ' '

  association [0..*] to I_SAFTSupTaxRegnNmbr as _MultiVAT on a.Supplier = _MultiVAT.Supplier

{
      @ObjectModel.foreignKey.association: '_SourceLedger'
  key a.SourceLedger                                                            as SourceLedger,
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key a.CompanyCode                                                             as CompanyCode,
      @ObjectModel.foreignKey.association: '_FiscalYear'
  key a.FiscalYear                                                              as FiscalYear,
      @ObjectModel.foreignKey.association: '_JournalEntry'
  key a.AccountingDocument                                                      as AccountingDocument,
  key a.LedgerGLLineItem                                                        as LedgerGLLineItem,
      @ObjectModel.foreignKey.association: '_Ledger'
  key a.Ledger                                                                  as Ledger,

      @ObjectModel.foreignKey.association: '_ChartOfAccounts'
      a.ChartOfAccounts,
      @ObjectModel.foreignKey.association: '_GLAccountInChartOfAccounts'
      a.GLAccount,

      @ObjectModel.foreignKey.association: '_AccountingDocumentCategory'
      a.AccountingDocumentCategory,

      a.AccountingDocumentItem                                                  as AccountingDocumentItem,
      a.PostingDate                                                             as PostingDate,
      a.Supplier                                                                as Supplier,
      b.AddressID,
      substring(b.VATRegistration ,3,18)                                        as VATRegistration,
      concat( concat( b.BusinessPartnerName1, ' '), b.BusinessPartnerName2 )      as CompanyName,
      //b.StreetName                                                         as StreetName,

      b.BPAddrStreetName                                                        as StreetName,
      b._AddressRepresentation.StreetPrefixName1                                as StreetPrefixName,
      b._AddressRepresentation.StreetPrefixName2                                as AdditionalStreetPrefixName,
      b._AddressRepresentation.StreetSuffixName1                                as StreetSuffixName,
      b._AddressRepresentation.StreetSuffixName2                                as AdditionalStreetSuffixName,
      b._AddressRepresentation.HouseNumber                                      as HouseNumber,

      b.BPAddrCityName                                                          as CityName,
      b.PostalCode                                                              as PostalCode,
      b.Country                                                                 as Country,
      //b.Supplier                                                                as SupplierName,

      b.Region,
      a._SupplierCompany[ 1:CompanyCode = a.CompanyCode ].ReconciliationAccount as ReconciliationAccount,


      //Associations

      a._SupplierCompany, //Reconciliation Account

      b._AddressRepresentation,
      _MultiVAT,          //MultiVAT

      a._ChartOfAccounts,
      a._GLAccountInChartOfAccounts,
      a._SourceLedger,
      a._CompanyCode,
      a._FiscalYear,
      a._JournalEntry,
      a._Ledger,
      a._AccountingDocumentCategory,
      a._Supplier

}
where
  a.FinancialAccountType = 'K'