I_CmplRqRsltPCESEnvrmtAssmtTP

@AbapCatalog:
{
  sqlViewName: 'ICRRASENTP',
  compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #MANDATORY,
  privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser' ]
}
--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API

@ObjectModel:
{
  modelCategory: #BUSINESS_OBJECT,
  compositionRoot: true,
  draftEnabled: true,
  transactionalProcessingEnabled: true,
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: true,//TODO: This is inconsistent with I_CmplRqRsltSubstListChkTP

  writeDraftPersistence: 'EHSDSW_CRR_CSENV',
  writeActivePersistence: 'EHFNDV_CRR2',
  semanticKey:  [ 'CmplRqRsltUUID' ],
  usageType:
  {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #XL,
    serviceQuality: #C
  },
  entityChangeStateId: 'LastChangeDateTime',
  sapObjectNodeType.name: 'ContributingScenarioAssessment'    
}

@EndUserText.label: 'Contributing Scenario Environment Assessment - TP'

define view I_CmplRqRsltPCESEnvrmtAssmtTP
  as select from I_CmplRqRslt
  // RAP BO Exposure Scenario

  association [1..1] to I_ExposureScenario            as _ExposureScenario          on $projection.PCESScenarioUUID = _ExposureScenario.PCESScenarioUUID
  // Contributing Scenario General Data

  association [0..1] to I_CntrbtScenEnvrmtGenDataTP   as _CntrbtScenEnvrmtGenData   on $projection.CmplRqRsltUUID = _CntrbtScenEnvrmtGenData.CmplRqRsltUUID

  // Environment Release Estimation

  association [0..*] to I_CntrbtScenEnvrmtRelEstnTP   as _CntrbtScenEnvrmtRelEstn   on $projection.CmplRqRsltUUID = _CntrbtScenEnvrmtRelEstn.CmplRqRsltUUID

  // Environment Exposure Estimation

  association [0..*] to I_CntrbtScenEnvrmtExpsrEstnTP as _CntrbtScenEnvrmtExpsrEstn on $projection.CmplRqRsltUUID = _CntrbtScenEnvrmtExpsrEstn.CmplRqRsltUUID

  // Environment Exposure Estimation Additional Detail

  association [0..*] to I_CntrbtScenEnvrmtEstnDetTP   as _CntrbtScenEnvrmtEstnDet   on $projection.CmplRqRsltUUID = _CntrbtScenEnvrmtEstnDet.CmplRqRsltUUID

  // Environmnt  Prevention of Release to Environment

  association [0..*] to I_CntrbtScenEnvrmtRelPrvtnTP  as _CntrbtScenEnvrmtRelPrvtn  on $projection.CmplRqRsltUUID = _CntrbtScenEnvrmtRelPrvtn.CmplRqRsltUUID

  // Environment  Operational Conditions

  association [0..*] to I_CntrbtScenEnvrmtOplCndnTP   as _CntrbtScenEnvrmtOplCndn   on $projection.CmplRqRsltUUID = _CntrbtScenEnvrmtOplCndn.CmplRqRsltUUID

  // Environment  Waste-Related Measures

  association [0..*] to I_CntrbtScenEnvrmtWasteMsrTP  as _CntrbtScenEnvrmtWasteMsr  on $projection.CmplRqRsltUUID = _CntrbtScenEnvrmtWasteMsr.CmplRqRsltUUID

  // Environment Msafe

  association [0..1] to I_CntrbtScenEnvrmtMsafeTP     as _CntrbtScenEnvrmtMsafe     on $projection.CmplRqRsltUUID = _CntrbtScenEnvrmtMsafe.CmplRqRsltUUID

  //Environment  Frequency/Duration

  association [0..*] to I_CntrbtScenEnvrmtFrqcyDurnTP as _CntrbtScenEnvrmtFrqcyDurn on $projection.CmplRqRsltUUID = _CntrbtScenEnvrmtFrqcyDurn.CmplRqRsltUUID

  //Environment Amount used

  association [0..*] to I_CntrbtScenEnvrmtAmtUsedTP   as _CntrbtScenEnvrmtAmtUsed   on $projection.CmplRqRsltUUID = _CntrbtScenEnvrmtAmtUsed.CmplRqRsltUUID

  //Environment Product Article Characteristics

  association [0..1] to I_CntrbtScenEnvrmtProdCharcTP as _CntrbtScenEnvrmtProdCharc on $projection.CmplRqRsltUUID = _CntrbtScenEnvrmtProdCharc.CmplRqRsltUUID

  //Environment  Advices

  association [0..*] to I_CntrbtScenEnvrmtAdvcTP      as _CntrbtScenEnvrmtAdvc      on $projection.CmplRqRsltUUID = _CntrbtScenEnvrmtAdvc.CmplRqRsltUUID

  //Environment  Other factors

  association [0..1] to I_CntrbtScenEnvrmtOthFctrTP   as _CntrbtScenEnvrmtOthFctr   on $projection.CmplRqRsltUUID = _CntrbtScenEnvrmtOthFctr.CmplRqRsltUUID

  --Link to user data
  association [0..1] to I_User                        as _CreatedByUser             on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                        as _LastChangedByUser         on $projection.LastChangedByUser = _LastChangedByUser.UserID


