I_CmplRqRsltPCESWrkrAssmtTP

@AbapCatalog:
{
  sqlViewName: 'ICRRASWRTP',
  compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #MANDATORY,
  privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser' ]
}
--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API

@ObjectModel:
{
  modelCategory: #BUSINESS_OBJECT,
  compositionRoot: true,
  draftEnabled: true,
  transactionalProcessingEnabled: true,
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: true,//TODO: This is inconsistent with I_CmplRqRsltSubstListChkTP

  writeDraftPersistence: 'EHSDSW_CRR_CSWRK',
  writeActivePersistence: 'EHFNDV_CRR2',
  semanticKey:  [ 'CmplRqRsltUUID' ],

  usageType:
  {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #XL,
    serviceQuality: #C
  }
  ,
  entityChangeStateId: 'LastChangeDateTime',
  sapObjectNodeType.name: 'ContributingScenarioAssessment'  
}

@EndUserText.label: 'Contributing Scenario Worker Assessment - TP'


define view I_CmplRqRsltPCESWrkrAssmtTP
  as select from I_CmplRqRslt
  -- RAP BO Exposure Scenario
  association [1..1] to I_ExposureScenario            as _ExposureScenario          on $projection.PCESScenarioUUID = _ExposureScenario.PCESScenarioUUID

  --General Data
  association [0..1] to I_CntrbtScenWrkrGenDataTP     as _CntrbtScenWrkrGenData     on $projection.CmplRqRsltUUID = _CntrbtScenWrkrGenData.CmplRqRsltUUID

  --Worker Amount Used
  association [0..*] to I_CntrbtScenWrkrAmtUsedTP     as _CntrbtScenWrkrAmtUsed     on $projection.CmplRqRsltUUID = _CntrbtScenWrkrAmtUsed.CmplRqRsltUUID

  --Worker Product Article Characteristics
  association [0..1] to I_CntrbtScenWrkrProdCharcTP   as _CntrbtScenWrkrProdCharc   on $projection.CmplRqRsltUUID = _CntrbtScenWrkrProdCharc.CmplRqRsltUUID

  --Worker - Operational Condition
  association [0..1] to I_CntrbtScenWrkrOplCndnTP     as _CntrbtScenWrkrOplCndn     on $projection.CmplRqRsltUUID = _CntrbtScenWrkrOplCndn.CmplRqRsltUUID

  --Worker - Other Factors
  association [0..*] to I_CntrbtScenWrkrOthFctrTP     as _CntrbtScenWrkrOthFctr     on $projection.CmplRqRsltUUID = _CntrbtScenWrkrOthFctr.CmplRqRsltUUID

  --Worker -Personal Risk Management
  association [0..*] to I_CntrbtScenWrkrPersRskMgmtTP as _CntrbtScenWrkrPersRskMgmt on $projection.CmplRqRsltUUID = _CntrbtScenWrkrPersRskMgmt.CmplRqRsltUUID

  --Exposure Estimation Worker
  association [0..*] to I_CntrbtScenWrkrExpsrEstnTP   as _CntrbtScenWrkrExpsrEstn   on $projection.CmplRqRsltUUID = _CntrbtScenWrkrExpsrEstn.CmplRqRsltUUID

  --Exposure Estimation Additional Detail Worker
  association [0..*] to I_CntrbtScenWrkrEstnDetTP     as _CntrbtScenWrkrEstnDet     on $projection.CmplRqRsltUUID = _CntrbtScenWrkrEstnDet.CmplRqRsltUUID

  --Technical and organizational risk management measures
  association [0..*] to I_CntrbtScenWrkrTechRskMgmtTP as _CntrbtScenTechOrglRskMgmt on $projection.CmplRqRsltUUID = _CntrbtScenTechOrglRskMgmt.CmplRqRsltUUID

  --Additional Good Practice Advice
  association [0..*] to I_CntrbtScenWrkrAdvcTP        as _CntrbtScenWrkrAdvc        on $projection.CmplRqRsltUUID = _CntrbtScenWrkrAdvc.CmplRqRsltUUID

  --Frequency/Duration
  association [0..*] to I_CntrbtScenWrkrFrqcyDurnTP   as _CntrbtScenWrkrFrqcyDurn   on $projection.CmplRqRsltUUID = _CntrbtScenWrkrFrqcyDurn.CmplRqRsltUUID


  --Link to user data
  association [0..1] to I_User                        as _CreatedByUser             on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                        as _LastChangedByUser         on $projection.LastChangedByUser = _LastChangedByUser.UserID


