FAA_UPA_MIG_BAL_DOC

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Asset documents'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
define view entity FAA_UPA_MIG_BAL_DOC
  as select from acdoca                       as acdoca
    inner join   I_LedgerCompanyCodeCrcyRoles as LedgerCompanyCodeCrcyRoles on  acdoca.rbukrs = LedgerCompanyCodeCrcyRoles.CompanyCode
                                                                            and acdoca.rldnr  = LedgerCompanyCodeCrcyRoles.Ledger
{
  key  acdoca.rbukrs                                             as CompanyCode,
  key  acdoca.anln1                                              as MasterFixedAsset,
  key  acdoca.anln2                                              as FixedAsset,
  key  acdoca.gjahr                                              as FiscalYear,
  key  cast(acdoca.belnr  as fis_belnr preserving type)          as AccountingDocument,
  key  cast(acdoca.docln  as fis_docln preserving type)          as LedgerGLLineItem,
  key  acdoca.subta                                              as TransactionSubitem,
  key  acdoca.afabe                                              as AssetDepreciationArea,
  key  cast(acdoca.slalittype as fis_slalittype preserving type) as SubLedgerAcctLineItemType,
  key  acdoca.poper                                              as FiscalPeriod,
  key  acdoca.rldnr                                              as Ledger,
  key  acdoca.drcrk                                              as DebitCreditCode,
       cast(acdoca.awtyp as fis_awtyp preserving type)           as ReferenceDocumentType,
       acdoca.awref                                              as ReferenceDocument,
       acdoca.aworg                                              as ReferenceDocumentContext,
       acdoca.awsys                                              as LogicalSystem,
       acdoca.movcat                                             as AssetAcctTransClassfctn,
       acdoca.depr_period                                        as DepreciationFiscalPeriod,
       //Measures

       LedgerCompanyCodeCrcyRoles.CompanyCodeCurrencyRole,
       acdoca.rhcur                                              as CompanyCodeCurrency,
       @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
       acdoca.hsl                                                as AmountInCompanyCodeCurrency,

       LedgerCompanyCodeCrcyRoles.GlobalCurrencyRole,
       acdoca.rkcur                                              as GlobalCurrency,
       @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
       acdoca.ksl                                                as AmountInGlobalCurrency,

       LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency1Role,
       acdoca.rocur                                              as FreeDefinedCurrency1,
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
       acdoca.osl                                                as AmountInFreeDefinedCurrency1,

       LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency2Role,
       acdoca.rvcur                                              as FreeDefinedCurrency2,
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
       acdoca.vsl                                                as AmountInFreeDefinedCurrency2,

       LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency3Role,
       acdoca.rbcur                                              as FreeDefinedCurrency3,
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
       acdoca.bsl                                                as AmountInFreeDefinedCurrency3,

       LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency4Role,
       acdoca.rccur                                              as FreeDefinedCurrency4,
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
       acdoca.csl                                                as AmountInFreeDefinedCurrency4,

       LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency5Role,
       acdoca.rdcur                                              as FreeDefinedCurrency5,
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
       acdoca.dsl                                                as AmountInFreeDefinedCurrency5,

       LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency6Role,
       acdoca.recur                                              as FreeDefinedCurrency6,
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
       acdoca.esl                                                as AmountInFreeDefinedCurrency6,

       LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency7Role,
       acdoca.rfcur                                              as FreeDefinedCurrency7,
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
       acdoca.fsl                                                as AmountInFreeDefinedCurrency7,

       LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency8Role,
       acdoca.rgcur                                              as FreeDefinedCurrency8,
       @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
       acdoca.gsl                                                as AmountInFreeDefinedCurrency8
}
// Restrict the line items to line items related to asset accounting

where
     acdoca.slalittype between '07000' and '07209'
  or
  //Additionaly for the transaction list of asset accounting

     acdoca.slalittype between '07900' and '07906'
  or acdoca.slalittype =       '07940'

