FAC_DART_Z3_PROFITCENTER

@AbapCatalog.sqlViewName: 'FAC_DZPROFITCTR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@EndUserText.label: 'Profit Center'
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

define view FAC_DART_Z3_PROFITCENTER
  with parameters
    P_Ledger           : fins_ledger,
    P_FiscalYear       : fins_gjahr,
    @EndUserText.label: 'From Fiscal Period'
    P_FromFiscalPeriod : fins_fagl_fiscper_from,
    @EndUserText.label: 'To Fiscal Period'
    P_ToFiscalPeriod   : fins_fagl_fiscper_to,

    @Consumption.hidden: true
    @Environment.systemField: #SYSTEM_LANGUAGE
    P_Language         : sylangu
  as select from FAC_DART_Z3_PROFITCENTER_BASE( P_Language : $parameters.P_Language ) as _profitcenter
    inner join   I_LedgerCompanyCodeCrcyRoles on  I_LedgerCompanyCodeCrcyRoles.CompanyCode = _profitcenter.CompanyCode
                                              and I_LedgerCompanyCodeCrcyRoles.Ledger      = $parameters.P_Ledger

  association [0..1] to I_FiscalPeriodForVariant as _ToFiscalPeriodForVariant   on  _ToFiscalPeriodForVariant.FiscalYearVariant = $projection.FiscalYearVariant
                                                                                and _ToFiscalPeriodForVariant.FiscalYear        = $parameters.P_FiscalYear
                                                                                and _ToFiscalPeriodForVariant.FiscalPeriod      = $parameters.P_ToFiscalPeriod
  association [0..1] to I_FiscalPeriodForVariant as _FromFiscalPeriodForVariant on  _FromFiscalPeriodForVariant.FiscalYearVariant = $projection.FiscalYearVariant
                                                                                and _FromFiscalPeriodForVariant.FiscalYear        = $parameters.P_FiscalYear
                                                                                and _FromFiscalPeriodForVariant.FiscalPeriod      = $parameters.P_FromFiscalPeriod
{
  key _profitcenter.ProfitCenter,
      @ObjectModel.foreignKey.association: '_ControllingArea'
  key _profitcenter.ControllingArea,
  key _profitcenter.ValidityEndDate,
  key _profitcenter.CompanyCode,
      ControllingAreaName,
      @EndUserText.label: 'Company Code'
      _profitcenter.CompanyCode                      as InputCompanyCode,
      ProfitCenterName,
      @EndUserText.label: 'Description of Profit Center Long'
      ProfitCenterLongName,

      I_LedgerCompanyCodeCrcyRoles.FiscalYearVariant as FiscalYearVariant,

      ProfitCtrResponsibleUser,
      @Semantics.businessDate.from: true
      ValidityStartDate,
      Department,
      ProfitCenterStandardHierarchy,
      //--[ GENERATED:012:29JlHNUf7jY4ipE4XHfNBG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_SegmentStdVH',
                     element: 'Segment' }
        }]
      //@ObjectModel.text.association: '_SegmentText'

      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_Segment' //Inserted by VDM CDS Suite Plugin

      Segment,
      ProfitCenterIsBlocked,
      FormulaPlanningTemplate,
      FormOfAddress,
      AddressName,
      AdditionalName,
      ProfitCenterAddrName3,
      ProfitCenterAddrName4,
      StreetAddressName,
      POBox,
      CityName,
      PostalCode,
      District,
      @ObjectModel.foreignKey.association: '_Country' //Inserted by VDM CDS Suite Plugin

      Country,
      @ObjectModel.foreignKey.association: '_Region'
      Region,
      TaxJurisdiction,
      @Semantics.language:true
      @ObjectModel.foreignKey.association: '_Language' //Inserted by VDM CDS Suite Plugin

      Language,
      PhoneNumber1,
      PhoneNumber2,
      TeleboxNumber,
      TelexNumber,
      FaxNumber,
      DataCommunicationPhoneNumber,
      ProfitCenterPrinterName,
      ProfitCenterCreatedByUser,
      ProfitCenterCreationDate,

      @EndUserText.label: 'System Client'
      $session.client                                as SystemClient,

      _Text,
      _Country,
      _ControllingArea,
      _ProfitCenterHierarchyNode,
      _Language,
      _Segment,
      _Region

}
where
       _profitcenter.ValidityEndDate   >= _FromFiscalPeriodForVariant.FiscalPeriodStartDate
  and  _profitcenter.ValidityStartDate <= _ToFiscalPeriodForVariant.FiscalPeriodEndDate
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FAC_DART_Z3_PROFITCENTER_BASE",
"I_FISCALPERIODFORVARIANT",
"I_LEDGERCOMPANYCODECRCYROLES"
],
"ASSOCIATED":
[
"I_CONTROLLINGAREA",
"I_COUNTRY",
"I_FISCALPERIODFORVARIANT",
"I_LANGUAGE",
"I_PROFITCENTERHIERARCHYNODE",
"I_PROFITCENTERTEXT",
"I_REGION",
"I_SEGMENT"
],
"BASE":
[
"FAC_DART_Z3_PROFITCENTER_BASE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/