P_EBOC_OrderPlanCost2

@AbapCatalog.sqlViewName: 'PEBOCPLNCST2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #COMPOSITE
@VDM.private: true

define view P_EBOC_OrderPlanCost2
  with parameters
    P_OrderID              : fis_order_number,
    P_FromFiscalYearPeriod : fis_jahrper,
    P_ToFiscalYearPeriod   : fis_jahrper,
    P_Ledger               : fins_ledger,
    P_CurrencyRole         : fac_crcyrole
  as select from P_EBOC_OrderPlanCost1( P_OrderID              : :P_OrderID,
                                        P_FromFiscalYearPeriod : :P_FromFiscalYearPeriod,
                                        P_ToFiscalYearPeriod   : :P_ToFiscalYearPeriod,
                                        P_Ledger               : :P_Ledger ) as _Costs
    inner join   I_MfgOrdPlngCat                                             as _PlngCat                   on  _Costs.PlanningCategory              = _PlngCat.PlanningCategory
                                                                                                           and _PlngCat.PlngCatIsForOrdReltdPlnCost = 'X'
    inner join   I_LedgerCompanyCodeCrcyRoles                                as _LedgerCompanyCodeCrcyRole on  _LedgerCompanyCodeCrcyRole.CompanyCode = _Costs.CompanyCode
                                                                                                           and _LedgerCompanyCodeCrcyRole.Ledger      = :P_Ledger
{
  key _Costs.CompanyCode,
  key Plant,
  key ControllingArea,
  key _Costs.PlanningCategory,
  key CostElement,
  key BusinessTransactionCategory,
  key ControllingDebitCreditCode,
  key CtrlgOriginClassification,
  key OrderID,
  key OrderItem,
  key AccountAssignmentType,
  key PartnerAccountAssignmentType,
  key PartnerCostCenter,
  key PartnerCostCtrActivityType,
  key PartnerOrder,
  key UnitOfMeasure,
  key Material,
  key IsLotSizeIndependent,
  key _Costs.CostOriginGroup,
  key OriginCostCenter,
  key OriginCostCtrActivityType,

      cast(
        case :P_CurrencyRole
           when CompanyCodeCurrencyRole  then AmountInCompanyCodeCurrency
           when GlobalCurrencyRole       then AmountInGlobalCurrency
           when FreeDefinedCurrency1Role then AmountInFreeDefinedCurrency1
           when FreeDefinedCurrency2Role then AmountInFreeDefinedCurrency2
           when FreeDefinedCurrency3Role then AmountInFreeDefinedCurrency3
           when FreeDefinedCurrency4Role then AmountInFreeDefinedCurrency4
           when FreeDefinedCurrency5Role then AmountInFreeDefinedCurrency5
           when FreeDefinedCurrency6Role then AmountInFreeDefinedCurrency6
           when FreeDefinedCurrency7Role then AmountInFreeDefinedCurrency7
           when FreeDefinedCurrency8Role then AmountInFreeDefinedCurrency8
         else 0
      end as farp_amount_display_crcy) as AmountInDisplayCurrency,

      // Cost Rate for Fixed Amount

      cast(
        (case
           when AmountInGlobalCurrency <> 0
             then division(FixedAmountInGlobalCrcy, AmountInGlobalCurrency, 8)
           else 0
         end) as abap.dec(14, 8)
      )                                as CostRateFixedAmount,

      Quantity
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LEDGERCOMPANYCODECRCYROLES",
"I_MFGORDPLNGCAT",
"P_EBOC_ORDERPLANCOST1"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/