FAC_DART_Z3_AP_LINEITEM

@AbapCatalog.sqlViewName: 'FAC_DZAPLNITM'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Account Payable - Line Items'
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AbapCatalog.preserveKey: true
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
define view FAC_DART_Z3_AP_LINEITEM
  with parameters
    P_Ledger           : fins_ledger,
    P_FiscalYear       : fins_gjahr,
    @EndUserText.label: 'From Fiscal Period'
    P_FromFiscalPeriod : fins_fagl_fiscper_from,
    @EndUserText.label: 'To Fiscal Period'
    P_ToFiscalPeriod   : fins_fagl_fiscper_to,
    @Consumption.hidden: true
    @Environment.systemField: #SYSTEM_LANGUAGE
    P_Language         : sylangu
  as select from FAC_DART_Z3_AP_LINEITEM_BASE as Base
    inner join   I_LedgerCompanyCodeCrcyRoles on  Base.CompanyCode                    = I_LedgerCompanyCodeCrcyRoles.CompanyCode
                                              and I_LedgerCompanyCodeCrcyRoles.Ledger = $parameters.P_Ledger
                                              
  left outer join P_Bset on Base.CompanyCode = P_Bset.CompanyCode
                      and Base.FiscalYear = P_Bset.FiscalYear
                      and Base.AccountingDocument = P_Bset.AccountingDocument
                      and Base.AccountingDocumentItem = P_Bset.TaxItem
                      
  association [0..1] to E_JournalEntryItem       as _Extension                  on  _Extension.SourceLedger       = ' ' // This extension association is needed to enable extensibility for

                                                                                and _Extension.CompanyCode        = Base.CompanyCode // OData model FAC_FINANCIAL_DOCUMENT_MDL. The OData service is

                                                                                and _Extension.FiscalYear         = Base.FiscalYear // using this CDS view for modeling purposes only, not at runtime.

                                                                                and _Extension.AccountingDocument = Base.AccountingDocument // The extension of this CDS view actually doesn't work, as extension

                                                                                and _Extension.LedgerGLLineItem   = Base.AccountingDocumentItem // fields are available in ACDOCA only, not in BSEG. But it has to be modeled...

  association [0..1] to I_FiscalPeriodForVariant as _ToFiscalPeriodForVariant   on  _ToFiscalPeriodForVariant.FiscalYearVariant = $projection.FiscalYearVariant
                                                                                and _ToFiscalPeriodForVariant.FiscalYear        = $parameters.P_FiscalYear
                                                                                and _ToFiscalPeriodForVariant.FiscalPeriod      = $parameters.P_ToFiscalPeriod
  association [0..1] to I_FiscalPeriodForVariant as _FromFiscalPeriodForVariant on  _FromFiscalPeriodForVariant.FiscalYearVariant = $projection.FiscalYearVariant
                                                                                and _FromFiscalPeriodForVariant.FiscalYear        = $parameters.P_FiscalYear
                                                                                and _FromFiscalPeriodForVariant.FiscalPeriod      = $parameters.P_FromFiscalPeriod
{
      //BEGIN OF FIELDS SHOWN IN REPORT


      @ObjectModel.foreignKey.association: '_CompanyCode'
  key Base.CompanyCode,
      @ObjectModel.foreignKey.association: '_JournalEntry'
  key Base.AccountingDocument,
      @ObjectModel.foreignKey.association: '_FiscalYear'
  key Base.FiscalYear,
  key AccountingDocumentItem,
      @EndUserText.label: 'System Client'
      $session.client                                as SystemClient,
      @ObjectModel.foreignKey.association: '_FinancialAccountType'
      FinancialAccountType,
      @ObjectModel.foreignKey.association: '_Supplier'
      Supplier,
      @EndUserText.label: 'Customer'
      @ObjectModel.foreignKey.association: '_Customer'
      Customer,
      @ObjectModel.foreignKey.association: '_SpecialGLCode'
      SpecialGLCode,
      case
        when ClearingDate > _ToFiscalPeriodForVariant.FiscalPeriodEndDate
          then '00000000'
        else ClearingDate
      end                                            as ClearingDate,
      case
        when ClearingDate > _ToFiscalPeriodForVariant.FiscalPeriodEndDate
          then ''
        else ClearingAccountingDocument
      end                                            as ClearingAccountingDocument,
      AssignmentReference,
      PostingDate,
      DocumentDate,
      AccountingDocumentCreationDate,
      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      @Semantics.currencyCode:true
      TransactionCurrency,
      DocumentReferenceID,
      @ObjectModel.foreignKey.association: '_AccountingDocumentType'
      AccountingDocumentType,
      @ObjectModel.foreignKey.association: '_FiscalPeriod'
      FiscalPeriod,
      @ObjectModel.foreignKey.association: '_PostingKey'
      PostingKey,
      @ObjectModel.foreignKey.association: '_DebitCreditCode'
      Base.DebitCreditCode,
      @ObjectModel.foreignKey.association: '_BusinessArea'
      BusinessArea,
      Base.TaxCode,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      AmountInCompanyCodeCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      AmountInTransactionCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      Base.TaxAmountInCoCodeCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      Base.TaxAmount,
      DocumentItemText,
      @ObjectModel.foreignKey.association: '_Order'
      OrderID,
      @ObjectModel.foreignKey.association: '_PurchasingDocument'
      PurchasingDocument,
      @ObjectModel.foreignKey.association: '_PurchasingDocumentItem'
      PurchasingDocumentItem,
      OperationalGLAccount,
      @ObjectModel.foreignKey.association: '_GLAccountInChartOfAccounts'
      Base.GLAccount,
      BranchAccount,
      DueCalculationBaseDate,
      PaymentTerms,
      CashDiscount1Days,
      CashDiscount2Days,
      NetPaymentDays,
      CashDiscount1Percent,
      CashDiscount2Percent,
      FixedCashDiscount,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      CashDiscountAmtInCoCodeCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      CashDiscountAmount,
      PaymentMethod,
      @ObjectModel.foreignKey.association: '_HouseBank'
      HouseBank,
      InvoiceReference,
      InvoiceReferenceFiscalYear,
      InvoiceItemReference,
      @ObjectModel.foreignKey.association: '_SupplyingCountry'
      Base.SupplyingCountry,
      NetAmountIsPosted,
      DownPaymentIsNetProcedure,
      AddressAndBankIsSetManually,
      PaytSlipWthRefSubscriber,
      PaytSlipWthRefReference,
      PaytSlipWthRefCheckDigit,
      IsUsedInPaymentTransaction,
      TaxDistributionCode1,
      TaxDistributionCode2,
      TaxDistributionCode3,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      TaxBrkdwnAmount1InCoCodeCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      TaxBrkdwnAmount2InCoCodeCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      TaxBrkdwnAmount3InCoCodeCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      TaxBrkdwnAmount1InTransCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      TaxBrkdwnAmount2InTransCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      TaxBrkdwnAmount3InTransCrcy,
      WithholdingTaxCode,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      WithholdingTaxBaseAmount,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      WithholdingTaxAmount,
      @ObjectModel.foreignKey.association: '_PartnerCompany'
      PartnerCompany,
      FollowOnDocumentType,
      Base.VATRegistration,
      DelivOfGoodsDestCountry,
      WithholdingTaxCertificate,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      WithholdingTaxExemptionAmt,
      @ObjectModel.foreignKey.association: '_WBSElementInternalID'
      WBSElementInternalID,
      IsEUTriangularDeal,
      @ObjectModel.foreignKey.association: '_CostCenter'
      CostCenter,
      AlternativePayeePayer,
      @ObjectModel.foreignKey.association: '_ProfitCenter'
      ProfitCenter,
      PaymentReference,
      @ObjectModel.foreignKey.association: '_PaymentCurrency'
      @Semantics.currencyCode:true
      PaymentCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'PaymentCurrency'} }
      AmountInPaymentCurrency,
      TaxSection,
      @ObjectModel.foreignKey.association: '_FunctionalArea'
      FunctionalArea,
      BillingDocument,
      @ObjectModel.foreignKey.association: '_SalesDoc'
      SalesDocument,
      @ObjectModel.foreignKey.association: '_SalesDocItem'
      SalesDocumentItem,
      ValueDate,
      PaymentMethodSupplement,

      //END OF FIELDS SHOWN IN REPORT


      I_LedgerCompanyCodeCrcyRoles.FiscalYearVariant as FiscalYearVariant,
      @EndUserText.label: 'Reconciliation Account'
      ReconciliationAccount,
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      @EndUserText.label: 'Debit Amt in CoCode Currency'
      case Base.DebitCreditCode
             when 'S'
               then cast( AmountInCompanyCodeCurrency as fis_dr_hsl )
               else cast( cast ( '0' as abap.curr(23,2) ) as fis_dr_hsl)
             end                                     as DebitAmountInCoCodeCrcy,
      Base.CompanyCodeCurrency                            as DebitCompanyCodeCurrency,
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      @EndUserText.label: 'Credit Amt in CoCode Currency'
      case Base.DebitCreditCode
         when 'H'
           then cast( (-1) * AmountInCompanyCodeCurrency as fis_cr_hsl )
           else cast( cast ( '0' as abap.curr(23,2) ) as fis_cr_hsl)
         end                                         as CreditAmountInCoCodeCrcy,
      Base.CompanyCodeCurrency                            as CreditCompanyCodeCurrency,
      @ObjectModel.foreignKey.association: '_ChartOfAccounts'
      Base.ChartOfAccounts,
      OriginalReferenceDocument,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      case Base.DebitCreditCode
         when 'S'
           then AmountInTransactionCurrency
           else 0
         end                                         as DebitAmountInTransCrcy,

      TransactionCurrency                            as DebitTransactionCurrency,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      case Base.DebitCreditCode
         when 'H'
           then (-1) * AmountInTransactionCurrency
           else 0
         end                                         as CreditAmountInTransCrcy,
      TransactionCurrency                            as CreditTransactionCurrency,
      _DebitCreditCode._Text[1: Language = $parameters.P_Language].DebitCreditCodeName,
      @ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
      @Semantics.currencyCode:true
      Base.CompanyCodeCurrency,
      @ObjectModel.foreignKey.association: '_AccountingDocumentCategory'
      AccountingDocumentCategory,
      AccountingDocumentItemType,
      case
        when ClearingDate > _ToFiscalPeriodForVariant.FiscalPeriodEndDate
          then '00000000'
        else ClearingCreationDate
      end                                            as ClearingCreationDate,
      SpecialGLTransactionType,
      @ObjectModel.foreignKey.association: '_PartnerBusinessArea'
      PartnerBusinessArea,
      Base.TaxCountry,
      
      P_Bset.TaxRateValidityStartDate,
      
      @ObjectModel.foreignKey.association: '_TaxType'
      TaxType,
      Base.TaxItemGroup,
      Base.TransactionTypeDetermination,
      @ObjectModel.foreignKey.association: '_FinancialTransactionType'
      FinancialTransactionType,
      CorporateGroupAccount,
      PlanningLevel,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      Base.ControllingArea,
      Project, // DO NOT USE ; this is the old unused Project

      ScheduleLine,
      @Consumption.valueHelpDefinition: [
              { entity:  { name:    'I_AcctgServiceDocumentTypeVH',
                           element: 'ServiceDocumentType' }
              }]
      @Analytics.internalName: #LOCAL
      @ObjectModel.foreignKey.association: '_ServiceDocumentType'
      ServiceDocumentType,
      @Consumption.valueHelpDefinition: [
              { entity:  { name:    'I_AcctgServiceDocumentVH',
                           element: 'ServiceDocument' }
              }]
      @Analytics.internalName: #LOCAL
      @ObjectModel.foreignKey.association: '_ServiceDocument'
      ServiceDocument,
      @Consumption.valueHelpDefinition: [
              { entity:  { name:    'I_AcctgServiceDocumentItemVH',
                           element: 'ServiceDocumentItem' }
              }]
      @Analytics.internalName: #LOCAL
      @ObjectModel.foreignKey.association: '_ServiceDocumentItem'
      ServiceDocumentItem,
      @Consumption.valueHelpDefinition: [
              { entity:  { name:    'I_AcctgServiceDocumentTypeVH',
                           element: 'PartnerServiceDocumentType' }
              }]
      @ObjectModel.foreignKey.association: '_MasterFixedAsset'
      MasterFixedAsset,
      @ObjectModel.foreignKey.association: '_FixedAsset'
      FixedAsset,
      @ObjectModel.foreignKey.association: '_AssetTransactionType'
      AssetTransactionType,
      AssetValueDate,
      AssetClass,
      @ObjectModel.foreignKey.association: '_Employment'
      PersonnelNumber,
      IsSalesRelated,
      LineItemDisplayIsEnabled,
      IsOpenItemManaged,
      IsNotCashDiscountLiable,
      IsAutomaticallyCreated,
      IsBalanceSheetAccount,
      ProfitLossAccountType,
      SpecialGLAccountAssignment,
      PaymentBlockingReason,
      @ObjectModel.foreignKey.association: '_SupplierBankDetails'
      BPBankAccountInternalID,
      StateCentralBankPaymentReason,
      InvoiceList,
      BillOfExchangeUsage,
      DunningKey,
      DunningBlockingReason,
      LastDunningDate,
      DunningLevel,
      DunningArea,
      @ObjectModel.foreignKey.association: '_Material'
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'Product'
      Material, // do not use any longer, use Product

      @ObjectModel.foreignKey.association: '_Product'
      Product,
      @ObjectModel.foreignKey.association: '_Plant'
      Plant,
      AccountAssignmentNumber,
      IsCompletelyDelivered,
      MaterialPriceControl,
      @ObjectModel.foreignKey.association: '_ValuationArea'
      ValuationArea,
      @ObjectModel.foreignKey.association: '_InventoryValuationType'
      InventoryValuationType,
      @ObjectModel.foreignKey.association: '_PaymentDifferenceReason'
      PaymentDifferenceReason,
      JointVenture,
      JointVentureCostRecoveryCode,
      JointVentureEquityGroup,
      TreasuryContractType,
      AssetContract,
      CashFlowType,
      Base.TaxJurisdiction,
      RealEstateObject,
      SettlementReferenceDate,
      CommitmentItem,
      CostObject,
      @ObjectModel.foreignKey.association: '_ProjectNetwork'
      ProjectNetwork,
      OrderInternalBillOfOperations,
      OrderIntBillOfOperationsItem,
      ProfitabilitySegment,
      JointVentureEquityType,
      CostOriginGroup,
      CompanyCodeCurrencyDetnMethod,
      case
        when ClearingDate > _ToFiscalPeriodForVariant.FiscalPeriodEndDate
          then ''
        else ClearingIsReversed
      end                                            as ClearingIsReversed,
      AlternativeGLAccount,
      FundsCenter,
      Fund,
      @ObjectModel.foreignKey.association: '_PartnerProfitCenter'
      PartnerProfitCenter,
      Reference1IDByBusinessPartner,
      Reference2IDByBusinessPartner,
      IsNegativePosting,
      PaymentCardItem,
      PaymentCardPaymentSettlement,
      Base.CreditControlArea,
      Reference3IDByBusinessPartner,
      DataExchangeInstruction1,
      DataExchangeInstruction2,
      DataExchangeInstruction3,
      DataExchangeInstruction4,
      Region,
      HasPaymentOrder,
      Base.TaxDeterminationDate,
      case
        when ClearingDate > _ToFiscalPeriodForVariant.FiscalPeriodEndDate
          then 0
        else ClearingItem
      end                                            as ClearingItem,
      Base.BusinessPlace,
      @ObjectModel.foreignKey.association: '_CostCtrActivityType'
      CostCtrActivityType,
      AccountsReceivableIsPledged,
      @ObjectModel.foreignKey.association: '_BusinessProcess'
      BusinessProcess,
      GrantID,
      CustomerIsInExecution,
      FundedProgram,
      case
        when ClearingDate > _ToFiscalPeriodForVariant.FiscalPeriodEndDate
          then '0000'
        else ClearingDocFiscalYear
      end                                            as ClearingDocFiscalYear,
      LedgerGLLineItem,
      @ObjectModel.foreignKey.association: '_Segment'
      Segment,
      @ObjectModel.foreignKey.association: '_PartnerSegment'
      PartnerSegment,
      @ObjectModel.foreignKey.association: '_PartnerFunctionalArea'
      PartnerFunctionalArea,
      @ObjectModel.foreignKey.association: '_HouseBankAccount'
      HouseBankAccount,
      CostElement,
      PaymentServiceProvider,
      PaymentRefByPaytSrvcProvider,
      SEPAMandate,
      ReferenceDocumentType,
      ReferenceDocumentLogicalSystem,
      AccountingDocumentItemRef,
      NetDueDate,
      CashDiscount1DueDate,
      CashDiscount2DueDate,
      @ObjectModel.foreignKey.association: '_OffsettingAccountWithBP'
      OffsettingAccount,
      @ObjectModel.foreignKey.association: '_OffsettingAccountType'
      OffsettingAccountType,
      @ObjectModel.foreignKey.association: '_OffsettingChartOfAccounts'
      OffsettingChartOfAccounts,
      PartnerFund,
      PartnerGrant,
      @ObjectModel.foreignKey.association: '_BudgetPeriod'
      BudgetPeriod,
      PartnerBudgetPeriod,
      BranchCode,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      Base.TaxBaseAmountInCoCodeCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      ValuationDiffAmtInCoCodeCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      InvoiceAmtInCoCodeCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      OriginalTaxBaseAmount,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      Base.TaxBaseAmountInTransCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      PlannedAmtInTransactionCrcy,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      CashDiscountBaseAmount,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      NetPaymentAmount,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      InvoiceAmountInFrgnCurrency,
      @ObjectModel.foreignKey.association: '_BalanceTransactionCurrency'
      @Semantics.currencyCode:true
      BalanceTransactionCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'BalanceTransactionCurrency'} }
      AmountInBalanceTransacCrcy,
      @ObjectModel.foreignKey.association: '_AdditionalCurrency1'
      @Semantics.currencyCode:true
      Base.AdditionalCurrency1,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'AdditionalCurrency1'} }
      ValuationDiffAmtInAddlCrcy1,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'AdditionalCurrency1'} }
      AmountInAdditionalCurrency1,
      @ObjectModel.foreignKey.association: '_AdditionalCurrency2'
      @Semantics.currencyCode:true
      Base.AdditionalCurrency2,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'AdditionalCurrency2'} }
      AmountInAdditionalCurrency2,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'AdditionalCurrency2'} }
      ValuationDiffAmtInAddlCrcy2,
      @ObjectModel.foreignKey.association: '_CreditControlAreaCurrency'
      @Semantics.currencyCode:true
      CreditControlAreaCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CreditControlAreaCurrency'} }
      HedgedAmount,
      @ObjectModel.foreignKey.association: '_BaseUnit'
      @Semantics.unitOfMeasure:true
      BaseUnit,
      @DefaultAggregation: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
      Quantity,
      @ObjectModel.foreignKey.association: '_GoodsMovementEntryUnit'
      @Semantics.unitOfMeasure:true
      GoodsMovementEntryUnit,
      @DefaultAggregation: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'GoodsMovementEntryUnit'} }
      QuantityInEntryUnit,
      @ObjectModel.foreignKey.association: '_PurchasingDocumentPriceUnit'
      @Semantics.unitOfMeasure:true
      PurchasingDocumentPriceUnit,
      @DefaultAggregation: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'PurchasingDocumentPriceUnit'} }
      PurchaseOrderQty,
      MaterialPriceUnitQty,
      @DefaultAggregation: #SUM
      NumberOfItems,

      _AccountingDocumentCategory,
      _AccountingDocumentCategoryT,
      _AccountingDocumentType,
      _AdditionalCurrency1,
      _AdditionalCurrency2,
      _AssetTransactionType,
      _BalanceTransactionCurrency,
      _BaseUnit,
      _BudgetPeriod,
      _BudgetPeriodText,
      _BusinessArea,
      _BusinessAreaText,
      _BusinessProcess,
      _BusinessProcessText,
      Base._ChartOfAccountsText,
      Base._ChartOfAccounts,
      Base._CompanyCode,
      _CompanyCodeCurrency,
      Base._ControllingArea,
      Base._ControllingAreaText,
      _CostCenter,
      _CostCenterText,
      _CostCtrActivityType,
      _CostOriginGroup,
      _CreditControlAreaCurrency,
      _CurrentCostCenter,
      _CurrentProfitCenter,
      _Customer,
      _CustomerText,
      _DebitCreditCode,
      _Employment,
      _FinancialAccountType,
      _FinancialTransactionType,
      _FiscalPeriod,
      _FiscalYear,
      _FixedAsset,
      _FixedAssetText,
      _FunctionalArea,
      _FunctionalAreaText,
      _GLAccountInChartOfAccounts,
      _GLAccountInCompanyCode,
      _GoodsMovementEntryUnit,
      _HouseBank,
      _HouseBankAccount,
      _HouseBankAccountText,
      _InternalOrder,
      _InventoryValuationType,
      _JournalEntry,
      _MasterFixedAsset,
      _MasterFixedAssetText,
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: '_Product'
      _Material,
      _MaterialText,
      _OffsettingAccount,
      _OffsettingAccountType,
      _OffsettingAccountTypeText,
      _OffsettingAccountWithBP,
      _OffsettingChartOfAccounts,
      _OffsettingChartOfAccountsText,
      _Order,
      _PartnerBusinessArea,
      _PartnerBusinessAreaText,
      _PartnerCompany,
      _PartnerCompanyText,
      _PartnerFunctionalArea,
      _PartnerProfitCenter,
      _PartnerSegment,
      _PartnerSegmentText,
      _PaymentCurrency,
      _PaymentDifferenceReason,
      _Plant,
      _PostingKey,
      _Product,
      _ProductText,
      _ProfitCenter,
      _ProfitCenterText,
      _ProjectNetwork,
      _ProjectNetworkText,
      _PurchasingDocument,
      _PurchasingDocumentItem,
      _PurchasingDocumentPriceUnit,
      _SalesDoc,
      _SalesDocItem,
      _SalesDocument,
      _SalesDocumentItem,
      _Segment,
      _SegmentText,
      _ServiceDocument,
      _ServiceDocumentItem,
      _ServiceDocumentType,
      _SpecialGLCode,
      _Supplier,
      _SupplierBankDetails,
      _SupplyingCountry,
      _TaxCode,
      _TaxType,
      _TransactionCurrency,
      _ValuationArea,
      _WBSElementInternalID,
      _WBSElementInternalIDText

}
where
        FinancialAccountType       =  'K'
  and(
        AccountingDocumentCategory <> 'D'
    and AccountingDocumentCategory <> 'M'
    and AccountingDocumentCategory <> 'S'
    and AccountingDocumentCategory <> 'V'
    and AccountingDocumentCategory <> 'W'
    and AccountingDocumentCategory <> 'Z'
    and AccountingDocumentCategory <> 'T'
  )
  and   PostingDate                <= _ToFiscalPeriodForVariant.FiscalPeriodEndDate
  and   PostingDate                >= _FromFiscalPeriodForVariant.FiscalPeriodStartDate
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FAC_DART_Z3_AP_LINEITEM_BASE",
"I_DEBITCREDITCODE",
"I_DEBITCREDITCODETEXT",
"I_FISCALPERIODFORVARIANT",
"I_LEDGERCOMPANYCODECRCYROLES",
"P_BSET"
],
"ASSOCIATED":
[
"E_JOURNALENTRYITEM",
"I_ACCOUNTINGDOCUMENTCATEGORY",
"I_ACCOUNTINGDOCUMENTCATEGORYT",
"I_ACCOUNTINGDOCUMENTTYPE",
"I_ASSETTRANSACTIONTYPE",
"I_BUDGETPERIOD",
"I_BUDGETPERIODTEXT",
"I_BUSINESSAREA",
"I_BUSINESSAREATEXT",
"I_BUSINESSPROCESS",
"I_BUSINESSPROCESSTEXT",
"I_CHARTOFACCOUNTS",
"I_CHARTOFACCOUNTSTEXT",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COSTCENTER",
"I_COSTCENTERACTIVITYTYPE",
"I_COSTCENTERTEXT",
"I_COSTORIGINGROUP",
"I_COUNTRY",
"I_CURRENCY",
"I_CUSTOMER",
"I_DEBITCREDITCODE",
"I_EMPLOYMENT",
"I_FINANCIALACCOUNTTYPE",
"I_FINANCIALACCOUNTTYPETEXT",
"I_FINANCIALTRANSACTIONTYPE",
"I_FISCALPERIODFORVARIANT",
"I_FISCALYEARFORCOMPANYCODE",
"I_FISCALYEARPERIODFORCMPNYCODE",
"I_FIXEDASSET",
"I_FUNCTIONALAREA",
"I_FUNCTIONALAREATEXT",
"I_GLACCOUNTINCHARTOFACCOUNTS",
"I_GLACCOUNTINCOMPANYCODE",
"I_HOUSEBANK",
"I_HOUSEBANKACCOUNT",
"I_HOUSEBANKACCOUNTTEXT",
"I_INTERNALORDER",
"I_INVENTORYVALUATIONTYPE",
"I_JOURNALENTRY",
"I_MASTERFIXEDASSET",
"I_MATERIAL",
"I_MATERIALTEXT",
"I_OFFSETTINGACCOUNT",
"I_ORDER",
"I_PAYMENTDIFFERENCEREASON",
"I_PLANT",
"I_POSTINGKEY",
"I_PRODUCT",
"I_PRODUCTDESCRIPTION",
"I_PROFITCENTER",
"I_PROFITCENTERTEXT",
"I_PROJECTNETWORK",
"I_PURCHASINGDOCUMENT",
"I_PURCHASINGDOCUMENTITEM",
"I_PURREQVALUATIONAREA",
"I_SALESDOCUMENT",
"I_SALESDOCUMENTITEM",
"I_SALESORDER",
"I_SALESORDERITEM",
"I_SEGMENT",
"I_SEGMENTTEXT",
"I_SERVICEDOCUMENTTYPE",
"I_SPECIALGLCODE",
"I_SRVCDOCBYDOCUMENTTYPE",
"I_SRVCDOCITEMBYDOCUMENTTYPE",
"I_SUPLRBANKDETAILSBYINTID",
"I_SUPPLIER",
"I_TAXCODE",
"I_TAXTYPE",
"I_UNITOFMEASURE",
"I_WBSELEMENTBYINTERNALKEY"
],
"BASE":
[
"FAC_DART_Z3_AP_LINEITEM_BASE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/