C_PurOrdMaintainSuplrValHelp

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'CPOMAINTVHSUPLR'
@EndUserText.label: 'PO Maintenance: Value Help for Supplier'
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED

@ObjectModel.dataCategory:#VALUE_HELP
@ObjectModel.representativeKey: 'Supplier'
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]

define view C_PurOrdMaintainSuplrValHelp
  as select from I_Supplier as _Supplier
  association [0..*] to I_SupplierCompany as _SupplierMaster on  $projection.Supplier = _SupplierMaster.Supplier
                                                             and _SupplierMaster.CompanyCode != ''
  association [0..*] to I_CountryText     as _CountryText    on  $projection.Country = _CountryText.Country
  association [0..*] to I_RegionText      as _RegionText     on  $projection.Country = _RegionText.Country
                                                             and $projection.Region  = _RegionText.Region
{
  key _Supplier.Supplier                                         as Supplier,
  key _SupplierMaster.CompanyCode                                as CompanyCode, //prerequisition: this field always has to be used in a filter

      cast(_Supplier.SupplierName as abap.char(35))              as SupplierName,
      _Supplier._StandardAddress.Country                         as Country,
      cast(_Supplier._StandardAddress.CityName as abap.char(35)) as CityName,
      _Supplier._StandardAddress.PostalCode                      as PostalCode,
      _Supplier._StandardAddress.Region                          as Region,
      _Supplier.SupplierAccountGroup                             as SupplierAccountGroup,
      _Supplier.AuthorizationGroup                               as AuthorizationGroup,
      
      @Consumption.hidden:true
      @UI.hidden:true
      _Supplier.DataControllerSet, 
      
      @Consumption.hidden:true
      @UI.hidden:true
      @Semantics.booleanIndicator: true
      _Supplier.IsBusinessPurposeCompleted,
      
      _CountryText,
      _RegionText
}