C_GRC_SupplierChangeLog

@AbapCatalog.sqlViewName: 'CGRCSUPLRMSTRCHG'
@EndUserText.label: 'Supplier change log'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #CONSUMPTION
@OData.publish: true
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view C_GRC_SupplierChangeLog
  as select from I_ChangeDocumentItem
    inner join   I_Supplier on I_ChangeDocumentItem.ChangeDocObject = I_Supplier.Supplier
{
  key I_Supplier.Supplier,
  key I_ChangeDocumentItem.ChangeDocument,
  key I_ChangeDocumentItem.ChangeDocDatabaseTableField,
  key I_ChangeDocumentItem.ChangeDocItemChangeType,

      cast (I_ChangeDocumentItem._ChangeDocument.CreationDate as fis_udate)      as ChangeDocCreationDate,
      cast(I_ChangeDocumentItem._ChangeDocument.CreatedByUser as lcm_changed_by) as LastChangedByUser,
      @EndUserText.label: 'New Field Value'
      I_ChangeDocumentItem.ChangeDocNewFieldValue,
      @EndUserText.label: 'Old Field Value'
      I_ChangeDocumentItem.ChangeDocPreviousFieldValue,
      @EndUserText.label: 'New Unit'
      I_ChangeDocumentItem.ChangeDocNewUnit,
      @EndUserText.label: 'Old Unit'
      I_ChangeDocumentItem.ChangeDocPreviousUnit,
      @EndUserText.label: 'New Currency'
      I_ChangeDocumentItem.ChangeDocNewCurrency,
      @EndUserText.label: 'Old Currency'
      I_ChangeDocumentItem.ChangeDocPreviousCurrency,

      I_Supplier.SupplierName,
      I_Supplier.SupplierAccountGroup,
      I_Supplier.CreatedByUser,
      I_Supplier.CreationDate,
      I_Supplier.IsOneTimeAccount,
      I_Supplier.PostingIsBlocked,
      I_Supplier.IsBusinessPurposeCompleted,      
      I_Supplier.PurchasingIsBlocked,
      I_Supplier.CityName,
      I_Supplier.Country,      
      I_Supplier.AuthorizationGroup,

      I_ChangeDocumentItem.ChangeDocObjectClass,
      I_ChangeDocumentItem.DatabaseTable,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      I_Supplier.DataControllerSet,
      //added only for DCL check

      @UI.hidden: true
      @Consumption.filter.hidden: true
      I_Supplier.DataController1,
      //added only for DCL check

      @UI.hidden: true
      @Consumption.filter.hidden: true
      I_Supplier.DataController2,
      //added only for DCL check

      @UI.hidden: true
      @Consumption.filter.hidden: true
      I_Supplier.DataController3,
      //added only for DCL check

      @UI.hidden: true
      @Consumption.filter.hidden: true
      I_Supplier.DataController4,
      //added only for DCL check

      @UI.hidden: true
      @Consumption.filter.hidden: true
      I_Supplier.DataController5,
      //added only for DCL check

      @UI.hidden: true
      @Consumption.filter.hidden: true
      I_Supplier.DataController6,
      //added only for DCL check

      @UI.hidden: true
      @Consumption.filter.hidden: true
      I_Supplier.DataController7,
      //added only for DCL check

      @UI.hidden: true
      @Consumption.filter.hidden: true
      I_Supplier.DataController8,
      //added only for DCL check

      @UI.hidden: true
      @Consumption.filter.hidden: true
      I_Supplier.DataController9,
      //added only for DCL check

      @UI.hidden: true
      @Consumption.filter.hidden: true
      I_Supplier.DataController10      
}
where
      I_ChangeDocumentItem.ChangeDocObjectClass = 'KRED'
  and I_ChangeDocumentItem.DatabaseTable        = 'LFA1'