I_CmplRqRsltGHSClfnAssmtTP

@EndUserText.label: 'GHS Classification Assessment - TP'

@AbapCatalog:
{
  sqlViewName: 'ICRRGHSCTP',
  compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #CHECK,
  privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser', '_ReleasedByUser' ]
}

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM:
{
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}

@ObjectModel:
{
  --Transactional Annotations for the generated BO
  modelCategory: #BUSINESS_OBJECT,
  compositionRoot: true,
  transactionalProcessingEnabled: true,
  createEnabled: 'EXTERNAL_CALCULATION',
  updateEnabled: 'EXTERNAL_CALCULATION',
  deleteEnabled: 'EXTERNAL_CALCULATION',
  draftEnabled: true,
  writeDraftPersistence: 'EHSDSW_CRR_GHSC',
  writeActivePersistence: 'EHFNDV_CRR2',
  entityChangeStateId: 'LastChangeDateTime',
  semanticKey:  [ 'CmplRqRsltUUID' ],
  sapObjectNodeType.name: 'GHSClassificationAssessment',
  usageType:
  {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #L,
    serviceQuality: #C
  }
}
 
define view I_CmplRqRsltGHSClfnAssmtTP 
  --Select data from basic view 'GHS Classification Assessment'
  as select from I_CmplRqRslt 

  --GHS Classification
  association [0..*] to I_CmplRqRsltGHSClfnTP          as _CmplRqRsltGHSClfn          on  $projection.CmplRqRsltUUID = _CmplRqRsltGHSClfn.CmplRqRsltUUID

  --Specific Concentration Limit
  association [0..*] to I_CmplRqRsltGHSConcnLmtTP      as _CmplRqRsltGHSConcnLmt      on  $projection.CmplRqRsltUUID = _CmplRqRsltGHSConcnLmt.CmplRqRsltUUID

  --Acute Toxicity Estimation
  association [0..1] to I_CmplRqRsltGHSConcnAcuteEstTP as _CmplRqRsltGHSConcnAcuteEst on  $projection.CmplRqRsltUUID = _CmplRqRsltGHSConcnAcuteEst.CmplRqRsltUUID

  --Reason For No Data Assignment
  association [0..1] to I_CmplRqRsltGHSClfnRsnNoDataTP as _CmplRqRsltGHSClfnRsnNoData on  $projection.CmplRqRsltUUID = _CmplRqRsltGHSClfnRsnNoData.CmplRqRsltUUID

  --Product Category
  association [0..1] to I_ChmlComposition              as _ChmlComposition            on  $projection.ChmlCmplncInfoUUID         = _ChmlComposition.ChmlCmplncInfoUUID
                                                                                      and $projection.ChmlCompositionType        = _ChmlComposition.ChmlCompositionType
                                                                                      and _ChmlComposition.ChmlCompositionStatus = 'RE'
  --Link to user data
  association [0..1] to I_User                         as _CreatedByUser              on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                         as _LastChangedByUser          on  $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [0..1] to I_User                         as _ReleasedByUser             on  $projection.ReleasedByUser = _ReleasedByUser.UserID

{
      --CmplRqRsltUUID
      @ObjectModel.mandatory: true
  key CmplRqRsltUUID,

      @ObjectModel.readOnly: true
      CmplRqRsltUUID as ActiveCmplRqRsltUUID, --Active UUID of CRR

      --UUID of CRV
      @ObjectModel.mandatory: true
      CmplRqVersUUID,

      --UUID of CCI
      ChmlCmplncInfoUUID,

      --UUID of substance
      SubstanceUUID,

      --UUID of Supplier Material
      ChmlSuplrMatlUUID,

      --Compliance Requirement
      ComplianceRequirement,

      --Create at date/time and by user
      @ObjectModel.readOnly: true
      CreationDateTime,
      @ObjectModel.readOnly: true
      CreatedByUser,

      --Update at date/time and by user
      @ObjectModel.readOnly: true
      LastChangeDateTime,
      @ObjectModel.readOnly: true
      LastChangedByUser,

      --Processing status
      @ObjectModel.mandatory: true
      CmplRqRsltProcessingStatus,

      --Processor,
      Processor      as CmplRqRsltProcessor,

      --Released by user
      ReleasedByUser,

      --Valid from (release date)
      ValidityStartDateTime,

      --Valid to
      ValidityEndDateTime,

      --Released Compliance Status
      CmplRqRsltReldCmplncSts,

      --Calculated Status
      CmplRqRsltCalculatedStatus,

      --Manual status
      CmplRqRsltManualStatus,

      --Status Remark
      CmplRqRsltStatusRemark,

      --Composition Type
      ChmlCompositionType,

      --Material is sold
      MaterialIsSold,

      --Material is transported
      MaterialIsTransported,

      --Material is sourced
      MaterialIsSourced,

      --Material is produced
      MaterialIsProduced,

      /**** Associations ****/
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _CmplRqRsltGHSClfn,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _CmplRqRsltGHSClfnRsnNoData,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _CmplRqRsltGHSConcnLmt,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _CmplRqRsltGHSConcnAcuteEst,

      _ChmlCmplncInfo,
      _ChmlComposition,
      _Substance,
      _CmplRqVers,
      _CreatedByUser,
      _LastChangedByUser,
      _ReleasedByUser,
      _CmplRqRsltProcessingStatus
}

where
  _CmplRqVers.CmplRqPattern = 'CompliancePatternGHSClfn'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CMPLRQRSLT",
"I_CMPLRQVERSENHANCED"
],
"ASSOCIATED":
[
"I_CHMLCMPLNCINFO",
"I_CHMLCOMPOSITION",
"I_CMPLRQRSLTGHSCLFNRSNNODATATP",
"I_CMPLRQRSLTGHSCLFNTP",
"I_CMPLRQRSLTGHSCONCNACUTEESTTP",
"I_CMPLRQRSLTGHSCONCNLMTTP",
"I_CMPLRQRSLTPROCESSINGSTATUS",
"I_CMPLRQVERSENHANCED",
"I_SUBSTANCEENHANCED",
"I_USER"
],
"BASE":
[
"I_CMPLRQRSLT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/