union all select from acdoca                       as acdoca
  inner join          I_TechnicalLedger            as TechnicalLedger            on acdoca.rldnr = TechnicalLedger.TechnicalLedger
  inner join          I_LedgerCompanyCodeCrcyRoles as LedgerCompanyCodeCrcyRoles on  TechnicalLedger.Ledger = LedgerCompanyCodeCrcyRoles.Ledger
                                                                                 and acdoca.rbukrs          = LedgerCompanyCodeCrcyRoles.CompanyCode
{
  key  acdoca.rbukrs                                             as CompanyCode,
  key  acdoca.anln1                                              as MasterFixedAsset,
  key  acdoca.anln2                                              as FixedAsset,
  key  acdoca.gjahr                                              as FiscalYear,
  key  cast(acdoca.belnr  as fis_belnr preserving type)          as AccountingDocument,
  key  cast(acdoca.docln  as fis_docln preserving type)          as LedgerGLLineItem,
  key  acdoca.subta                                              as TransactionSubitem,
  key  acdoca.afabe                                              as AssetDepreciationArea,
  key  cast(acdoca.slalittype as fis_slalittype preserving type) as SubLedgerAcctLineItemType,
  key  acdoca.poper                                              as FiscalPeriod,
  key  TechnicalLedger.Ledger                                    as Ledger,
  key  acdoca.drcrk                                              as DebitCreditCode,
       cast(acdoca.awtyp as fis_awtyp preserving type)           as ReferenceDocumentType,
       acdoca.awref                                              as ReferenceDocument,
       acdoca.aworg                                              as ReferenceDocumentContext,
       acdoca.awsys                                              as LogicalSystem,
       acdoca.movcat                                             as AssetAcctTransClassfctn,
       acdoca.depr_period                                        as DepreciationFiscalPeriod,
       //Measures

       LedgerCompanyCodeCrcyRoles.CompanyCodeCurrencyRole,
       acdoca.rhcur                                              as CompanyCodeCurrency,
       acdoca.hsl                                                as AmountInCompanyCodeCurrency,

       LedgerCompanyCodeCrcyRoles.GlobalCurrencyRole,
       acdoca.rkcur                                              as GlobalCurrency,
       acdoca.ksl                                                as AmountInGlobalCurrency,

       LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency1Role,
       acdoca.rocur                                              as FreeDefinedCurrency1,
       acdoca.osl                                                as AmountInFreeDefinedCurrency1,

       LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency2Role,
       acdoca.rvcur                                              as FreeDefinedCurrency2,
       acdoca.vsl                                                as AmountInFreeDefinedCurrency2,

       LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency3Role,
       acdoca.rbcur                                              as FreeDefinedCurrency3,
       acdoca.bsl                                                as AmountInFreeDefinedCurrency3,

       LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency4Role,
       acdoca.rccur                                              as FreeDefinedCurrency4,
       acdoca.csl                                                as AmountInFreeDefinedCurrency4,

       LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency5Role,
       acdoca.rdcur                                              as FreeDefinedCurrency5,
       acdoca.dsl                                                as AmountInFreeDefinedCurrency5,

       LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency6Role,
       acdoca.recur                                              as FreeDefinedCurrency6,
       acdoca.esl                                                as AmountInFreeDefinedCurrency6,

       LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency7Role,
       acdoca.rfcur                                              as FreeDefinedCurrency7,
       acdoca.fsl                                                as AmountInFreeDefinedCurrency7,

       LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency8Role,
       acdoca.rgcur                                              as FreeDefinedCurrency8,
       acdoca.gsl                                                as AmountInFreeDefinedCurrency8
}
// Restrict the line items to line items related to asset accounting

where
     acdoca.slalittype between '07000' and '07209'
  or
  //Additionaly for the transaction list of asset accounting

     acdoca.slalittype between '07900' and '07906'
  or acdoca.slalittype =       '07940'

