FAC_DART_Z3_JournalEnty_CHGDOC

@AbapCatalog.sqlViewName: 'FAC_DZJECHGD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.dataClass:  #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Journal Entry Change Document'
define view FAC_DART_Z3_JournalEnty_CHGDOC
  with parameters
    //    P_CompanyCode      : bukrs,

    P_Ledger           : fins_ledger,
    P_FiscalYear       : fins_gjahr,
    @EndUserText.label: 'From Fiscal Period'
    P_FromFiscalPeriod : fins_fagl_fiscper_from,
    @EndUserText.label: 'To Fiscal Period'
    P_ToFiscalPeriod   : fins_fagl_fiscper_to,
    @Consumption.hidden: true
    @Environment.systemField: #SYSTEM_LANGUAGE
    P_Language         : sylangu
  as select from    fiscds_trk_doc_02( P_Language : $parameters.P_Language ) as chlog
    left outer join I_LedgerCompanyCodeCrcyRoles on  I_LedgerCompanyCodeCrcyRoles.CompanyCode = chlog.CompanyCode
                                                 and I_LedgerCompanyCodeCrcyRoles.Ledger      = $parameters.P_Ledger
  association [0..1] to I_FiscalPeriodForVariant     as _ToFiscalPeriodForVariant   on  _ToFiscalPeriodForVariant.FiscalYearVariant = $projection.FiscalYearVariant
                                                                                    and _ToFiscalPeriodForVariant.FiscalYear        = $parameters.P_FiscalYear
                                                                                    and _ToFiscalPeriodForVariant.FiscalPeriod      = $parameters.P_ToFiscalPeriod
  association [0..1] to I_FiscalPeriodForVariant     as _FromFiscalPeriodForVariant on  _FromFiscalPeriodForVariant.FiscalYearVariant = $projection.FiscalYearVariant
                                                                                    and _FromFiscalPeriodForVariant.FiscalYear        = $parameters.P_FiscalYear
                                                                                    and _FromFiscalPeriodForVariant.FiscalPeriod      = $parameters.P_FromFiscalPeriod
  association [0..*] to I_ChgDocItemChangeTypeText   as _ChgDocItemChangeTypeText   on  chlog.chngind = _ChgDocItemChangeTypeText.ChangeDocItemChangeType
  association [0..*] to I_ChangeLogDatabaseTableText as _ChangeLogDatabaseTableText on  chlog.TableName = _ChangeLogDatabaseTableText.DatabaseTable
{
  key chlog.CompanyCode,
  key FiscalYear,
  key AccountingDocument,
  key JournalEntryItem,
  key chlog.Ledger,
  key changenr                                       as ChangeDocument,
  key chlog.TableName                                as DatabaseTable,
  key tabkey                                         as ChangeDocTableKey,
  key fname                                          as FieldName,
      GLAccountNR,
      _ChangeLogDatabaseTableText[1: Language = $parameters.P_Language].DatabaseTableText,
      FieldName                                      as FieldText,
      _ChgDocItemChangeTypeText[1: Language = $parameters.P_Language].ChangeDocItemChangeTypeText,
      I_LedgerCompanyCodeCrcyRoles.FiscalYearVariant as FiscalYearVariant,
      chlog.ChangedBy                                as ChangedBy,
      chlog.ChangedAt                                as ChangedAt,
      chlog.OldValue                                 as OldValue,
      chlog.NewValue                                 as NewValue,
      chlog.ChangedOn                                as ChangedOn,
      text_case,
      @Semantics.systemDate.createdAt: true
      CreationDate,
      @Semantics.systemTime.createdAt: true
      CreationTime,
      //      $parameters.P_CompanyCode                      as ReportCompanyCode,

      @EndUserText.label: 'System Client'
      cast ( $session.client as char3 )              as SystemClient,
      I_LedgerCompanyCodeCrcyRoles._CompanyCode.ChartOfAccounts

}
where
       CreationDate >= _FromFiscalPeriodForVariant.FiscalPeriodStartDate
  and  CreationDate <= _ToFiscalPeriodForVariant.FiscalPeriodEndDate
  //  and(

  //       //       chlog.CompanyCode  = $parameters.P_CompanyCode

  //       chlog.CompanyCode =  ''

  //  )

  and(
       chlog.Ledger =  ''
    or chlog.Ledger = $parameters.P_Ledger
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FISCDS_TRK_DOC_02",
"I_CHANGELOGDATABASETABLETEXT",
"I_CHGDOCITEMCHANGETYPETEXT",
"I_COMPANYCODE",
"I_FISCALPERIODFORVARIANT",
"I_LEDGERCOMPANYCODECRCYROLES"
],
"ASSOCIATED":
[
"I_CHANGELOGDATABASETABLETEXT",
"I_CHGDOCITEMCHANGETYPETEXT",
"I_FISCALPERIODFORVARIANT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/