R_DangerousGoodsClassfctnTP

@EndUserText.label: 'Dangerous Goods Classification - TP'
@AccessControl.authorizationCheck: #MANDATORY
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel:
{
  sapObjectNodeType.name: 'DangerousGoodsClassification',
  semanticKey:  [ 'ComplianceRequirement', 'Product' ],
  representativeKey:  'CmplRqRsltUUID',
  usageType:
  {
    dataClass: #MIXED,
    sizeCategory: #L, // <10.000.000

    serviceQuality: #C // <= 15 msec

  }
}
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define root view entity R_DangerousGoodsClassfctnTP
  --Select data from basic view 'Chemical Component'
  as select from I_CmplRqRslt as DangerousGoodsClassification
  composition[0..1] of R_DangerousGoodsClassfctnDetTP as _Detail
  composition[0..*] of R_DngrsGdsClassfctnMOTTP as _ModeOfTransport
  composition[0..*] of R_DngrsGdsClassfctnHazardLblTP as _HazardLabel
  composition[0..*] of R_DngrsGdsClassfctnHndlgLblTP as _HandlingLabel  
  association[0..1] to P_NewestReleasedRsltForCmplRq as _NewestReleasedRsltForCmplRq on  _NewestReleasedRsltForCmplRq.ComplianceRequirement = $projection.ComplianceRequirement
                                                                                     and _NewestReleasedRsltForCmplRq.ChmlCmplncInfoUUID = $projection.ChmlCmplncInfoUUID
                                                                                     
  
{
  key CmplRqRsltUUID,
      ChmlCmplncInfoUUID,
      cast( _ChmlCmplncInfo._PrimaryMaterial.Material as productnumber preserving type ) as Product, 
      CmplRqVersUUID,
      cast ( _CmplRqVers.CmplRqVers as ehfnd_vdm_crv preserving type ) as CmplRqVers, 
      _CmplRqVers.CmplRqVersName,

      cast ( case when _NewestReleasedRsltForCmplRq.LastChangeDateTime = DangerousGoodsClassification.LastChangeDateTime then 'X' else '' end as ehfnd_crv_is_latest preserving type ) as CmplRqVersIsLatest,

      CreationDateTime,
      CreatedByUser,
      LastChangeDateTime,
      LastChangedByUser,

      ComplianceRequirement,
      CmplRqRsltProcessingStatus,     
      /* Associations */
      _ChmlCmplncInfo,      
      _CmplRqRsltProcessingStatus,
      _CmplRqVers,
      /* Compoisitions */
      _Detail,
      _ModeOfTransport,
      _HazardLabel,
      _HandlingLabel
} where _CmplRqVers.CmplRqApplicationComponent = 'DG'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHMLCMPLNCINFO",
"I_CHMLCMPLNCMATLASSGMT",
"I_CMPLRQRSLT",
"I_CMPLRQVERSENHANCED",
"P_NEWESTRELEASEDRSLTFORCMPLRQ"
],
"ASSOCIATED":
[
"I_CHMLCMPLNCINFO",
"I_CMPLRQRSLTPROCESSINGSTATUS",
"I_CMPLRQVERSENHANCED",
"R_DANGEROUSGOODSCLASSFCTNDETTP",
"R_DNGRSGDSCLASSFCTNHAZARDLBLTP",
"R_DNGRSGDSCLASSFCTNHNDLGLBLTP",
"R_DNGRSGDSCLASSFCTNMOTTP"
],
"BASE":
[
"I_CMPLRQRSLT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/