R_DngrsGdsBasicClassfctnTP

@EndUserText.label: 'DG Basic Classification - TP'
@AccessControl.authorizationCheck: #MANDATORY
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel:
{
  sapObjectNodeType.name: 'DngrsGoodsBasicClassification',
  semanticKey:  [ 'ComplianceRequirement', 'Product' ],
  representativeKey:  'CmplRqRsltUUID',
  usageType:
  {
    dataClass: #MIXED,
    sizeCategory: #L, // <10.000.000

    serviceQuality: #C // <= 15 msec

  }
}
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define root view entity R_DngrsGdsBasicClassfctnTP
  --Select data from basic view 'Chemical Component'
  as select from I_CmplRqRslt as DangerousGoodsClassification
  composition [0..1] of R_DngrsGdsBasicClassfctnDetTP  as _Detail
  composition [0..*] of R_DngrsGdsBasicClassfctnTextTP as _Text
  composition [0..*] of R_DngrsGdsClassfctnSgrgtnGrpTP as _SegregationGroup
  composition [0..*] of R_DngrsGdsSftyDtaShtNoteTP     as _SafetyDataSheetNote
  association [0..1] to P_NewestReleasedRsltForCmplRq  as _NewestReleasedRsltForCmplRq on  _NewestReleasedRsltForCmplRq.ComplianceRequirement = $projection.ComplianceRequirement
                                                                                       and _NewestReleasedRsltForCmplRq.ChmlCmplncInfoUUID    = $projection.ChmlCmplncInfoUUID


{
  key CmplRqRsltUUID,
      ChmlCmplncInfoUUID,
      cast( _ChmlCmplncInfo._PrimaryMaterial.Material as productnumber preserving type ) as Product,
      CmplRqVersUUID,
      cast ( _CmplRqVers.CmplRqVers as ehfnd_vdm_crv preserving type )                   as CmplRqVers,
      _CmplRqVers.CmplRqVersName,

      cast ( case when _NewestReleasedRsltForCmplRq.LastChangeDateTime = DangerousGoodsClassification.LastChangeDateTime
              then 'X'
              else ''
              end as ehfnd_crv_is_latest preserving type )                               as CmplRqVersIsLatest,

      @Semantics.systemDateTime.createdAt: true
      CreationDateTime,
      @Semantics.user.createdBy: true
      CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser,

      ReleasedByUser,
      ValidityStartDateTime,
      ValidityEndDateTime,

      ComplianceRequirement,
      CmplRqRsltProcessingStatus,

      CmplRqRsltManualStatus,
      CmplRqRsltReldCmplncSts,
      @Semantics.booleanIndicator:true
      cast( case CmplRqRsltManualStatus
                when '01' then 'X'
              end as transportisallowed_nd  preserving type )                            as TransportIsAllowed,

      Processor                                                                          as CmplRqRsltProcessor,

      CmplRqRsltStatusRemark,

      MaterialIsProduced,
      MaterialIsSold,
      MaterialIsSourced,
      MaterialIsTransported,

      /* Associations */
      _ChmlCmplncInfo,
      _CmplRqRsltProcessingStatus,
      _CmplRqVers,
      /* Compoisitions */
      _Detail,
      _Text,
      _SegregationGroup,
      _SafetyDataSheetNote
}
where
      _CmplRqVers.CmplRqApplicationComponent = 'DG'
  and _ChmlCmplncInfo.ChmlCmplncInfoType     = 'BU'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHMLCMPLNCINFO",
"I_CHMLCMPLNCMATLASSGMT",
"I_CMPLRQRSLT",
"I_CMPLRQVERSENHANCED",
"P_NEWESTRELEASEDRSLTFORCMPLRQ"
],
"ASSOCIATED":
[
"I_CHMLCMPLNCINFO",
"I_CMPLRQRSLTPROCESSINGSTATUS",
"I_CMPLRQVERSENHANCED",
"R_DNGRSGDSBASICCLASSFCTNDETTP",
"R_DNGRSGDSBASICCLASSFCTNTEXTTP",
"R_DNGRSGDSCLASSFCTNSGRGTNGRPTP",
"R_DNGRSGDSSFTYDTASHTNOTETP"
],
"BASE":
[
"I_CMPLRQRSLT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/