P_EBPAO_PCCProductionCost

@AbapCatalog: {
  compiler.compareFilter: true,
  sqlViewName: 'PEBPAOPCCPRDCST'
}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {
  serviceQuality: #D,
  sizeCategory: #XL,
  dataClass: #MIXED
}
@VDM: {
  private: true,
  viewType: #COMPOSITE
}
define view P_EBPAO_PCCProductionCost
  with parameters
    P_Ledger               : fins_ledger,
    P_FromFiscalYearPeriod : fins_fyearperiod,
    P_ToFiscalYearPeriod   : fins_fyearperiod,
    P_CurrencyRole         : fis_curtp
  as select from P_EBPAO_PCCProductionCost1( P_Ledger               : :P_Ledger,
                                             P_FromFiscalYearPeriod : :P_FromFiscalYearPeriod,
                                             P_ToFiscalYearPeriod   : :P_ToFiscalYearPeriod ) as ProductionCost
    inner join   I_LedgerCompanyCodeCrcyRoles                                                 as CurrencyRoles on  CurrencyRoles.CompanyCode = ProductionCost.CompanyCode
                                                                                                               and CurrencyRoles.Ledger      = :P_Ledger
{
  key ProductionCost.OrderID,
  key ProductionCost.CompanyCode,
  key ProductionCost.ControllingArea,
  key ProductionCost.Plant,
  key ProductionCost.ProfitCenter,
  key ProductionCost.OrderCategory,
  key ProductionCost.OrderType,
  key ProductionCost.StorageLocation,
  key ProductionCost.Product,
  key ProductionCost.ProductGroup,

      cast(
        case :P_CurrencyRole
           when CurrencyRoles.CompanyCodeCurrencyRole  then ProductionCost.AmountInCompanyCodeCurrency
           when CurrencyRoles.GlobalCurrencyRole       then ProductionCost.AmountInGlobalCurrency
           when CurrencyRoles.FreeDefinedCurrency1Role then ProductionCost.AmountInFreeDefinedCurrency1
           when CurrencyRoles.FreeDefinedCurrency2Role then ProductionCost.AmountInFreeDefinedCurrency2
           when CurrencyRoles.FreeDefinedCurrency3Role then ProductionCost.AmountInFreeDefinedCurrency3
           when CurrencyRoles.FreeDefinedCurrency4Role then ProductionCost.AmountInFreeDefinedCurrency4
           when CurrencyRoles.FreeDefinedCurrency5Role then ProductionCost.AmountInFreeDefinedCurrency5
           when CurrencyRoles.FreeDefinedCurrency6Role then ProductionCost.AmountInFreeDefinedCurrency6
           when CurrencyRoles.FreeDefinedCurrency7Role then ProductionCost.AmountInFreeDefinedCurrency7
           when CurrencyRoles.FreeDefinedCurrency8Role then ProductionCost.AmountInFreeDefinedCurrency8
         else 0
      end as fis_dr_actlcost_in_dspcrcy preserving type) as AmountInDisplayCurrency
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LEDGERCOMPANYCODECRCYROLES",
"P_EBPAO_PCCPRODUCTIONCOST1"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/