P_AR_PurchaseVATRateDetail2

@AbapCatalog.sqlViewName: 'PARPURCVTRD2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
@VDM.viewType: #CONSUMPTION
@VDM.private: true
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_AR_PurchaseVATRateDetail2
  with parameters
    P_RptgAmountIsInTransCrcy : fiar_use_transaction_currency

  as select from    P_AR_PurchaseVATRateDetail ( P_RptgAmountIsInTransCrcy : $parameters.P_RptgAmountIsInTransCrcy ) as PurchaseVATRateDetail

    inner join      P_AR_PurchaseVATRateSupplier                                                                     as PurchaseVATRateSupplier      on  PurchaseVATRateDetail.CompanyCode        = PurchaseVATRateSupplier.CompanyCode
                                                                                                                                                     and PurchaseVATRateDetail.FiscalYear         = PurchaseVATRateSupplier.FiscalYear
                                                                                                                                                     and PurchaseVATRateDetail.AccountingDocument = PurchaseVATRateSupplier.AccountingDocument

    inner join      I_Supplier                                                                                       as Supplier                     on Supplier.Supplier = PurchaseVATRateSupplier.Supplier
    

{
  key PurchaseVATRateDetail.CompanyCode,
  key PurchaseVATRateDetail.FiscalYear,
  key PurchaseVATRateDetail.AccountingDocument,
  key PurchaseVATRateDetail.StatryRptCategory,
  key PurchaseVATRateDetail.StatryRptgEntity,
  key PurchaseVATRateDetail.StatryRptRunID,
  key PurchaseVATRateDetail.TaxRate,
      PurchaseVATRateDetail.PostingDate,
      PurchaseVATRateDetail.DocumentDate,
      PurchaseVATRateDetail.ReportingDate,
      PurchaseVATRateDetail.TaxReportingDate,
      PurchaseVATRateDetail.AccountingDocumentType,
      PurchaseVATRateDetail.DocumentReferenceID,
      PurchaseVATRateSupplier.DebitCreditCode,

      cast(
        case
          when Supplier.IsOneTimeAccount = 'X'
            then PurchaseVATRateDetail._OneTimeAccountBP.BusinessPartnerName1
          else Supplier.OrganizationBPName1
        end as businesspartnername
      ) as BusinessPartnerName,

      cast(
        case
          when Supplier.IsOneTimeAccount = 'X'
            then PurchaseVATRateDetail._OneTimeAccountBP.TaxID1
          else Supplier.TaxNumber1
        end as stcd1 preserving type
      ) as TaxNumber1,

      cast(
        case
          when Supplier.IsOneTimeAccount = 'X'
            then PurchaseVATRateDetail._OneTimeAccountBP.TaxNumberType
          else Supplier.TaxNumberType
        end as j_1atoid preserving type
      ) as TaxNumberType,

      cast(
        case
          when Supplier.IsOneTimeAccount = 'X'
            then PurchaseVATRateDetail._OneTimeAccountBP.Country
          else Supplier.Country
        end as glo_partner_country preserving type
      ) as BusinessPartnerCountry,

      cast(
        case
          when Supplier.IsOneTimeAccount = 'X'
            then PurchaseVATRateDetail._OneTimeAccountBP.IsNaturalPerson
          else Supplier.IsNaturalPerson
        end as bu_natural_person preserving type
      ) as IsNaturalPerson,

      PurchaseVATRateDetail.AR_Branch,
      PurchaseVATRateDetail.AR_OfficialDocumentNumber,
      PurchaseVATRateDetail.AR_PrintCharacter,
      PurchaseVATRateDetail.AR_OfficialDocumentType,
      PurchaseVATRateDetail.AR_OfficialDocumentClass,
      
      PurchaseVATRateDetail.CompanyCodeCountry,

      @Semantics.currencyCode:true
      PurchaseVATRateDetail.CompanyCodeCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      PurchaseVATRateDetail.TaxAmountInCoCodeCrcy,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      PurchaseVATRateDetail.TaxBaseAmountInCoCodeCrcy,

      @Semantics.currencyCode:true
      PurchaseVATRateDetail.TransactionCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      PurchaseVATRateDetail.TaxAmountInTransCrcy,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      PurchaseVATRateDetail.TaxBaseAmountInTransCrcy,

      @Semantics.currencyCode:true
      PurchaseVATRateDetail.ReportingCurrency,
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      PurchaseVATRateDetail.TaxAmountInRptgCrcy,
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      PurchaseVATRateDetail.TaxBaseAmountInRptgCrcy,

      PurchaseVATRateDetail.NmbrOfVATRates,
      PurchaseVATRateDetail._OneTimeAccountBP
}