C_LCMSupplierValueHelp

@AbapCatalog.sqlViewName: 'CLCMSUPPLVH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true
@VDM.viewType: #CONSUMPTION
@Search.searchable: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: { semanticKey: ['Supplier', 'CompanyCode'],
                representativeKey: 'Supplier',
                usageType.dataClass: #MASTER,
                usageType.serviceQuality: #C,
                usageType.sizeCategory: #XL,
                dataCategory: #VALUE_HELP }
@EndUserText.label: 'Supplier Value Help'
@Consumption.ranked: true
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view C_LCMSupplierValueHelp
  as select from I_Supplier

  association [0..*] to I_BusinessPartnerSuplrCo      as _BusinessPartnerSuplrCo  on $projection.Supplier = _BusinessPartnerSuplrCo.Supplier

  association [1..1] to I_Supplier_to_BusinessPartner as _SupplierBusinessPartner on $projection.Supplier = _SupplierBusinessPartner.Supplier

{
         @ObjectModel.text.element:  [ 'BusinessPartnerName' ]
         @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
         @UI.selectionField: [{ position: 10 }]
         @UI.lineItem: [{ position: 10 }]
  key    Supplier                                                                           as Supplier,

         @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
         @UI.selectionField: [{ position: 50 }]
         @UI.lineItem: [{ position: 50 }]
  key    _BusinessPartnerSuplrCo.CompanyCode                                                as CompanyCode,

         @UI.selectionField: [{ position: 30 }]
         @UI.lineItem: [{ position: 30 }]
         _SupplierBusinessPartner._BusinessPartner.BusinessPartner                          as BusinessPartner,

         @Semantics.text: true
         @UI.selectionField: [{ position: 40 }]
         @UI.lineItem: [{ position: 40 }]
         @EndUserText.label: 'Business Partner Name'
         _SupplierBusinessPartner._BusinessPartner.BusinessPartnerName                      as BusinessPartnerName,

         @UI.selectionField: [{ position: 60 }]
         @UI.lineItem: [{ position: 60 }]
         _AddressRepresentation.CityName                                                    as CityName,

         @UI.selectionField: [{ position: 70 }]
         @UI.lineItem: [{ position: 70 }]
         _AddressRepresentation.PostalCode                                                  as PostalCode,

         @UI.selectionField: [{ position: 80 }]
         @UI.lineItem: [{ position: 80 }]
         _AddressRepresentation.Region                                                      as Region,

         @UI.selectionField: [{ position: 90 }]
         @UI.lineItem: [{ position: 90 }]
         _AddressRepresentation.Country                                                     as Country,

         @UI.selectionField: [{ position: 100 }]
         @UI.lineItem: [{ position: 100 }]
         _AddressRepresentation.StreetName                                                  as StreetName,

         @UI.selectionField: [{ position: 110 }]
         @UI.lineItem: [{ position: 110 }]
         _AddressRepresentation._CurrentDfltLandlinePhoneNmbr.PhoneAreaCodeSubscriberNumber as PhoneNumber,

         @UI.selectionField: [{ position: 120 }]
         @UI.lineItem: [{ position: 120 }]
         _AddressRepresentation._CurrentDfltEmailAddress.EmailAddress                       as EmailAddress,

         // Added for Fuzzy Search Capabilities

         // In the I_BusinessPartner CDS View, BusinessPartnerName is calcuated using CASE and CONCAT

         // Hence, Fuzzy Search can't be enabled for BusinessPartnerName field.

         // As an altreanative, enabling the fuzzy search on following fields.


         // BEGIN OF FUZZY SEARCH RELATED FIELDS

         // For Supplier Name

         @UI.hidden: true
         @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.7 }
         _SupplierBusinessPartner._BusinessPartner.FirstName                                as LglCntntMSupplierFirstName,
         @UI.hidden: true
         @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.7 }
         _SupplierBusinessPartner._BusinessPartner.LastName                                 as LglCntntMSupplierLastName,
         @UI.hidden: true
         @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.7 }
         _SupplierBusinessPartner._BusinessPartner.OrganizationBPName1                      as LglCntntMSupplierOrgFirstName,
         @UI.hidden: true
         @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.7 }
         _SupplierBusinessPartner._BusinessPartner.OrganizationBPName2                      as LglCntntMSupplierOrgSecondName,
         @UI.hidden: true
         @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.7 }
         _SupplierBusinessPartner._BusinessPartner.GroupBusinessPartnerName1                as LglCntntMSupplierGrpFirstName,
         @UI.hidden: true
         @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.7 }
         _SupplierBusinessPartner._BusinessPartner.GroupBusinessPartnerName2                as LglCntntMSupplierGrpSecondName,
         // END OF FUZZY SEARCH RELATED FIELDS


         @Consumption.filter.hidden: true
         _BusinessPartnerSuplrCo,
         
         @Consumption.filter.hidden: true
         _SupplierBusinessPartner,

         //Added for DPP

         @UI.hidden: true
         AuthorizationGroup,

         @UI.hidden: true
         SupplierAccountGroup,

         @UI.hidden: true
         @Semantics.booleanIndicator: true
         IsBusinessPurposeCompleted,

         //added only for DCL check

         @Consumption.hidden:true
         @UI.hidden:true
         I_Supplier.DataControllerSet,
         @Consumption.hidden:true
         @UI.hidden:true
         I_Supplier.DataController1,
         //added only for DCL check

         @Consumption.hidden:true
         @UI.hidden:true
         I_Supplier.DataController2,
         //added only for DCL check

         @Consumption.hidden:true
         @UI.hidden:true
         I_Supplier.DataController3,
         //added only for DCL check

         @Consumption.hidden:true
         @UI.hidden:true
         I_Supplier.DataController4,
         //added only for DCL check

         @Consumption.hidden:true
         @UI.hidden:true
         I_Supplier.DataController5,
         @Consumption.hidden:true
         @UI.hidden:true
         I_Supplier.DataController6,
         //added only for DCL check

         @Consumption.hidden:true
         @UI.hidden:true
         I_Supplier.DataController7,
         //added only for DCL check

         @Consumption.hidden:true
         @UI.hidden:true
         I_Supplier.DataController8,
         //added only for DCL check

         @Consumption.hidden:true
         @UI.hidden:true
         I_Supplier.DataController9,
         //added only for DCL check

         @Consumption.hidden:true
         @UI.hidden:true
         I_Supplier.DataController10
}