I_CmplRqRsltProtTP

@AbapCatalog.sqlViewName: 'ICRRPPMTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl: {
    authorizationCheck: #CHECK,
    privilegedAssociations: ['_CmplRqRsltProtNote']
}
@EndUserText.label: 'Personal Protection Measures'

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API

@ObjectModel:
{
  modelCategory: #BUSINESS_OBJECT,
  compositionRoot: true,
  draftEnabled: true,
  transactionalProcessingEnabled: true,
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: 'EXTERNAL_CALCULATION',
  writeDraftPersistence: 'ehfndw_crr_ppm',
  writeActivePersistence: 'ehfndv_crr',
  semanticKey:  [ 'CmplRqRsltUUID' ],
  entityChangeStateId: 'LastChangeDateTime',
  usageType:
  {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #XL,
    serviceQuality: #C
  },
  sapObjectNodeType.name: 'PrsnlProtMeasureAssessment'
}

define view I_CmplRqRsltProtTP
  as select from I_CmplRqRslt

  association [0..*] to I_CmplRqRsltProtEyeTP         as _CmplRqRsltProtEye         on $projection.CmplRqRsltUUID = _CmplRqRsltProtEye.CmplRqRsltUUID
  association [0..*] to I_CmplRqRsltProtSkinTP        as _CmplRqRsltProtSkin        on $projection.CmplRqRsltUUID = _CmplRqRsltProtSkin.CmplRqRsltUUID
  association [0..*] to I_CmplRqRsltProtHandTP        as _CmplRqRsltProtHand        on $projection.CmplRqRsltUUID = _CmplRqRsltProtHand.CmplRqRsltUUID
  association [0..*] to I_CmplRqRsltProtGenMsrTP      as _CmplRqRsltProtGenMsr      on $projection.CmplRqRsltUUID = _CmplRqRsltProtGenMsr.CmplRqRsltUUID
  association [0..*] to I_CmplRqRsltProtHandAddlTP    as _CmplRqRsltProtHandAddl    on $projection.CmplRqRsltUUID = _CmplRqRsltProtHandAddl.CmplRqRsltUUID
  association [0..*] to I_CmplRqRsltProtRespirationTP as _CmplRqRsltProtRespiration on $projection.CmplRqRsltUUID = _CmplRqRsltProtRespiration.CmplRqRsltUUID
  association [0..1] to I_CmplRqRsltProtNoteTP        as _CmplRqRsltProtNote        on $projection.CmplRqRsltUUID = _CmplRqRsltProtNote.PCPrptyRootUUID
  association [0..1] to I_CmplRqRsltProtFltrTP        as _CmplRqRsltProtFltr        on $projection.CmplRqRsltUUID = _CmplRqRsltProtFltr.CmplRqRsltUUID
  association [0..1] to I_CmplRqRsltProtAssmtTP       as _CmplRqRsltProtAssmt       on $projection.CmplRqRsltUUID = _CmplRqRsltProtAssmt.CmplRqRsltUUID

{
  key CmplRqRsltUUID,
      @ObjectModel.readOnly: true
      CmplRqRsltUUID as ActiveCmplRqRsltUUID, --Active UUID of CRR

      ChmlCmplncInfoUUID,
      SubstanceUUID,
      ChmlSuplrMatlUUID,
      CmplRqVersUUID,
      ComplianceRequirement,
      CreationDateTime,
      CreatedByUser,
      LastChangeDateTime,
      LastChangedByUser,
      CmplRqRsltProcessingStatus,
      ReleasedByUser,
      Processor,
      ValidityStartDateTime,
      ValidityEndDateTime,
      CmplRqRsltReldCmplncSts,
      CmplRqRsltCalculatedStatus,
      CmplRqRsltManualStatus,
      CmplRqRsltStatusRemark,
      ChmlCompositionType,
      MaterialIsSold,
      MaterialIsTransported,
      MaterialIsSourced,
      MaterialIsProduced,


      /**** Associations ****/
      _ChmlCmplncInfo,
      _CmplRqVers,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CmplRqRsltProtEye,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CmplRqRsltProtSkin,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CmplRqRsltProtGenMsr,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CmplRqRsltProtHandAddl,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CmplRqRsltProtRespiration,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CmplRqRsltProtHand,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CmplRqRsltProtNote,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CmplRqRsltProtFltr,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CmplRqRsltProtAssmt

}
where
  _CmplRqVers.CmplRqPattern = 'CompliancePatternPersonProtect';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CMPLRQRSLT",
"I_CMPLRQVERSENHANCED"
],
"ASSOCIATED":
[
"I_CHMLCMPLNCINFO",
"I_CMPLRQRSLTPROTASSMTTP",
"I_CMPLRQRSLTPROTEYETP",
"I_CMPLRQRSLTPROTFLTRTP",
"I_CMPLRQRSLTPROTGENMSRTP",
"I_CMPLRQRSLTPROTHANDADDLTP",
"I_CMPLRQRSLTPROTHANDTP",
"I_CMPLRQRSLTPROTNOTETP",
"I_CMPLRQRSLTPROTRESPIRATIONTP",
"I_CMPLRQRSLTPROTSKINTP",
"I_CMPLRQVERSENHANCED"
],
"BASE":
[
"I_CMPLRQRSLT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/