I_BusinessPartnerSupplierDEX

@Analytics.technicalName: 'IBPSUPPLIERDEX'
@Analytics.internalName: #LOCAL
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #MANDATORY
@ObjectModel.representativeKey: 'BusinessPartner'
@ObjectModel.sapObjectNodeType.name: 'Supplier'
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.personalData.blockingIndicator: ['IsBusinessPurposeCompleted']
@EndUserText.label: 'Data Extraction for BP Supplier'
@Analytics: {
  dataCategory: #DIMENSION, 
  dataExtraction: {
    enabled: true,
    delta.changeDataCapture: {
       mapping:[
             
                {
                   table: 'BUT000' , role: #MAIN,
                   viewElement: ['BusinessPartner'],
                    tableElement: ['partner']
                },
                 {
                   table: 'CVI_VEND_LINK', role: #LEFT_OUTER_TO_ONE_JOIN,
                    viewElement: ['BusinessPartnerUUID'],
                    tableElement: ['partner_guid']
                },
                {
                   table: 'LFA1', role: #LEFT_OUTER_TO_ONE_JOIN,
                    viewElement: ['Supplier'],
                    tableElement: ['lifnr']
                }
                
      ]
    }
  }
}
@Metadata.allowExtensions: true
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MASTER
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE,
                                     #CDS_MODELING_DATA_SOURCE,
                                     #CDS_MODELING_ASSOCIATION_TARGET,
                                     #EXTRACTION_DATA_SOURCE,
                                     #ANALYTICAL_DIMENSION]
 @Consumption.dbHints: [ 'USE_HEX_PLAN' ]
 
define view entity I_BusinessPartnerSupplierDEX 
as select from  I_Supplier as Supplier
    inner join      cvi_vend_link on Supplier.Supplier = cvi_vend_link.vendor
    left outer to one join but000        on cvi_vend_link.partner_guid = but000.partner_guid
    
    association [1..1] to I_Supplier_to_BusinessPartner as _SupplierToBusinessPartner on $projection.Supplier = _SupplierToBusinessPartner.Supplier
{
  key but000.partner                                  as BusinessPartner,
      Supplier.Supplier,
      cvi_vend_link.partner_guid                      as BusinessPartnerUUID,
      but000.type                                     as BusinessPartnerCategory,
      Supplier.SupplierAccountGroup,
      Supplier.FormOfAddress as TitleSupplier,
      Supplier.InternationalLocationNumber1,
      Supplier.InternationalLocationNumber2,
      Supplier.InternationalLocationNumber3,      
      Supplier.ReferenceAccountGroup,      
      Supplier.AlternativePayeeAccountNumber          as SupplierAlternativePayee,
      Supplier.Customer,
      Supplier.PostingIsBlocked,
      Supplier.PurchasingIsBlocked,
      Supplier.VATLiability,
      Supplier.PaymentIsBlockedForSupplier,
      Supplier.SuplrProofOfDelivRlvtCode,
      Supplier.BR_TaxIsSplit,
      cast( 'X' as sdraft_is_active preserving type ) as IsActiveEntity,
      Supplier.AuthorizationGroup,
      Supplier.IsToBeAcceptedAtOrigin,
      Supplier.SupplierCorporateGroup,
      Supplier.ResponsibleType, 
      Supplier.FiscalAddress,
      Supplier.SupplierProcurementBlock,
      Supplier.DataExchangeInstructionKey,
      Supplier.BPIsEqualizationTaxSubject,
      Supplier.BRSpcfcTaxBasePercentageCode,
      Supplier.DataMediumExchangeIndicator,
      Supplier.TranspServiceAgentStstcGrp,
      Supplier.TaxNumberResponsible,
      Supplier.TaxNumberType,
      Supplier.SuplrQualityManagementSystem,
      Supplier.SuplrQltyInProcmtCertfnValidTo,
      Supplier.SupplierIsSubRangeRelevant,
      Supplier.TrainStationName,
      Supplier.AlternativePayeeIsAllowed,
      Supplier.PaytSlipWthRefSubscriber,
      Supplier.SupplierIsPlantRelevant,
      Supplier.FactoryCalendar,
      Supplier.SupplierPlant,
      Supplier.DeletionIndicator,
      @Semantics.booleanIndicator: true
      Supplier.IsBusinessPurposeCompleted,
      Supplier.PaymentReason,
      Supplier.SupplierCentralDeletionIsBlock,      
      //added only for DCL check

      @Consumption.hidden:true     
      Supplier.DataControllerSet,
      @Consumption.hidden:true      
      Supplier.DataController1,
      //added only for DCL check

      @Consumption.hidden:true      
      Supplier.DataController2,
      //added only for DCL check

      @Consumption.hidden:true     
      Supplier.DataController3,
      //added only for DCL check

      @Consumption.hidden:true     
      Supplier.DataController4,
      //added only for DCL check

      @Consumption.hidden:true      
      Supplier.DataController5,
      @Consumption.hidden:true      
      Supplier.DataController6,
      //added only for DCL check

      @Consumption.hidden:true      
      Supplier.DataController7,
      //added only for DCL check

      @Consumption.hidden:true      
      Supplier.DataController8,
      //added only for DCL check

      @Consumption.hidden:true      
      Supplier.DataController9,
      //added only for DCL check

      @Consumption.hidden:true      
      Supplier.DataController10,
      Supplier.IsOneTimeAccount,
      Supplier.BusinessPartnerPanNumber,
      _SupplierToBusinessPartner
  
}