union all select from faat_doc_it                  as docit
  inner join          I_LedgerGroupAssignment      as LedgerGroupAssignment      on  docit.ldgrp                                  = LedgerGroupAssignment.LedgerGroup
                                                                                 and LedgerGroupAssignment.IsRepresentativeLedger = 'X'
  inner join          I_LedgerCompanyCodeCrcyRoles as LedgerCompanyCodeCrcyRoles on  LedgerGroupAssignment.Ledger = LedgerCompanyCodeCrcyRoles.Ledger
                                                                                 and docit.bukrs                  = LedgerCompanyCodeCrcyRoles.CompanyCode
{
  key docit.bukrs                                              as CompanyCode,
  key docit.anln1                                              as MasterFixedAsset,
  key docit.anln2                                              as FixedAsset,
  key docit.gjahr                                              as FiscalYear,
  key cast('' as fis_belnr)                                    as AccountingDocument,
  key cast('' as fis_docln)                                    as LedgerGLLineItem,
  key docit.subta                                              as TransactionSubitem,
  key docit.afabe                                              as AssetDepreciationArea,
  key cast(docit.slalittype as fis_slalittype preserving type) as SubLedgerAcctLineItemType,
  key docit.poper                                              as FiscalPeriod,
  key LedgerGroupAssignment.Ledger                             as Ledger,
  key docit.drcrk                                              as DebitCreditCode,
      cast(docit.awtyp as fis_awtyp)                           as ReferenceDocumentType,
      docit.awref                                              as ReferenceDocument,
      docit.aworg                                              as ReferenceDocumentContext,
      docit.awsys                                              as LogicalSystem,
      docit.movcat                                             as AssetAcctTransClassfctn,
      cast('000' as fis_peraf)                                 as DepreciationFiscalPeriod,
      //Measures

      LedgerCompanyCodeCrcyRoles.CompanyCodeCurrencyRole,
      docit.rhcur                                              as CompanyCodeCurrency,
      docit.hsl                                                as AmountInCompanyCodeCurrency,

      LedgerCompanyCodeCrcyRoles.GlobalCurrencyRole,
      docit.rkcur                                              as GlobalCurrency,
      docit.ksl                                                as AmountInGlobalCurrency,

      LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency1Role,
      docit.rocur                                              as FreeDefinedCurrency1,
      docit.osl                                                as AmountInFreeDefinedCurrency1,

      LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency2Role,
      docit.rvcur                                              as FreeDefinedCurrency2,
      docit.vsl                                                as AmountInFreeDefinedCurrency2,

      LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency3Role,
      docit.rbcur                                              as FreeDefinedCurrency3,
      docit.bsl                                                as AmountInFreeDefinedCurrency3,

      LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency4Role,
      docit.rccur                                              as FreeDefinedCurrency4,
      docit.csl                                                as AmountInFreeDefinedCurrency4,

      LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency5Role,
      docit.rdcur                                              as FreeDefinedCurrency5,
      docit.dsl                                                as AmountInFreeDefinedCurrency5,

      LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency6Role,
      docit.recur                                              as FreeDefinedCurrency6,
      docit.esl                                                as AmountInFreeDefinedCurrency6,

      LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency7Role,
      docit.rfcur                                              as FreeDefinedCurrency7,
      docit.fsl                                                as AmountInFreeDefinedCurrency7,

      LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency8Role,
      docit.rgcur                                              as FreeDefinedCurrency8,
      docit.gsl                                                as AmountInFreeDefinedCurrency8
}
where
  (
    (
          docit.vorgn      <>      'AFAB'
      and docit.movcat     <>      '06'
      and not(
        docit.slalittype   between '07203' and '07209'
      )
    )
    or(
          docit.movcat     =       '00'
    )
  )
  //Exclude FAAT_DOC_IT records which are migrated to ACDOCA

  and     docit.sdm_status <>      '18'
  and     docit.sdm_status <>      '19'
  and     docit.sdm_status <>      '22'
  and     docit.sdm_status <>      '1A'

