I_LEDGERCOMPANYCODECRCYROLES

@AbapCatalog: { sqlViewName: 'ILDGRCOMPCOCR',
                compiler.compareFilter: true,
                preserveKey: true,
                buffering.status: #NOT_ALLOWED }   
@AccessControl.authorizationCheck: #CHECK
@Analytics: {dataCategory: #DIMENSION, dataExtraction.enabled: true}
@VDM.viewType: #BASIC
      
@ObjectModel: {usageType.sizeCategory: #S,
               usageType.dataClass:  #MASTER,
               usageType.serviceQuality: #A,
               representativeKey: 'CompanyCode',
                supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #EXTRACTION_DATA_SOURCE],
                modelingPattern: #ANALYTICAL_DIMENSION }                      
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true  
@EndUserText.label: 'Currency Roles for Ledger'
@Metadata.allowExtensions:true

define view I_LedgerCompanyCodeCrcyRoles as select from finsc_ld_cmp

association [0..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [0..1] to I_Ledger as _Ledger   on $projection.Ledger = _Ledger.Ledger  
association [0..1] to I_CurrencyRole        as _CompanyCodeCurrencyRole  on $projection.CompanyCodeCurrencyRole  = _CompanyCodeCurrencyRole.CurrencyRole
association [0..1] to I_CurrencyRole        as _GlobalCurrencyRole       on $projection.GlobalCurrencyRole       = _GlobalCurrencyRole.CurrencyRole
association [0..1] to I_CurrencyRole        as _FreeDefinedCurrency1Role on $projection.FreeDefinedCurrency1Role = _FreeDefinedCurrency1Role.CurrencyRole
association [0..1] to I_CurrencyRole        as _FreeDefinedCurrency2Role on $projection.FreeDefinedCurrency2Role = _FreeDefinedCurrency2Role.CurrencyRole
association [0..1] to I_CurrencyRole        as _FreeDefinedCurrency3Role on $projection.FreeDefinedCurrency3Role = _FreeDefinedCurrency3Role.CurrencyRole
association [0..1] to I_CurrencyRole        as _FreeDefinedCurrency4Role on $projection.FreeDefinedCurrency4Role = _FreeDefinedCurrency4Role.CurrencyRole
association [0..1] to I_CurrencyRole        as _FreeDefinedCurrency5Role on $projection.FreeDefinedCurrency5Role = _FreeDefinedCurrency5Role.CurrencyRole
association [0..1] to I_CurrencyRole        as _FreeDefinedCurrency6Role on $projection.FreeDefinedCurrency6Role = _FreeDefinedCurrency6Role.CurrencyRole
association [0..1] to I_CurrencyRole        as _FreeDefinedCurrency7Role on $projection.FreeDefinedCurrency7Role = _FreeDefinedCurrency7Role.CurrencyRole
association [0..1] to I_CurrencyRole        as _FreeDefinedCurrency8Role on $projection.FreeDefinedCurrency8Role = _FreeDefinedCurrency8Role.CurrencyRole
association [0..1] to I_CurrencyRole        as _FunctionalCurrencyRole   on $projection.FunctionalCurrencyRole   = _FunctionalCurrencyRole.CurrencyRole
association [0..1] to I_FiscalYearVariant   as _FiscalYearVariant        on $projection.FiscalYearVariant        = _FiscalYearVariant.FiscalYearVariant
association [0..1] to I_AccountingPrinciple as _AccountingPrinciple      on $projection.AccountingPrinciple      = _AccountingPrinciple.AccountingPrinciple
association [0..1] to I_Companycodecurrencyrole as _CoCodeCurrencyRoleCurrency on  $projection.CompanyCodeCurrencyRole = _CoCodeCurrencyRoleCurrency.CurrencyRole
                                                                               and $projection.CompanyCode             = _CoCodeCurrencyRoleCurrency.CompanyCode
association [0..1] to I_Companycodecurrencyrole as _GlobalCurrencyRoleCurrency on  $projection.GlobalCurrencyRole = _GlobalCurrencyRoleCurrency.CurrencyRole
                                                                               and $projection.CompanyCode             = _GlobalCurrencyRoleCurrency.CompanyCode
association [0..1] to I_Companycodecurrencyrole as _FreeDfndCrcyRole1Currency on  $projection.FreeDefinedCurrency1Role = _FreeDfndCrcyRole1Currency.CurrencyRole
                                                                               and $projection.CompanyCode             = _FreeDfndCrcyRole1Currency.CompanyCode
association [0..1] to I_Companycodecurrencyrole as _FreeDfndCrcyRole2Currency on  $projection.FreeDefinedCurrency2Role = _FreeDfndCrcyRole2Currency.CurrencyRole
                                                                               and $projection.CompanyCode             = _FreeDfndCrcyRole2Currency.CompanyCode                                                                                                                                                                                                                                             
association [0..1] to I_Companycodecurrencyrole as _FreeDfndCrcyRole3Currency on  $projection.FreeDefinedCurrency3Role = _FreeDfndCrcyRole3Currency.CurrencyRole
                                                                               and $projection.CompanyCode             = _FreeDfndCrcyRole3Currency.CompanyCode
association [0..1] to I_Companycodecurrencyrole as _FreeDfndCrcyRole4Currency on  $projection.FreeDefinedCurrency4Role = _FreeDfndCrcyRole4Currency.CurrencyRole
                                                                               and $projection.CompanyCode             = _FreeDfndCrcyRole4Currency.CompanyCode
association [0..1] to I_Companycodecurrencyrole as _FreeDfndCrcyRole5Currency on  $projection.FreeDefinedCurrency5Role = _FreeDfndCrcyRole5Currency.CurrencyRole
                                                                               and $projection.CompanyCode             = _FreeDfndCrcyRole5Currency.CompanyCode
association [0..1] to I_Companycodecurrencyrole as _FreeDfndCrcyRole6Currency on  $projection.FreeDefinedCurrency6Role = _FreeDfndCrcyRole6Currency.CurrencyRole
                                                                               and $projection.CompanyCode             = _FreeDfndCrcyRole6Currency.CompanyCode
association [0..1] to I_Companycodecurrencyrole as _FreeDfndCrcyRole7Currency on  $projection.FreeDefinedCurrency7Role = _FreeDfndCrcyRole7Currency.CurrencyRole
                                                                               and $projection.CompanyCode             = _FreeDfndCrcyRole7Currency.CompanyCode                                                                                                                                                                                                                                             
association [0..1] to I_Companycodecurrencyrole as _FreeDfndCrcyRole8Currency on  $projection.FreeDefinedCurrency8Role = _FreeDfndCrcyRole8Currency.CurrencyRole
                                                                               and $projection.CompanyCode             = _FreeDfndCrcyRole8Currency.CompanyCode     
association [0..1] to I_Companycodecurrencyrole as _FunctionalCrcyRoleCurrency on  $projection.FunctionalCurrencyRole  = _FunctionalCrcyRoleCurrency.CurrencyRole
                                                                               and $projection.CompanyCode             = _FunctionalCrcyRoleCurrency.CompanyCode 
{
    
@ObjectModel.foreignKey.association: '_Ledger'
key finsc_ld_cmp.rldnr as Ledger,
@ObjectModel.foreignKey.association: '_CompanyCode'
key finsc_ld_cmp.bukrs as CompanyCode,

periv as FiscalYearVariant,

cast(finsc_ld_cmp.curtph as fis_cc_currole preserving type ) as CompanyCodeCurrencyRole,   
cast(finsc_ld_cmp.curtpk as fis_gc_currole preserving type ) as GlobalCurrencyRole,
// Free Defined Currency 1

cast(finsc_ld_cmp.curtpo as fis_fdc1_currole preserving type ) as FreeDefinedCurrency1Role,
// Free Defined Currency 2

cast(finsc_ld_cmp.curtpv as fis_fdc2_currole preserving type ) as FreeDefinedCurrency2Role,
// Free Defined Currency 3

cast(finsc_ld_cmp.curtpb as fis_fdc3_currole preserving type ) as FreeDefinedCurrency3Role,
// Free Defined Currency 4

cast(finsc_ld_cmp.curtpc as fis_fdc4_currole preserving type ) as FreeDefinedCurrency4Role,
// Free Defined Currency 5

cast(finsc_ld_cmp.curtpd as fis_fdc5_currole preserving type ) as FreeDefinedCurrency5Role,
// Free Defined Currency 6

cast(finsc_ld_cmp.curtpe as fis_fdc6_currole preserving type ) as FreeDefinedCurrency6Role,
// Free Defined Currency 7

cast(finsc_ld_cmp.curtpf as fis_fdc7_currole preserving type ) as FreeDefinedCurrency7Role,
// Free Defined Currency 8

cast(finsc_ld_cmp.curtpg as fis_fdc8_currole preserving type ) as FreeDefinedCurrency8Role,

@Analytics.internalName: #LOCAL 
@ObjectModel.foreignKey.association: '_AccountingPrinciple'
cast(finsc_ld_cmp.acc_principle as accounting_principle preserving type) as AccountingPrinciple,

// cast(finsc_ld_cmp.functional_currency as fis_functional_currole preserving type ) as FunctionalCurrencyRole,

cast( case when finsc_ld_cmp.functional_currency <> '  ' then finsc_ld_cmp.functional_currency
                                                         else finsc_ld_cmp.curtph           
      end                                    
      as fis_functional_currole 
     ) as FunctionalCurrencyRole,
cast ( case when  finsc_ld_cmp.curposk = '2' then 'GC'
     when  finsc_ld_cmp.curposo = '2' then 'FDC1'
     when  finsc_ld_cmp.curposv = '2' then 'FDC2'
     when  finsc_ld_cmp.curposb = '2' then 'FDC3'
     when  finsc_ld_cmp.curposc = '2' then 'FDC4'
     when  finsc_ld_cmp.curposd = '2' then 'FDC5'
     when  finsc_ld_cmp.curpose = '2' then 'FDC6'
     when  finsc_ld_cmp.curposf = '2' then 'FDC7'
     when  finsc_ld_cmp.curposg = '2' then 'FDC8'   
     else '' end 
     as fis_addl1_crcy_field ) as AdditionalCurrency1Field,  
cast ( case when  finsc_ld_cmp.curposk = '3' then 'GC'
     when  finsc_ld_cmp.curposo = '3' then 'FDC1'
     when  finsc_ld_cmp.curposv = '3' then 'FDC2'
     when  finsc_ld_cmp.curposb = '3' then 'FDC3'
     when  finsc_ld_cmp.curposc = '3' then 'FDC4'
     when  finsc_ld_cmp.curposd = '3' then 'FDC5'
     when  finsc_ld_cmp.curpose = '3' then 'FDC6'
     when  finsc_ld_cmp.curposf = '3' then 'FDC7'
     when  finsc_ld_cmp.curposg = '3' then 'FDC8'   
     else '' end 
     as fis_addl2_crcy_field ) as AdditionalCurrency2Field, 
_Ledger,
_CompanyCode,
_FiscalYearVariant,
_CompanyCodeCurrencyRole,
_GlobalCurrencyRole,
_FreeDefinedCurrency1Role,
_FreeDefinedCurrency2Role,
_FreeDefinedCurrency3Role,
_FreeDefinedCurrency4Role,
_FreeDefinedCurrency5Role,
_FreeDefinedCurrency6Role,
_FreeDefinedCurrency7Role,
_FreeDefinedCurrency8Role,
_FunctionalCurrencyRole,
_AccountingPrinciple,
_CoCodeCurrencyRoleCurrency,
_GlobalCurrencyRoleCurrency,
_FreeDfndCrcyRole1Currency,
_FreeDfndCrcyRole2Currency,
_FreeDfndCrcyRole3Currency,
_FreeDfndCrcyRole4Currency,
_FreeDfndCrcyRole5Currency,
_FreeDfndCrcyRole6Currency,
_FreeDfndCrcyRole7Currency,
_FreeDfndCrcyRole8Currency,
_FunctionalCrcyRoleCurrency

    
}   
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"FINSC_LD_CMP"
],
"ASSOCIATED":
[
"I_ACCOUNTINGPRINCIPLE",
"I_COMPANYCODE",
"I_COMPANYCODECURRENCYROLE",
"I_CURRENCYROLE",
"I_FISCALYEARVARIANT",
"I_LEDGER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/