I_FiscalCalendarDateForLedger

@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'IFIFISCCAL4L'
@AbapCatalog.compiler.compareFilter: true

@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Fiscal Calendar Dates for Ledger'
@VDM.viewType: #COMPOSITE

@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MASTER

@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.representativeKey: 'CalendarDate'
//@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }

@Analytics: { dataCategory: #DIMENSION }
//--[ GENERATED:012:29JlHNUf7jY4ip0dSlCN8W

//@AccessControl.privilegedAssociations: ['_ControllingAreaText','_LedgerText']

// ]--GENERATED


@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, 
                                     #CDS_MODELING_ASSOCIATION_TARGET, 
                                     #CDS_MODELING_DATA_SOURCE,
                                     #SQL_DATA_SOURCE]
                                     
define view I_FiscalCalendarDateForLedger as select from I_FiscalCalendarDate inner join I_LedgerCompanyCodeCrcyRoles 
                                                    on   I_FiscalCalendarDate.FiscalYearVariant = I_LedgerCompanyCodeCrcyRoles.FiscalYearVariant


  //--[ GENERATED:012:29JlHNUf7jY4ip0dSlCN8W

  association [0..1] to I_ControllingArea      as _ControllingAreaText   on  $projection.ControllingArea   = _ControllingAreaText.ControllingArea
  association [0..*] to I_LedgerText           as _LedgerText            on  $projection.Ledger            = _LedgerText.Ledger
  // ]--GENERATED

  association [0..1] to I_CompanyCode          as _CompanyCode           on  $projection.CompanyCode       = _CompanyCode.CompanyCode
  association [0..1] to I_Ledger               as _Ledger                on  $projection.Ledger            = _Ledger.Ledger
  association [0..1] to I_ControllingArea      as _ControllingArea       on  $projection.ControllingArea   = _ControllingArea.ControllingArea
  association [0..*] to I_FiscalYearPeriodText as _Text                  on  $projection.FiscalYearVariant = _Text.FiscalYearVariant
                                                                         and $projection.FiscalYear        = _Text.FiscalYear
                                                                         and $projection.FiscalPeriod      = _Text.FiscalPeriod
  association [0..1] to I_FiscalYear           as _FiscalYear            on  $projection.FiscalYearVariant = _FiscalYear.FiscalYearVariant
                                                                         and $projection.FiscalYear        = _FiscalYear.FiscalYear

{
  
//@ObjectModel.foreignKey.association: '_CalendarDate'      

key CalendarDate,
      //--[ GENERATED:012:29JlHNUf7jY4ip0dSlCN8W

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_CompanyCodeStdVH',
                     element: 'CompanyCode' }
        }]
      // ]--GENERATED

@ObjectModel.foreignKey.association: '_CompanyCode'      
key cast( CompanyCode as fis_bukrs preserving type ) as CompanyCode,
      //--[ GENERATED:012:29JlHNUf7jY4ip0dSlCN8W

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_LedgerStdVH',
                     element: 'Ledger' }
        }]
      @ObjectModel.text.association: '_LedgerText'
      // ]--GENERATED

@ObjectModel.foreignKey.association: '_Ledger'      
key cast( Ledger as fis_rldnr preserving type ) as Ledger,

@ObjectModel.foreignKey.association: '_FiscalYearVariant'      
    I_FiscalCalendarDate.FiscalYearVariant,
      //--[ GENERATED:012:29JlHNUf7jY4ip0dSlCN8W

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_ControllingAreaStdVH',
                     element: 'ControllingArea' }
        }]
      @ObjectModel.text.association: '_ControllingAreaText'
      // ]--GENERATED

@ObjectModel.foreignKey.association: '_ControllingArea' 
    _CompanyCode.ControllingArea as ControllingArea,
    
@ObjectModel.foreignKey.association: '_FiscalYear'      
    FiscalYear,
    FiscalYearStartDate,
    FiscalYearEndDate,
        
@ObjectModel.text.association: '_Text'
    FiscalPeriod,
    FiscalPeriodStartDate,
    FiscalPeriodEndDate,

    FiscalQuarter,
    FiscalQuarterStartDate,
    FiscalQuarterEndDate,

    FiscalWeek,
    FiscalWeekStartDate,
    FiscalWeekEndDate,
     
    FiscalYearPeriod,
    FiscalYearQuarter,
    FiscalYearWeek,
    
    FiscalYearConsecutiveNumber,
    FiscalPeriodConsecutiveNumber,
    FiscalQuarterConsecutiveNumber,
    FiscalWeekConsecutiveNumber,
    
    I_FiscalCalendarDate._FiscalYearVariant,
    _CompanyCode,
    _Ledger,
    _ControllingArea,
    _CalendarDate,
    _FiscalYear,
    _Text    ,
      //--[ GENERATED:012:29JlHNUf7jY4ip0dSlCN8W

      @Consumption.hidden: true
      _ControllingAreaText,
      @Consumption.hidden: true
      _LedgerText
      // ]--GENERATED


          
}            
 

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_FISCALCALENDARDATE",
"I_LEDGERCOMPANYCODECRCYROLES"
],
"ASSOCIATED":
[
"I_CALENDARDATE",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_FISCALYEAR",
"I_FISCALYEARPERIODTEXT",
"I_FISCALYEARVARIANT",
"I_LEDGER",
"I_LEDGERTEXT"
],
"BASE":
[
"I_FISCALCALENDARDATE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/