union all select from faat_plan_values             as duevalues
  inner join          I_LedgerCompanyCodeCrcyRoles as LedgerCompanyCodeCrcyRoles on  duevalues.bukrs = LedgerCompanyCodeCrcyRoles.CompanyCode
                                                                                 and duevalues.rldnr = LedgerCompanyCodeCrcyRoles.Ledger
{
  key duevalues.bukrs                                              as CompanyCode,
  key duevalues.anln1                                              as MasterFixedAsset,
  key duevalues.anln2                                              as FixedAsset,
  key duevalues.gjahr                                              as FiscalYear,
  key cast('' as fis_belnr)                                        as AccountingDocument,
  key cast('' as fis_docln)                                        as LedgerGLLineItem,
  key cast( '000000' as fins_subta preserving type )               as TransactionSubitem,
  key duevalues.afabe                                              as AssetDepreciationArea,
  key cast(duevalues.slalittype as fis_slalittype preserving type) as SubLedgerAcctLineItemType,
  key duevalues.poper                                              as FiscalPeriod,
  key duevalues.rldnr                                              as ledger,
  key cast( '' as shkzg preserving type )                          as DebitCreditCode,
      cast( '' as fis_awtyp )                                      as ReferenceDocumentType,
      cast( '' as awref )                                          as ReferenceDocument,
      cast( '' as fis_aworg )                                      as ReferenceDocumentContext,
      cast( '' as logsystem )                                      as LogicalSystem,
      duevalues.movcat                                             as AssetAcctTransClassfctn,
      cast( '000' as fis_peraf preserving type )                   as DepreciationFiscalPeriod,
      //Measures

      LedgerCompanyCodeCrcyRoles.CompanyCodeCurrencyRole,
      duevalues.rhcur                                              as CompanyCodeCurrency,
      duevalues.hsl                                                as AmountInCompanyCodeCurrency,

      LedgerCompanyCodeCrcyRoles.GlobalCurrencyRole,
      duevalues.rkcur                                              as GlobalCurrency,
      duevalues.ksl                                                as AmountInGlobalCurrency,

      LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency1Role,
      duevalues.rocur                                              as FreeDefinedCurrency1,
      duevalues.osl                                                as AmountInFreeDefinedCurrency1,

      LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency2Role,
      duevalues.rvcur                                              as FreeDefinedCurrency2,
      duevalues.vsl                                                as AmountInFreeDefinedCurrency2,

      LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency3Role,
      duevalues.rbcur                                              as FreeDefinedCurrency3,
      duevalues.bsl                                                as AmountInFreeDefinedCurrency3,

      LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency4Role,
      duevalues.rccur                                              as FreeDefinedCurrency4,
      duevalues.csl                                                as AmountInFreeDefinedCurrency4,

      LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency5Role,
      duevalues.rdcur                                              as FreeDefinedCurrency5,
      duevalues.dsl                                                as AmountInFreeDefinedCurrency5,

      LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency6Role,
      duevalues.recur                                              as FreeDefinedCurrency6,
      duevalues.esl                                                as AmountInFreeDefinedCurrency6,

      LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency7Role,
      duevalues.rfcur                                              as FreeDefinedCurrency7,
      duevalues.fsl                                                as AmountInFreeDefinedCurrency7,

      LedgerCompanyCodeCrcyRoles.FreeDefinedCurrency8Role,
      duevalues.rgcur                                              as FreeDefinedCurrency8,
      duevalues.gsl                                                as AmountInFreeDefinedCurrency8
}
where
  duevalues.movcat = '00'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LEDGERCOMPANYCODECRCYROLES",
"I_LEDGERGROUPASSIGNMENT",
"I_TECHNICALLEDGER",
"ACDOCA",
"FAAT_DOC_IT",
"FAAT_PLAN_VALUES"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/