{
      /****  Keys  ****/

      @ObjectModel.mandatory: true
  key CmplRqRsltUUID,

      @ObjectModel.readOnly: true
      cast(CmplRqRsltUUID as ehfnd_crr_active_uuid preserving type ) as ActiveCmplRqRsltUUID, --Active UUID of CRR

      @ObjectModel.mandatory: true
      CmplRqVersUUID,

      ChmlCmplncInfoUUID,

      PCESScenarioUUID,

      _ExposureScenario.PCESExposureScenarioType,

      _ExposureScenario.PCESScenarioType,

      @ObjectModel.readOnly: true
      _CntrbtScenWrkrGenData.PCESShortTitlePhrs1UUID,

      @ObjectModel.readOnly: true
      _CntrbtScenWrkrGenData.PCESShortTitlePhrs2UUID,

      @ObjectModel.readOnly: true
      _CntrbtScenWrkrGenData.PCESShortTitlePhrs3UUID,

      @ObjectModel.readOnly: true
      _CntrbtScenWrkrGenData.PCESShortTitlePhrs4UUID,

      @ObjectModel.readOnly: true
      _CntrbtScenWrkrGenData.PCESShortTitlePhrs5UUID,

      @ObjectModel.readOnly: true
      _CntrbtScenWrkrGenData.PCESShortTitlePhrs6UUID,

      /****  Content  ****/
      ComplianceRequirement, // needed for DCL


      @ObjectModel.readOnly: true
      CreationDateTime,

      @ObjectModel.readOnly: true
      CreatedByUser,

      @ObjectModel.readOnly: true
      LastChangeDateTime,

      @ObjectModel.readOnly: true
      LastChangedByUser,

      @ObjectModel.mandatory: true
      CmplRqRsltProcessingStatus,

      //      Processor,

      Processor                                                      as CmplRqRsltProcessor,

      ReleasedByUser,

      ValidityStartDateTime,

      ValidityEndDateTime,

      CmplRqRsltReldCmplncSts,

      CmplRqRsltCalculatedStatus,

      CmplRqRsltManualStatus,

      CmplRqRsltPrelimCmplncSts,

      CmplRqRsltStatusRemark,


      /**** Associations ****/

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenWrkrGenData,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenWrkrAmtUsed,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenWrkrProdCharc,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenWrkrOplCndn,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenWrkrOthFctr,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenWrkrExpsrEstn,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenWrkrEstnDet,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenWrkrPersRskMgmt,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenTechOrglRskMgmt,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenWrkrAdvc,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CntrbtScenWrkrFrqcyDurn,

      _CmplRqRsltProcessingStatus,

      _CreatedByUser,

      _LastChangedByUser

}
where
      _CmplRqVers.CmplRqPattern = 'CompliancePatternExpsrScen'
  and _ExposureScenario.PCESScenarioType          = 'WRK'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CMPLRQRSLT",
"I_CMPLRQVERSENHANCED",
"I_CNTRBTSCENWRKRGENDATATP",
"I_EXPOSURESCENARIO"
],
"ASSOCIATED":
[
"I_CMPLRQRSLTPROCESSINGSTATUS",
"I_CNTRBTSCENWRKRADVCTP",
"I_CNTRBTSCENWRKRAMTUSEDTP",
"I_CNTRBTSCENWRKRESTNDETTP",
"I_CNTRBTSCENWRKREXPSRESTNTP",
"I_CNTRBTSCENWRKRFRQCYDURNTP",
"I_CNTRBTSCENWRKRGENDATATP",
"I_CNTRBTSCENWRKROPLCNDNTP",
"I_CNTRBTSCENWRKROTHFCTRTP",
"I_CNTRBTSCENWRKRPERSRSKMGMTTP",
"I_CNTRBTSCENWRKRPRODCHARCTP",
"I_CNTRBTSCENWRKRTECHRSKMGMTTP",
"I_EXPOSURESCENARIO",
"I_USER"
],
"BASE":
[
"I_CMPLRQRSLT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/