P_FixedAssetDepreciationList2

@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@VDM.private:true
@Metadata.ignorePropagatedAnnotations: true

define view entity P_FixedAssetDepreciationList2
  with parameters
    P_LedgerFiscalYear : fis_ryear,
    P_FiscalPeriod     : fis_poper

  as select from I_LedgerCompanyCodeCrcyRoles  as LedgerCompanyCodeCrcyRole
    inner join   I_FixedAssetLineItem          as Values                on  Values.CompanyCode = LedgerCompanyCodeCrcyRole.CompanyCode
                                                                        and Values.Ledger      = LedgerCompanyCodeCrcyRole.Ledger
    inner join   I_AssetKeyFigureSpecification as AssetKeyFigureSpec    on  AssetKeyFigureSpec.AssetAcctAnlytlTransClassfctn = Values.AssetAcctTransClassfctn
                                                                        and AssetKeyFigureSpec.SubLedgerAcctLineItemType     = Values.SubLedgerAcctLineItemType
    inner join   I_AssetKeyFigureSetSpec       as AssetKeyFigureSetSpec on AssetKeyFigureSetSpec.AssetAccountingKeyFigure = AssetKeyFigureSpec.AssetAccountingKeyFigure

{
  key Values.CompanyCode,
  key Values.AssetDepreciationArea,
  key Values.MasterFixedAsset,
  key Values.FixedAsset,
  key Values.Ledger,
  key Values.FiscalYear,
  key Values.FiscalPeriod,
  key Values.SubLedgerAcctLineItemType,
  key Values.AssetAcctTransClassfctn,
  key AssetKeyFigureSetSpec.AssetAccountingKeyFigure,
  key AssetKeyFigureSetSpec.AssetAccountingKeyFigureSet,
  key Values.AccountingDocument,
  key Values.LedgerGLLineItem,
  key Values.TransactionSubitem,
  key Values.DebitCreditCode,

      Values.ChartOfDepreciation,
      Values.ControllingArea,
      Values.Country,
      Values.FinancialManagementArea,
      Values.FiscalYearVariant,
      Values.LedgerFiscalYear,
      Values.PostingDate,

      Values.CompanyCodeCurrency,
      Values.GlobalCurrency,
      Values.FunctionalCurrency,
      Values.FreeDefinedCurrency1,
      Values.FreeDefinedCurrency2,
      Values.FreeDefinedCurrency3,
      Values.FreeDefinedCurrency4,
      Values.FreeDefinedCurrency5,
      Values.FreeDefinedCurrency6,
      Values.FreeDefinedCurrency7,
      Values.FreeDefinedCurrency8,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      Values.AmountInCompanyCodeCurrency,
      @Semantics.amount.currencyCode: 'GlobalCurrency'
      Values.AmountInGlobalCurrency,
      @Semantics.amount.currencyCode: 'FunctionalCurrency'
      Values.AmountInFunctionalCurrency,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency1'
      Values.AmountInFreeDefinedCurrency1,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency2'
      Values.AmountInFreeDefinedCurrency2,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency3'
      Values.AmountInFreeDefinedCurrency3,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency4'
      Values.AmountInFreeDefinedCurrency4,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency5'
      Values.AmountInFreeDefinedCurrency5,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency6'
      Values.AmountInFreeDefinedCurrency6,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency7'
      Values.AmountInFreeDefinedCurrency7,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency8'
      Values.AmountInFreeDefinedCurrency8,

      LedgerCompanyCodeCrcyRole.CompanyCodeCurrencyRole,
      LedgerCompanyCodeCrcyRole.GlobalCurrencyRole,
      LedgerCompanyCodeCrcyRole.FunctionalCurrencyRole,
      LedgerCompanyCodeCrcyRole.FreeDefinedCurrency1Role,
      LedgerCompanyCodeCrcyRole.FreeDefinedCurrency2Role,
      LedgerCompanyCodeCrcyRole.FreeDefinedCurrency3Role,
      LedgerCompanyCodeCrcyRole.FreeDefinedCurrency4Role,
      LedgerCompanyCodeCrcyRole.FreeDefinedCurrency5Role,
      LedgerCompanyCodeCrcyRole.FreeDefinedCurrency6Role,
      LedgerCompanyCodeCrcyRole.FreeDefinedCurrency7Role,
      LedgerCompanyCodeCrcyRole.FreeDefinedCurrency8Role
}
where
      Values.LedgerFiscalYear                    = $parameters.P_LedgerFiscalYear
  and Values.FiscalPeriod                        <= $parameters.P_FiscalPeriod
  and AssetKeyFigureSpec.PlannedValueIsInclusive <> '2'


