FAC_DART_Z3_MATLINVTRY_LINEITM

@AbapCatalog.sqlViewName: 'FAC_DZMILNITM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@EndUserText.label: 'Material Inventory Line Item'

define view FAC_DART_Z3_MATLINVTRY_LINEITM 
  with parameters
    P_FiscalYear       : fins_gjahr,

    @EndUserText.label: 'From Fiscal Period' 
    P_FromFiscalPeriod : fins_fagl_fiscper_from,
    @EndUserText.label: 'To Fiscal Period' 
    P_ToFiscalPeriod   : fins_fagl_fiscper_to
    
  as select from FAC_DART_Z3_MI_LINEITEM_BASE
  inner join I_LedgerCompanyCodeCrcyRoles on FAC_DART_Z3_MI_LINEITEM_BASE.CompanyCode = I_LedgerCompanyCodeCrcyRoles.CompanyCode
                                          and FAC_DART_Z3_MI_LINEITEM_BASE.Ledger = I_LedgerCompanyCodeCrcyRoles.Ledger
  association [0..1] to I_AccountingDocumentType     as _AccountingDocumentType     on  $projection.AccountingDocumentType = _AccountingDocumentType.AccountingDocumentType
  
  association [1]    to I_JournalEntry               as _JournalEntry               on  $projection.CompanyCode = _JournalEntry.CompanyCode
                                                                                    and $projection.FiscalYear  = _JournalEntry.FiscalYear
                                                                                    and $projection.AccountingDocument  = _JournalEntry.AccountingDocument
  association [0..1] to I_ReferenceDocumentType        as _ReferenceDocumentType         on  $projection.ReferenceDocumentType = _ReferenceDocumentType.ReferenceDocumentType
  
  association [0..1] to I_FiscalPeriodForVariant as _FromFiscalYearPeriod     on  _FromFiscalYearPeriod.FiscalYearVariant = $projection.FiscalYearVariant
                                                                       and _FromFiscalYearPeriod.FiscalYear        = $parameters.P_FiscalYear
                                                                       and _FromFiscalYearPeriod.FiscalPeriod      = $parameters.P_FromFiscalPeriod
                                                                                 
  association [0..1] to I_FiscalPeriodForVariant as _ToFiscalYearPeriod      on  _ToFiscalYearPeriod.FiscalYearVariant = $projection.FiscalYearVariant
                                                                      and _ToFiscalYearPeriod.FiscalYear        = $parameters.P_FiscalYear
                                                                      and _ToFiscalYearPeriod.FiscalPeriod      = $parameters.P_ToFiscalPeriod
{
  key SourceLedger,
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key FAC_DART_Z3_MI_LINEITEM_BASE.CompanyCode,
  key FAC_DART_Z3_MI_LINEITEM_BASE.Ledger,
      @ObjectModel.foreignKey.association: '_GLAccountInChartOfAccounts'
  key GLAccount,
      @Semantics.fiscal.year: true
  key FiscalYear,
      @ObjectModel.foreignKey.association: '_JournalEntry'
  key AccountingDocument,
  key LedgerGLLineItem,
      @ObjectModel.foreignKey.association: '_Material'
  key Material,
  
      I_LedgerCompanyCodeCrcyRoles.FiscalYearVariant as FiscalYearVariant,
      @ObjectModel.foreignKey.association: '_ChartOfAccounts'
      FAC_DART_Z3_MI_LINEITEM_BASE.ChartOfAccounts,
      _GLAccountInChartOfAccounts._Text[1: Language = $session.system_language].GLAccountLongName,
      _Material._Text[1: Language = $session.system_language].MaterialName,
      @ObjectModel.foreignKey.association: '_MaterialGroup'
      MaterialGroup,
      _MaterialGroup._Text[1: Language = $session.system_language].MaterialGroupName,
      PostingDate,
      @ObjectModel.foreignKey.association: '_Plant'
      Plant,
      _Plant.PlantName,
      
      @Semantics.fiscal.period: true
      FiscalPeriod,

      _JournalEntry.AccountingDocumentCategory as AccountingDocumentCategory,
      @ObjectModel.foreignKey.association: '_AccountingDocumentType'
      AccountingDocumentType,
      _AccountingDocumentType._Text[1: Language = $session.system_language].AccountingDocumentTypeName,
      _JournalEntry.OriginalReferenceDocument,
      @ObjectModel.foreignKey.association: '_ReferenceDocumentType'
      ReferenceDocumentType,
      _ReferenceDocumentType._Text[1: Language = $session.system_language ].ReferenceDocumentTypeName,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      AmountInCompanyCodeCurrency,
      @Semantics.currencyCode:true
      CompanyCodeCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
      InventoryQty,
      @Semantics.unitOfMeasure:true
      BaseUnit,
      ValuationArea,
      FAC_DART_Z3_MI_LINEITEM_BASE._CompanyCode,
      MaterialDocument,
      MaterialDocumentYear,
      _MaterialDocumentHeader.InventoryTransactionType,
      _JournalEntry.DocumentDate,
      _JournalEntry.AccountingDocumentHeaderText,
      _JournalEntry.AccountingDocumentCreationDate,
      _JournalEntry.AccountingDocCreatedByUser,
      _GLAccountInChartOfAccounts,
      _JournalEntry,
      _Material,
      FAC_DART_Z3_MI_LINEITEM_BASE._ChartOfAccounts,
      _MaterialGroup,
      _Plant,
      _AccountingDocumentType,
      _ReferenceDocumentType,
      _MaterialDocumentHeader
}
where
      _JournalEntry.AccountingDocumentCategory <> 'D'
  and _JournalEntry.AccountingDocumentCategory <> 'M'
  and _JournalEntry.AccountingDocumentCategory <> 'S'
  and _JournalEntry.AccountingDocumentCategory <> 'V'
  and _JournalEntry.AccountingDocumentCategory <> 'W'
  and _JournalEntry.AccountingDocumentCategory <> 'Z'
  and _JournalEntry.AccountingDocumentCategory <> 'T'
  and PostingDate <= _ToFiscalYearPeriod.FiscalPeriodEndDate
  and PostingDate >= _FromFiscalYearPeriod.FiscalPeriodStartDate
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FAC_DART_Z3_MI_LINEITEM_BASE",
"I_ACCOUNTINGDOCUMENTTYPE",
"I_ACCOUNTINGDOCUMENTTYPETEXT",
"I_FISCALPERIODFORVARIANT",
"I_GLACCOUNTINCHARTOFACCOUNTS",
"I_GLACCOUNTTEXT",
"I_JOURNALENTRY",
"I_LEDGERCOMPANYCODECRCYROLES",
"I_MATERIAL",
"I_MATERIALDOCUMENTHEADER",
"I_MATERIALGROUP",
"I_MATERIALGROUPTEXT",
"I_MATERIALTEXT",
"I_PLANT",
"I_REFERENCEDOCUMENTTYPE",
"I_REFERENCEDOCUMENTTYPETEXT"
],
"ASSOCIATED":
[
"I_ACCOUNTINGDOCUMENTTYPE",
"I_CHARTOFACCOUNTS",
"I_COMPANYCODE",
"I_FISCALPERIODFORVARIANT",
"I_GLACCOUNTINCHARTOFACCOUNTS",
"I_JOURNALENTRY",
"I_MATERIAL",
"I_MATERIALDOCUMENTHEADER",
"I_MATERIALGROUP",
"I_PLANT",
"I_REFERENCEDOCUMENTTYPE"
],
"BASE":
[
"FAC_DART_Z3_MI_LINEITEM_BASE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/