FAC_DART_Z3_GLACCOUNT_CHGDOC

@AbapCatalog.sqlViewName: 'FAC_DZGLDCHGD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.dataClass:  #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'G/L account change document'
define view FAC_DART_Z3_GLACCOUNT_CHGDOC
  with parameters
    //    P_CompanyCode      : bukrs,

    P_Ledger           : fins_ledger,
    P_FiscalYear       : fins_gjahr,
    @EndUserText.label: 'From Fiscal Period'
    P_FromFiscalPeriod : fins_fagl_fiscper_from,
    @EndUserText.label: 'To Fiscal Period'
    P_ToFiscalPeriod   : fins_fagl_fiscper_to,
    @Consumption.hidden: true
    @Environment.systemField: #SYSTEM_LANGUAGE
    P_Language         : sylangu
  as select from    FAC_DART_Z3_GLACCOUNT_CHGDOC_B as _glaccount_chlog
    left outer join I_LedgerCompanyCodeCrcyRoles on  I_LedgerCompanyCodeCrcyRoles.CompanyCode = _glaccount_chlog.CompanyCode
                                                 and I_LedgerCompanyCodeCrcyRoles.Ledger      = $parameters.P_Ledger

  association [0..*] to I_ChangeLogDatabaseTableText as _ChangeLogDatabaseTableText on  _glaccount_chlog.DatabaseTable = _ChangeLogDatabaseTableText.DatabaseTable
  association [0..*] to I_ChangeDocFieldNames        as _ChangeDocFieldNames        on  _glaccount_chlog.DatabaseTable               = _ChangeDocFieldNames.DatabaseTable
                                                                                    and _glaccount_chlog.ChangeDocDatabaseTableField = _ChangeDocFieldNames.Value
  association [0..*] to I_ChgDocItemChangeTypeText   as _ChgDocItemChangeTypeText   on  _glaccount_chlog.ChangeDocItemChangeType = _ChgDocItemChangeTypeText.ChangeDocItemChangeType
  association [0..1] to I_FiscalPeriodForVariant     as _ToFiscalPeriodForVariant   on  _ToFiscalPeriodForVariant.FiscalYearVariant = $projection.FiscalYearVariant
                                                                                    and _ToFiscalPeriodForVariant.FiscalYear        = $parameters.P_FiscalYear
                                                                                    and _ToFiscalPeriodForVariant.FiscalPeriod      = $parameters.P_ToFiscalPeriod
  association [0..1] to I_FiscalPeriodForVariant     as _FromFiscalPeriodForVariant on  _FromFiscalPeriodForVariant.FiscalYearVariant = $projection.FiscalYearVariant
                                                                                    and _FromFiscalPeriodForVariant.FiscalYear        = $parameters.P_FiscalYear
                                                                                    and _FromFiscalPeriodForVariant.FiscalPeriod      = $parameters.P_FromFiscalPeriod
  association [0..1] to I_CompanyCode                as _CompanyCode                on  _CompanyCode.CompanyCode = _glaccount_chlog.CompanyCode
  association [0..1] to I_Language                   as _Language                   on  _Language.Language = _glaccount_chlog.GLACCOUNTLANGUAGEKEY
{
  key ChartOfAccount,
  key GLAccount,
  key _glaccount_chlog.CompanyCode,
  key ChangeDocObject,
  key ChangeDocObjectClass,
  key ChangeDocument,
  key DatabaseTable,
  key ChangeDocTableKey,
  key ChangeDocDatabaseTableField,
  key ChangeDocItemChangeType,

      _ChangeLogDatabaseTableText[1: Language = $parameters.P_Language].DatabaseTableText,
      _ChgDocItemChangeTypeText[1: Language = $parameters.P_Language].ChangeDocItemChangeTypeText,
      I_LedgerCompanyCodeCrcyRoles.FiscalYearVariant as FiscalYearVariant,
      _ChangeDocFieldNames[1: Language = $parameters.P_Language].Text,
      ChangeDocNewFieldValue,
      ChangeDocPreviousFieldValue,
      ChangeDocPreviousUnit,
      ChangeDocNewUnit,
      ChangeDocPreviousCurrency,
      ChangeDocNewCurrency,

      ChangeDocTextIsChanged,

      @EndUserText.label: 'Output Length'
      case when newLength >= oldLength
        then newLength
        else oldLength end                           as outputLength,

      @EndUserText.label: 'G/L Account Maintainance Language Key'
      _Language.LanguageISOCode,

      CreatedByUser,
      @Semantics.systemDate.createdAt: true
      @EndUserText.label: 'Creatin date of the change document'
      CreationDate,
      @Semantics.systemTime.createdAt: true
      CreationTime,
      ChangeTransactionCode,
      _glaccount_chlog.ChangeDocChangeType,
      @Semantics.language: true
      //@ObjectModel.foreignKey.association: '_ChangeDocLanguage'

      ChangeDocLanguage,
      _ChangeDocument._ChangeDocLanguage._Text[1: Language = $parameters.P_Language].LanguageName,
      //      $parameters.P_CompanyCode                      as ReportCompanyCode,

      @EndUserText.label: 'System Client'
      cast ( $session.client as char3 )              as SystemClient
}
where
      _glaccount_chlog.CreationDate   >= _FromFiscalPeriodForVariant.FiscalPeriodStartDate
  and _glaccount_chlog.CreationDate   <= _ToFiscalPeriodForVariant.FiscalPeriodEndDate
//  and(

//      //       _glaccount_chlog.CompanyCode    = $parameters.P_CompanyCode

//      _glaccount_chlog.CompanyCode    =  ''

//  )

  and _glaccount_chlog.ChartOfAccount =  _CompanyCode.ChartOfAccounts
  and _glaccount_chlog.GLAccount      <> ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FAC_DART_Z3_GLACCOUNT_CHGDOC_B",
"I_CHANGEDOCFIELDNAMES",
"I_CHANGEDOCUMENT",
"I_CHANGELOGDATABASETABLETEXT",
"I_CHGDOCITEMCHANGETYPETEXT",
"I_COMPANYCODE",
"I_FISCALPERIODFORVARIANT",
"I_LANGUAGE",
"I_LANGUAGETEXT",
"I_LEDGERCOMPANYCODECRCYROLES"
],
"ASSOCIATED":
[
"I_CHANGEDOCFIELDNAMES",
"I_CHANGELOGDATABASETABLETEXT",
"I_CHGDOCITEMCHANGETYPETEXT",
"I_COMPANYCODE",
"I_FISCALPERIODFORVARIANT",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/