I_CMPLRQRSLT

@EndUserText.label: 'CRR - Compliance Requirement Result'

@AbapCatalog:
{
  sqlViewName: 'ICRRESULT',
  compiler.compareFilter: true,
  preserveKey: true
}

@AccessControl.authorizationCheck: #MANDATORY

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #BASIC

@ObjectModel:
{
  usageType:
  {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #XL,
    serviceQuality: #A
  }
}


define view I_CmplRqRslt
  as select from ehfndv_crr

  -- Link to compliance requirement version
  association [0..1] to I_CmplRqVersEnhanced as _CmplRqVers       on $projection.CmplRqVersUUID = _CmplRqVers.CmplRqVersUUID

  --Link to chemical compliance information
  association [0..1] to I_ChmlCmplncInfo     as _ChmlCmplncInfo   on $projection.ChmlCmplncInfoUUID = _ChmlCmplncInfo.ChmlCmplncInfoUUID

  --Link to substance
  association [0..1] to I_SubstanceEnhanced  as _Substance        on $projection.SubstanceUUID = _Substance.SubstanceUUID

  --Link to supplier material
  association [0..1] to I_ChmlSuplrMatl      as _SupplierMaterial on $projection.ChmlSuplrMatlUUID = _SupplierMaterial.ChmlSuplrMatlUUID
  
  
  association [0..1] to I_CmplRqRsltProcessingStatus as _CmplRqRsltProcessingStatus on $projection.CmplRqRsltProcessingStatus = _CmplRqRsltProcessingStatus.CmplRqRsltProcessingStatus

{
      /****  Keys  ****/

  key cmplrqrsltuuid                                                                   as CmplRqRsltUUID,

      chmlcmplncinfouuid                                                               as ChmlCmplncInfoUUID,

      substanceuuid                                                                    as SubstanceUUID,

      chmlsuplrmatluuid                                                                as ChmlSuplrMatlUUID,
      
      chemicalcustomermaterialuuid                                                     as ChemicalCustomerMaterialUUID,
      
      pcesscenariouuid                                                                 as PCESScenarioUUID,         

      cmplrqversuuid                                                                   as CmplRqVersUUID,

      compliancerequirement                                                            as ComplianceRequirement,

      /****  Content  ****/

      @Semantics.systemDateTime.createdAt: true
      cast( creationdatetime as ehfnd_bo_crea_date_time preserving type )              as CreationDateTime,

      @Semantics.user.createdBy: true
      cast( createdbyuser as ehfnd_bo_crea_uname preserving type )                     as CreatedByUser,

      @Semantics.systemDateTime.lastChangedAt: true
      cast( lastchangedatetime as ehfnd_bo_lchg_date_time preserving type )            as LastChangeDateTime,

      @Semantics.user.lastChangedBy: true
      cast( lastchangedbyuser as ehfnd_bo_lchg_uname preserving type )                 as LastChangedByUser,

      @ObjectModel.foreignKey.association: '_CmplRqRsltProcessingStatus'
      cast( cmplrqrsltprocessingstatus as cmplrqrsltprocessingstatus preserving type ) as CmplRqRsltProcessingStatus,

      releasedbyuser                                                                   as ReleasedByUser,

      processor                                                                        as Processor,

      validitystartdatetime                                                            as ValidityStartDateTime,

      validityenddatetime                                                              as ValidityEndDateTime,

      cmplrqrsltreldcmplncsts                                                          as CmplRqRsltReldCmplncSts,

      cmplrqrsltcalculatedstatus                                                       as CmplRqRsltCalculatedStatus,

      cast( cmplrqrsltmanualstatus as ehfnd_crr_man_stat_nd preserving type )          as CmplRqRsltManualStatus,
      
      cmplrqrsltprelimcmplncsts                                                        as CmplRqRsltPrelimCmplncSts,

      cmplrqrsltstatusremark                                                           as CmplRqRsltStatusRemark,

      chmlcompositiontype                                                              as ChmlCompositionType,

      materialissold                                                                   as MaterialIsSold,

      materialistransported                                                            as MaterialIsTransported,

      materialissourced                                                                as MaterialIsSourced,

      materialisproduced                                                               as MaterialIsProduced,


      /**** Associations ****/
      _CmplRqVers,
      _ChmlCmplncInfo,
      _Substance,
      _SupplierMaterial,
      _CmplRqRsltProcessingStatus

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"EHFNDV_CRR"
],
"ASSOCIATED":
[
"I_CHMLCMPLNCINFO",
"I_CHMLSUPLRMATL",
"I_CMPLRQRSLTPROCESSINGSTATUS",
"I_CMPLRQVERSENHANCED",
"I_SUBSTANCEENHANCED"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/