I_BPAddlSuplrMblPhNumberTP

@AbapCatalog.sqlViewName: 'IBPADDSMPNTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'BO view for Mobile nos of MLTAS Suppliers'
@AccessControl.personalData.blocking: #REQUIRED
@VDM.viewType: #TRANSACTIONAL
@ObjectModel.writeEnabled: true

@ObjectModel.writeDraftPersistence: 'BPADDSMPN_D'
@ObjectModel.draftEnabled:true

@ObjectModel.semanticKey: ['BusinessPartner', 'Supplier', 'AddressID', 'Person', 'OrdinalNumber' ] // Need to check

@ObjectModel.createEnabled
@ObjectModel.updateEnabled
@ObjectModel.deleteEnabled

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER

@Search.searchable: true
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view I_BPAddlSuplrMblPhNumberTP as select from I_BPMobilePhoneNumber as BPMobileNumber  inner join I_BPMultipleAssignment as BPMultipleAssignment on BPMobileNumber.AddressID = BPMultipleAssignment.AddressNumber inner join I_Supplier as Supplier on BPMultipleAssignment.BPObjectID = Supplier.Supplier
association [1..1] to I_BusinessPartnerTP as _BusinessPartner on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
association [1..1] to I_BPAdditionalSupplierTP as _BPAdditionalSupplier on $projection.BusinessPartner = _BPAdditionalSupplier.BusinessPartner
                                                                         and $projection.Supplier = _BPAdditionalSupplier.Supplier 
 
{
    key BPMultipleAssignment.BusinessPartner,
    key Supplier.Supplier as Supplier,
    key BPMobileNumber.AddressID, 
    key BPMobileNumber.Person, 
    key BPMobileNumber.OrdinalNumber, 
    BPMobileNumber.MobilePhoneCountry, 
    BPMobileNumber.IsDefaultPhoneNumber, 
    @Search.defaultSearchElement: true
    @Search.fuzzinessThreshold: 0.8
    @Search.ranking: #HIGH
    BPMobileNumber.MobilePhoneNumber, 
    BPMobileNumber.PhoneNumberType,    
    Supplier.SupplierName,
    
    
//    For field length incrrement

     Supplier.BPSupplierName,
    
    
    BPMobileNumber._AddressCommunicationRemark.CommunicationRemarkText as AddressCommunicationRemarkText,
    //cast('' as ad_remark2 ) as AddressCommunicationRemarkText,

    @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT ]
    _BusinessPartner,
    @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT ]
    _BPAdditionalSupplier
    
}
where BPMultipleAssignment.IsStandardAssignment <> 'X' and BPMultipleAssignment.BPAssignmentCategory = 'SUPPL'