I_CmplRqRsltPCESAssmtTP

@AbapCatalog:
{
  sqlViewName: 'ICRRESATP',
  compiler.compareFilter: true,
  preserveKey: true
}

@AccessControl:
{
  authorizationCheck: #MANDATORY,
  privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser' ]
}
--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API

@ObjectModel:
{
  modelCategory: #BUSINESS_OBJECT,
  compositionRoot: true,
  draftEnabled: true,
  transactionalProcessingEnabled: true,
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: true,//TODO: This is inconsistent with I_CmplRqRsltSubstListChkTP

  writeDraftPersistence: 'EHSDSW_CRR_ES',
  writeActivePersistence: 'EHFNDV_CRR2',
  semanticKey:  [ 'CmplRqRsltUUID' ],

  usageType:
  {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #XL,
    serviceQuality: #C
  }
  ,
  entityChangeStateId: 'LastChangeDateTime',
  sapObjectNodeType.name: 'ExposureScenarioAssessment'  
}

@EndUserText.label: 'Exposure Scenario Assessment - TP'

define view I_CmplRqRsltPCESAssmtTP
  as select from I_CmplRqRslt

  // RAP BO Exposure Scenario

  association [1..1] to I_ExposureScenario    as _ExposureScenario  on $projection.PCESScenarioUUID = _ExposureScenario.PCESScenarioUUID

  // General Data of Exposure Scenario

  association [0..1] to I_ExpsrScenGenDataTP  as _ExpsrScenGenData  on $projection.CmplRqRsltUUID = _ExpsrScenGenData.CmplRqRsltUUID

  //Guidance to Downstram Users

  association [0..*] to I_ExpsrScenGuidanceTP as _ExpsrScenGuidance on $projection.CmplRqRsltUUID = _ExpsrScenGuidance.CmplRqRsltUUID

  //Scaling Tools Details

  association [0..*] to I_ExpsrScenScalingTP  as _ExpsrScenScaling  on $projection.CmplRqRsltUUID = _ExpsrScenScaling.CmplRqRsltUUID

  //Contributing Scenario Assignment

  association [0..*] to I_CntrbtScenAssgmtTP  as _CntrbtScenAssgmt  on $projection.CmplRqRsltUUID = _CntrbtScenAssgmt.CmplRqRsltUUID

  --Link to user data
  association [0..1] to I_User                as _CreatedByUser     on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                as _LastChangedByUser on $projection.LastChangedByUser = _LastChangedByUser.UserID


{
      /****  Keys  ****/

      --Compliance Assessment UUID
      @ObjectModel.mandatory: true
  key CmplRqRsltUUID,

      @ObjectModel.readOnly: true
      cast(CmplRqRsltUUID as ehfnd_crr_active_uuid preserving type ) as ActiveCmplRqRsltUUID, --Active UUID of CRR

      --Compliance Assessment version UUID
      @ObjectModel.mandatory: true
      CmplRqVersUUID,

      ChmlCmplncInfoUUID,

      @ObjectModel.mandatory: true
      PCESScenarioUUID,

      -- Scenario Type
      @ObjectModel.mandatory: true
      _ExposureScenario.PCESScenarioType,

      -- Exposure Scenario Type
      @ObjectModel.mandatory: true
      _ExposureScenario.PCESExposureScenarioType,

      -- Short Title1
      @ObjectModel.readOnly: true
      _ExpsrScenGenData.PCESShortTitlePhrs1UUID,

      -- Short Title2
      @ObjectModel.readOnly: true
      _ExpsrScenGenData.PCESShortTitlePhrs2UUID,

      -- Short Title3
      @ObjectModel.readOnly: true
      _ExpsrScenGenData.PCESShortTitlePhrs3UUID,

      -- Short Title4
      @ObjectModel.readOnly: true
      _ExpsrScenGenData.PCESShortTitlePhrs4UUID,

      -- Short Title5
      @ObjectModel.readOnly: true
      _ExpsrScenGenData.PCESShortTitlePhrs5UUID,

      -- Short Title6
      @ObjectModel.readOnly: true
      _ExpsrScenGenData.PCESShortTitlePhrs6UUID,

      /****  Content  ****/
      ComplianceRequirement, // needed for DCL


      --Create at date/time
      @ObjectModel.readOnly: true
      CreationDateTime,

      --Create by user
      @ObjectModel.readOnly: true
      CreatedByUser,

      --Update at date/time
      @ObjectModel.readOnly: true
      LastChangeDateTime,

      --Update by user
      @ObjectModel.readOnly: true
      LastChangedByUser,

      @ObjectModel.mandatory: true
      CmplRqRsltProcessingStatus,

      Processor                                                      as CmplRqRsltProcessor,

      ReleasedByUser,

      ValidityStartDateTime,

      ValidityEndDateTime,

      CmplRqRsltReldCmplncSts,

      CmplRqRsltCalculatedStatus,

      CmplRqRsltManualStatus,

      CmplRqRsltPrelimCmplncSts,

      CmplRqRsltStatusRemark,

      /**** Associations ****/

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _ExpsrScenGenData,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _ExpsrScenGuidance,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _ExpsrScenScaling,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenAssgmt,

      _CmplRqRsltProcessingStatus,

      _CreatedByUser,

      _LastChangedByUser
}
where
      _CmplRqVers.CmplRqPattern          = 'CompliancePatternExpsrScen'
  and _ExposureScenario.PCESScenarioType = 'EXP'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CMPLRQRSLT",
"I_CMPLRQVERSENHANCED",
"I_EXPOSURESCENARIO",
"I_EXPSRSCENGENDATATP"
],
"ASSOCIATED":
[
"I_CMPLRQRSLTPROCESSINGSTATUS",
"I_CNTRBTSCENASSGMTTP",
"I_EXPOSURESCENARIO",
"I_EXPSRSCENGENDATATP",
"I_EXPSRSCENGUIDANCETP",
"I_EXPSRSCENSCALINGTP",
"I_USER"
],
"BASE":
[
"I_CMPLRQRSLT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/