P_MfgOrderEvtBsdVariance2

@AbapCatalog.sqlViewName: 'PMFGORDEBVARC2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@VDM.private: true
define view P_MfgOrderEvtBsdVariance2 
  with parameters
    P_Ledger               : fins_ledger,
    P_FromFiscalYearPeriod : fins_fyearperiod,
    P_ToFiscalYearPeriod   : fins_fyearperiod,
    P_CurrencyRole         : fac_crcyrole
  as select from P_MfgOrderEvtBsdVariance1( P_Ledger               : :P_Ledger,
                                            P_FromFiscalYearPeriod : :P_FromFiscalYearPeriod,
                                            P_ToFiscalYearPeriod   : :P_ToFiscalYearPeriod ) as _VarianceCost
    inner join   I_LedgerCompanyCodeCrcyRoles                                                as _LedgerCompanyCodeCrcyRole on  _LedgerCompanyCodeCrcyRole.CompanyCode = _VarianceCost.CompanyCode
                                                                                                                           and _LedgerCompanyCodeCrcyRole.Ledger      = :P_Ledger
{
  key _VarianceCost.Ledger,
  key _VarianceCost.CompanyCode,
  key _VarianceCost.OrderID,
  key _VarianceCost.OrderItem,
  key _VarianceCost.ChartOfAccounts,
  key _VarianceCost.GLAccount,
  key _VarianceCost.OriginProduct,
  key _VarianceCost.OriginCostCenter,
  key _VarianceCost.OriginCostCtrActivityType,
  key _VarianceCost.SubLedgerAcctLineItemType,
  key cast('31' as co_wrttp)           as ControllingValueType, // '31' = Variance


      cast(
        case :P_CurrencyRole
           when _LedgerCompanyCodeCrcyRole.CompanyCodeCurrencyRole  then _VarianceCost.AmountInCompanyCodeCurrency
           when _LedgerCompanyCodeCrcyRole.GlobalCurrencyRole       then _VarianceCost.AmountInGlobalCurrency
           when _LedgerCompanyCodeCrcyRole.FreeDefinedCurrency1Role then _VarianceCost.AmountInFreeDefinedCurrency1
           when _LedgerCompanyCodeCrcyRole.FreeDefinedCurrency2Role then _VarianceCost.AmountInFreeDefinedCurrency2
           when _LedgerCompanyCodeCrcyRole.FreeDefinedCurrency3Role then _VarianceCost.AmountInFreeDefinedCurrency3
           when _LedgerCompanyCodeCrcyRole.FreeDefinedCurrency4Role then _VarianceCost.AmountInFreeDefinedCurrency4
           when _LedgerCompanyCodeCrcyRole.FreeDefinedCurrency5Role then _VarianceCost.AmountInFreeDefinedCurrency5
           when _LedgerCompanyCodeCrcyRole.FreeDefinedCurrency6Role then _VarianceCost.AmountInFreeDefinedCurrency6
           when _LedgerCompanyCodeCrcyRole.FreeDefinedCurrency7Role then _VarianceCost.AmountInFreeDefinedCurrency7
           when _LedgerCompanyCodeCrcyRole.FreeDefinedCurrency8Role then _VarianceCost.AmountInFreeDefinedCurrency8
         else 0
      end as farp_amount_display_crcy) as AmountInDisplayCurrency
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LEDGERCOMPANYCODECRCYROLES",
"P_MFGORDEREVTBSDVARIANCE1"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/