I_CmplRqRsltPCESAnnexAssmtTP

@AbapCatalog:
{
  sqlViewName: 'ICRRESAATP',
  compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #MANDATORY,
  privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser' ]
}
--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API

@ObjectModel:
{
  modelCategory: #BUSINESS_OBJECT,
  compositionRoot: true,
  draftEnabled: true,
  transactionalProcessingEnabled: true,
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: true,//TODO: This is inconsistent with I_CmplRqRsltSubstListChkTP

  writeDraftPersistence: 'EHSDSW_CRR_ESDSA',
  writeActivePersistence: 'EHFNDV_CRR2',
  semanticKey:  [ 'CmplRqRsltUUID' ],

  usageType:
  {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #XL,
    serviceQuality: #C
  }
  ,
  entityChangeStateId: 'LastChangeDateTime',
  sapObjectNodeType.name: 'ExtdSftyDtaShtAnnexAssessment'
}

@EndUserText.label: 'Annex Assessment - TP'

define view I_CmplRqRsltPCESAnnexAssmtTP
  as select from I_CmplRqRslt

  // Exposure Scenario Assignment

  association [0..*] to I_ExpsrScenAssgmtTP as _ExpsrScenAssgmt   on $projection.CmplRqRsltUUID = _ExpsrScenAssgmt.CmplRqRsltUUID

  --Link to user data
  association [0..1] to I_User              as _CreatedByUser     on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User              as _LastChangedByUser on $projection.LastChangedByUser = _LastChangedByUser.UserID


{
      /****  Keys  ****/

      @ObjectModel.mandatory: true
  key CmplRqRsltUUID,

      @ObjectModel.readOnly: true
      cast(CmplRqRsltUUID as ehfnd_crr_active_uuid preserving type ) as ActiveCmplRqRsltUUID, --Active UUID of CRR

      @ObjectModel.mandatory: true
      CmplRqVersUUID,

      ChmlCmplncInfoUUID,

      SubstanceUUID,

      ChmlSuplrMatlUUID,

      ChemicalCustomerMaterialUUID,

      /****  Content  ****/
      ComplianceRequirement, // needed for DCL


      //@ObjectModel.readOnly: true

      CreationDateTime,

      //@ObjectModel.readOnly: true

      CreatedByUser,

      //@ObjectModel.readOnly: true

      LastChangeDateTime,

      //@ObjectModel.readOnly: true

      LastChangedByUser,

      @ObjectModel.mandatory: true
      CmplRqRsltProcessingStatus,

      //      Processor,

      Processor                                                      as CmplRqRsltProcessor,

      ReleasedByUser,

      ValidityStartDateTime,

      ValidityEndDateTime,

      CmplRqRsltReldCmplncSts,

      CmplRqRsltCalculatedStatus,

      CmplRqRsltManualStatus,

      CmplRqRsltPrelimCmplncSts,

      CmplRqRsltStatusRemark,

      ChmlCompositionType,

      MaterialIsSold,

      MaterialIsTransported,

      MaterialIsSourced,

      MaterialIsProduced,

      PCESScenarioUUID,

      /**** Associations ****/

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _ExpsrScenAssgmt,
      _CmplRqRsltProcessingStatus,

      _ChmlCmplncInfo,

      _CreatedByUser,

      _LastChangedByUser

      //      _Substance,

      //      _SupplierMaterial


}
where
      _CmplRqVers.CmplRqPattern = 'CompliancePatternExpsrScen'
 and ( ChmlCmplncInfoUUID <> hextobin( '00000000000000000000000000000000' ) or SubstanceUUID <> hextobin( '00000000000000000000000000000000' ) )

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CMPLRQRSLT",
"I_CMPLRQVERSENHANCED"
],
"ASSOCIATED":
[
"I_CHMLCMPLNCINFO",
"I_CMPLRQRSLTPROCESSINGSTATUS",
"I_EXPSRSCENASSGMTTP",
"I_USER"
],
"BASE":
[
"I_CMPLRQRSLT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/