{
      /****  Keys  ****/

      @ObjectModel.mandatory: true
  key CmplRqRsltUUID,

      @ObjectModel.readOnly: true
      cast(CmplRqRsltUUID as ehfnd_crr_active_uuid preserving type ) as ActiveCmplRqRsltUUID, --Active UUID of CRR

      @ObjectModel.mandatory: true
      CmplRqVersUUID,

      ChmlCmplncInfoUUID,

      PCESScenarioUUID,

      _ExposureScenario.PCESExposureScenarioType,

      _ExposureScenario.PCESScenarioType,

      @ObjectModel.readOnly: true
      _CntrbtScenEnvrmtGenData.PCESShortTitlePhrs1UUID,

      @ObjectModel.readOnly: true
      _CntrbtScenEnvrmtGenData.PCESShortTitlePhrs2UUID,

      @ObjectModel.readOnly: true
      _CntrbtScenEnvrmtGenData.PCESShortTitlePhrs3UUID,

      @ObjectModel.readOnly: true
      _CntrbtScenEnvrmtGenData.PCESShortTitlePhrs4UUID,

      @ObjectModel.readOnly: true
      _CntrbtScenEnvrmtGenData.PCESShortTitlePhrs5UUID,

      @ObjectModel.readOnly: true
      _CntrbtScenEnvrmtGenData.PCESShortTitlePhrs6UUID,

      /****  Content  ****/
      ComplianceRequirement, // needed for DCL


      @ObjectModel.readOnly: true
      CreationDateTime,

      @ObjectModel.readOnly: true
      CreatedByUser,

      @ObjectModel.readOnly: true
      LastChangeDateTime,

      @ObjectModel.readOnly: true
      LastChangedByUser,

      @ObjectModel.mandatory: true
      CmplRqRsltProcessingStatus,

      Processor                                                      as CmplRqRsltProcessor,

      ReleasedByUser,

      ValidityStartDateTime,

      ValidityEndDateTime,

      CmplRqRsltReldCmplncSts,

      CmplRqRsltCalculatedStatus,

      CmplRqRsltManualStatus,

      CmplRqRsltPrelimCmplncSts,

      CmplRqRsltStatusRemark,


      /**** Associations ****/
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenEnvrmtGenData,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenEnvrmtRelEstn,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenEnvrmtExpsrEstn,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenEnvrmtEstnDet,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenEnvrmtRelPrvtn,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenEnvrmtOplCndn,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenEnvrmtWasteMsr,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenEnvrmtMsafe,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenEnvrmtFrqcyDurn,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenEnvrmtAmtUsed,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenEnvrmtProdCharc,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenEnvrmtAdvc,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenEnvrmtOthFctr,

      _CmplRqRsltProcessingStatus,

      _CreatedByUser,

      _LastChangedByUser

}
where
      _CmplRqVers.CmplRqPattern          = 'CompliancePatternExpsrScen'
  and _ExposureScenario.PCESScenarioType = 'ENV'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CMPLRQRSLT",
"I_CMPLRQVERSENHANCED",
"I_CNTRBTSCENENVRMTGENDATATP",
"I_EXPOSURESCENARIO"
],
"ASSOCIATED":
[
"I_CMPLRQRSLTPROCESSINGSTATUS",
"I_CNTRBTSCENENVRMTADVCTP",
"I_CNTRBTSCENENVRMTAMTUSEDTP",
"I_CNTRBTSCENENVRMTESTNDETTP",
"I_CNTRBTSCENENVRMTEXPSRESTNTP",
"I_CNTRBTSCENENVRMTFRQCYDURNTP",
"I_CNTRBTSCENENVRMTGENDATATP",
"I_CNTRBTSCENENVRMTMSAFETP",
"I_CNTRBTSCENENVRMTOPLCNDNTP",
"I_CNTRBTSCENENVRMTOTHFCTRTP",
"I_CNTRBTSCENENVRMTPRODCHARCTP",
"I_CNTRBTSCENENVRMTRELESTNTP",
"I_CNTRBTSCENENVRMTRELPRVTNTP",
"I_CNTRBTSCENENVRMTWASTEMSRTP",
"I_EXPOSURESCENARIO",
"I_USER"
],
"BASE":
[
"I_CMPLRQRSLT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/