union all select from I_LedgerCompanyCodeCrcyRoles  as LedgerCompanyCodeCrcyRole
  inner join          I_FixedAssetPlanValue         as Values                on  Values.CompanyCode = LedgerCompanyCodeCrcyRole.CompanyCode
                                                                             and Values.Ledger      = LedgerCompanyCodeCrcyRole.Ledger
  inner join          I_AssetKeyFigureSpecification as AssetKeyFigureSpec    on  AssetKeyFigureSpec.AssetAcctAnlytlTransClassfctn = Values.AssetAcctTransClassfctn
                                                                             and AssetKeyFigureSpec.SubLedgerAcctLineItemType     = Values.SubLedgerAcctLineItemType
  inner join          I_AssetKeyFigureSetSpec       as AssetKeyFigureSetSpec on AssetKeyFigureSetSpec.AssetAccountingKeyFigure = AssetKeyFigureSpec.AssetAccountingKeyFigure
  inner join          I_CompanyCode                 as CompanyCode           on CompanyCode.CompanyCode = Values.CompanyCode

{
  key Values.CompanyCode,
  key Values.AssetDepreciationArea,
  key Values.MasterFixedAsset,
  key Values.FixedAsset,
  key Values.Ledger,
  key Values.FiscalYear,
  key Values.FiscalPeriod,
  key Values.SubLedgerAcctLineItemType,
  key Values.AssetAcctTransClassfctn,
  key AssetKeyFigureSetSpec.AssetAccountingKeyFigure,
  key AssetKeyFigureSetSpec.AssetAccountingKeyFigureSet,
  key cast('' as fis_belnr)        as AccountingDocument,
  key cast('' as fis_docln)        as LedgerGLLineItem,
  key cast('000000' as fins_subta) as TransactionSubitem,
  key cast('' as shkzg)            as DebitCreditCode,

      Values.ChartOfDepreciation,
      CompanyCode.ControllingArea,
      CompanyCode.Country,
      CompanyCode.FinancialManagementArea,
      LedgerCompanyCodeCrcyRole.FiscalYearVariant,
      Values.LedgerFiscalYear,
      cast('00000000' as budat)    as PostingDate,

      Values.CompanyCodeCurrency,
      Values.GlobalCurrency,
      cast('' as fins_currfc)      as FunctionalCurrency,
      Values.FreeDefinedCurrency1,
      Values.FreeDefinedCurrency2,
      Values.FreeDefinedCurrency3,
      Values.FreeDefinedCurrency4,
      Values.FreeDefinedCurrency5,
      Values.FreeDefinedCurrency6,
      Values.FreeDefinedCurrency7,
      Values.FreeDefinedCurrency8,

      Values.AmountInCompanyCodeCurrency,
      Values.AmountInGlobalCurrency,
      cast(0 as fins_vfccur12)     as AmountInFunctionalCurrency,
      Values.AmountInFreeDefinedCurrency1,
      Values.AmountInFreeDefinedCurrency2,
      Values.AmountInFreeDefinedCurrency3,
      Values.AmountInFreeDefinedCurrency4,
      Values.AmountInFreeDefinedCurrency5,
      Values.AmountInFreeDefinedCurrency6,
      Values.AmountInFreeDefinedCurrency7,
      Values.AmountInFreeDefinedCurrency8,

      LedgerCompanyCodeCrcyRole.CompanyCodeCurrencyRole,
      LedgerCompanyCodeCrcyRole.GlobalCurrencyRole,
      LedgerCompanyCodeCrcyRole.FunctionalCurrencyRole,
      LedgerCompanyCodeCrcyRole.FreeDefinedCurrency1Role,
      LedgerCompanyCodeCrcyRole.FreeDefinedCurrency2Role,
      LedgerCompanyCodeCrcyRole.FreeDefinedCurrency3Role,
      LedgerCompanyCodeCrcyRole.FreeDefinedCurrency4Role,
      LedgerCompanyCodeCrcyRole.FreeDefinedCurrency5Role,
      LedgerCompanyCodeCrcyRole.FreeDefinedCurrency6Role,
      LedgerCompanyCodeCrcyRole.FreeDefinedCurrency7Role,
      LedgerCompanyCodeCrcyRole.FreeDefinedCurrency8Role
}
where
      AssetKeyFigureSpec.PlannedValueIsInclusive <> '0'
  and Values.LedgerFiscalYear                    = $parameters.P_LedgerFiscalYear
  and Values.FiscalPeriod                        <= $parameters.P_FiscalPeriod
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ASSETKEYFIGURESETSPEC",
"I_ASSETKEYFIGURESPECIFICATION",
"I_COMPANYCODE",
"I_FIXEDASSETLINEITEM",
"I_FIXEDASSETPLANVALUE",
"I_LEDGERCOMPANYCODECRCYROLES"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/