C_UpaDaGdsClfnAssgdPckgdDet

/*----------------------------------------------------------------------------------------------------------------------
 * This view shows assigned packaged dangerous goods classifications (details)
 * to the unpackaged dangerous goods
 *----------------------------------------------------------------------------------------------------------------------*/
@VDM.viewType: #CONSUMPTION
@Metadata.allowExtensions: true

@AccessControl:
{
  authorizationCheck: #MANDATORY,
  personalData.blocking: #NOT_REQUIRED // blocking of personal data not required (no personal data fields exposed)

}

@ObjectModel:
{
  semanticKey:  [ 'ComplianceRequirement' ],
  usageType:
  {
    dataClass: #MIXED,
    sizeCategory: #L,
    serviceQuality: #C
  }
}

@EndUserText.label: 'Related Packaged Product Details'
define view entity C_UpaDaGdsClfnAssgdPckgdDet
  as select from I_CmplRqRslt         as crr
  //    inner join   i_cmplrqrsltdngrsgdsbscdets as crr_dg_dets on crr.cmplrqrsltuuid = crr_dg_dets.cmplrqrsltuuid

  // Only get CRRs which are for component "Dangerous Goods"

    join         I_CmplRqVersEnhanced as ComplianceRequirementVersion on  ComplianceRequirementVersion.CmplRqVersUUID             = crr.CmplRqVersUUID
                                                                      and ComplianceRequirementVersion.CmplRqApplicationComponent = 'DG'


{
      @ObjectModel.readOnly: true
  key crr.ChmlCmplncInfoUUID                                                                        as PckgdChmlCmplncInfoUUID,
      @ObjectModel.readOnly: true
  key crr.CmplRqRsltUUID,
      @ObjectModel.readOnly: true
      crr.CmplRqRsltProcessingStatus,

      @ObjectModel.readOnly: true
      cast ( ComplianceRequirementVersion.CmplRqVersName as ehdgm_regulation_name preserving type ) as CmplRqVersName,


      @ObjectModel: {
        readOnly: true,
        virtualElement: true,
        virtualElementCalculatedBy: 'ABAP:CL_EHDGM_PADA_DOC_DESC_EXIT'
      }
      cast( '' as ehdgm_final_description )                                                         as DangerousGoodDescForDocuments,

      // needed for access control

      crr.ComplianceRequirement

}
where
  (
       crr.CmplRqRsltProcessingStatus =  'RE'
    or ( crr.CmplRqRsltProcessingStatus =  'IP' and
         crr.CmplRqRsltCalculatedStatus != '' )
  )

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CMPLRQRSLT",
"I_CMPLRQVERSENHANCED"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/