P_AR_PurchaseVATRateSupplier

@AbapCatalog.sqlViewName: 'PARPURVTRTSUPLR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.private:true
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass:  #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #D

define view P_AR_PurchaseVATRateSupplier
  as select distinct from I_OperationalAcctgDocItem
    inner join   I_Supplier as Supplier on I_OperationalAcctgDocItem.Supplier = Supplier.Supplier
                                        and Supplier.TaxNumber1 <> '30546676591'
                                        and Supplier.TaxNumber1 <> '33693450239'
{
  key I_OperationalAcctgDocItem.CompanyCode,
  key I_OperationalAcctgDocItem.FiscalYear,
  key I_OperationalAcctgDocItem.AccountingDocument,
  key cast(
        case
          when Supplier.FiscalAddress <> ''
            then Supplier.FiscalAddress
          else Supplier.Supplier
        end as lifnr
      )   as Supplier,

      case
        when SpecialGLTransactionType = 'A' and DebitCreditCode = 'S'
          then 'H'
        when SpecialGLTransactionType = 'A' and DebitCreditCode = 'H'
          then 'S'
        else I_OperationalAcctgDocItem.DebitCreditCode
      end as DebitCreditCode
}
where
      I_OperationalAcctgDocItem.FinancialAccountType       = 'K'
  and I_OperationalAcctgDocItem.IsUsedInPaymentTransaction = ''