I_MaintenanceOrder

@EndUserText.label: 'Maintenance Order'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations:['_LocationAccountAssignment']
@AbapCatalog: { sqlViewName: 'IMAINTORDER', compiler.compareFilter, preserveKey }
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ObjectModel.representativeKey: 'MaintenanceOrder'
@ObjectModel.semanticKey:  [ 'MaintenanceOrder' ]
@Metadata.ignorePropagatedAnnotations: true

// BOPF objects are generated from --> I_MaintOrderTechObj !


@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #XL

define view I_MaintenanceOrder
  as select from     I_MaintenanceOrderBasic as _OrderBasic
  association [0..1] to I_LogisticsOrder              as _Order                      on  _Order.OrderID = $projection.MaintenanceOrder // AUFK (Order master data) and AFKO (Order Header data )

  association [1..1] to I_OrderCategory               as _MaintenanceOrderCategory   on  $projection.MaintenanceOrderCategory = _MaintenanceOrderCategory.OrderCategory
  association [1..1] to I_OrderType                   as _MaintenanceOrderType       on  $projection.MaintenanceOrderType = _MaintenanceOrderType.OrderType
  association [0..1] to I_ControllingArea             as _ControllingArea            on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_ControllingObjectClass      as _ControllingObjectClass     on  $projection.ControllingObjectClass = _ControllingObjectClass.ControllingObjectClass
  association [0..1] to I_CompanyCode                 as _CompanyCode                on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..*] to I_CostCenter                  as _ResponsibleCostCenter      on  $projection.ControllingArea       = _ResponsibleCostCenter.ControllingArea
                                                                                     and $projection.ResponsibleCostCenter = _ResponsibleCostCenter.CostCenter
  association [0..*] to I_ProfitCenter                as _ProfitCenter               on  $projection.ControllingArea = _ProfitCenter.ControllingArea
                                                                                     and $projection.ProfitCenter    = _ProfitCenter.ProfitCenter
  association [0..1] to I_Plant                       as _LocationPlant              on  $projection.MaintenancePlant = _LocationPlant.Plant
  association [0..1] to I_SchedulingType              as _BasicSchedulingType        on  $projection.BasicSchedulingType = _BasicSchedulingType.SchedulingType
  association [0..1] to I_MaintenanceTaskList         as _MaintenanceTaskList        on  $projection.TaskListType         = _MaintenanceTaskList.TaskListType
                                                                                     and $projection.TaskListGroup        = _MaintenanceTaskList.TaskListGroup
                                                                                     and $projection.TaskListGroupCounter = _MaintenanceTaskList.TaskListGroupCounter
  with default filter _MaintenanceTaskList.ValidityEndDate = '99991231'

  /* Order Refurbishment Item */
  association [0..1] to I_OrderItem                   as _OrderItem                  on  $projection.MaintenanceOrder = _OrderItem.OrderID
                                                                                     and _OrderItem.OrderItem         = '0001'
  association [0..*] to I_MaintenanceOrderOperation   as _MaintenanceOrderOperation  on  $projection.MaintOrderRoutingNumber = _MaintenanceOrderOperation.MaintOrderRoutingNumber
  association [0..*] to I_MaintenanceOrderCost        as _MaintenanceOrderCost       on  $projection.MaintenanceOrderInternalID = _MaintenanceOrderCost.MaintenanceOrderInternalID
  association [0..*] to I_MaintenanceOrderComponent_2 as _MaintenanceOrderComponent  on  $projection.MaintenanceOrder = _MaintenanceOrderComponent.MaintenanceOrder

  association [0..1] to I_LocationAccountAssignment   as _LocationAccountAssignment  on  $projection.MaintObjectLocAcctAssgmtNmbr = _LocationAccountAssignment.MaintObjectLocAcctAssgmtNmbr
  association [0..1] to I_MaintenanceNotification     as _MaintenanceNotification    on  $projection.MaintenanceNotification = _MaintenanceNotification.MaintenanceNotification
  association [0..1] to I_Equipment                   as _Equipment                  on  $projection.Equipment = _Equipment.Equipment
  association [0..1] to I_Material                    as _Assembly                   on  $projection.Assembly = _Assembly.Material
  association [0..1] to I_MaintenancePlanBasic        as _MaintenancePlan            on  $projection.MaintenancePlan = _MaintenancePlan.MaintenancePlan
  association [0..1] to I_MaintenanceItem             as _MaintenanceItem            on  $projection.MaintenanceItem = _MaintenanceItem.MaintenanceItem
  association [0..1] to I_Plant                       as _MaintenancePlanningPlant   on  $projection.MaintenancePlanningPlant = _MaintenancePlanningPlant.Plant
  association [0..1] to I_PMNotificationPriorityType  as _MaintenancePriorityType    on  $projection.MaintPriorityType = _MaintenancePriorityType.MaintPriorityType
  // Todo: check if I_Priority has to be created

  association [0..1] to I_PMNotificationPriority      as _MaintenancePriority        on  $projection.MaintPriority     = _MaintenancePriority.MaintPriority
                                                                                     and $projection.MaintPriorityType = _MaintenancePriority.MaintPriorityType
  association [0..1] to I_WorkCenter                  as _MainWorkCenter             on  $projection.WorkCenterInternalID = _MainWorkCenter.WorkCenterInternalID
                                                                                     and $projection.WorkCenterTypeCode   = _MainWorkCenter.WorkCenterTypeCode
  association [1..1] to I_WorkCenterType              as _WorkCenterType             on  $projection.WorkCenterTypeCode = _WorkCenterType.WorkCenterTypeCode
  association [0..1] to I_MaintenanceActivityType     as _MaintenanceActivityType    on  $projection.MaintenanceActivityType = _MaintenanceActivityType.MaintenanceActivityType
  association [0..*] to I_PlantMaintenancePartner     as _MaintenancePartner         on  $projection.MaintenanceOrderInternalID = _MaintenancePartner.MaintObjectInternalID
  association [0..1] to I_BusinessArea                as _BusinessArea               on  $projection.BusinessArea = _BusinessArea.BusinessArea
  association [0..1] to I_FunctionalArea              as _FunctionalArea             on  $projection.FunctionalArea = _FunctionalArea.FunctionalArea
  association [0..1] to I_MaintenancePlannerGroup     as _MaintenancePlannerGroup    on  $projection.MaintenancePlannerGroup  = _MaintenancePlannerGroup.MaintenancePlannerGroup
                                                                                     and $projection.MaintenancePlanningPlant = _MaintenancePlannerGroup.MaintenancePlanningPlant
  association [0..1] to I_MaintenanceOrderPhase       as _MaintenanceOrderPhase      on  $projection.MaintenanceProcessingPhase = _MaintenanceOrderPhase.MaintenanceProcessingPhase
  association [0..1] to I_StatusObject                as _StatusObject               on  $projection.MaintenanceOrderInternalID = _StatusObject.StatusObject
  association [1..*] to I_StatusObjectStatus          as _StatusObjectStatus         on  $projection.MaintenanceOrderInternalID = _StatusObjectStatus.StatusObject
  association [0..1] to I_MaintOperationSystCondition as _OperationSystemCondition   on  $projection.OperationSystemCondition = _OperationSystemCondition.OperationSystemCondition
  association [0..1] to I_Indicator                   as _OrderHasLongText           on  $projection.OrderHasLongText = _OrderHasLongText.IndicatorValue
  association [0..1] to I_MaintOrdPlngDegreeCode      as _MaintOrdPlngDegreeCode     on  $projection.MaintenanceOrderPlanningCode = _MaintOrdPlngDegreeCode.MaintenanceOrderPlanningCode
  association [0..1] to I_MaintenanceRevision         as _MaintenanceRevision        on  $projection.MaintenancePlanningPlant = _MaintenanceRevision.MaintenancePlanningPlant
                                                                                     and $projection.MaintenanceRevision      = _MaintenanceRevision.MaintenanceRevision

  association [0..1] to I_MaintOrderTypeControlParam  as _MaintOrderTypeControlParam on  $projection.MaintenanceOrderType = _MaintOrderTypeControlParam.OrderType
  association [0..*] to I_StatusObjectActiveStatus    as _StatusObjectActiveStatus   on  $projection.MaintenanceOrderInternalID = _StatusObjectActiveStatus.StatusObject
  association [0..1] to I_User                        as _CreatedByUser              on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..*] to I_MaintenanceItemObject       as _MaintenanceItemObject      on  $projection.MaintenanceItemObjectList = _MaintenanceItemObject.MaintenanceItemObjectList
  association [0..*] to I_MaintenanceOrderObjectList  as _MaintenanceOrderObjectList on  $projection.MaintenanceOrderObjectList = _MaintenanceOrderObjectList.MaintenanceOrderObjectList
  association [0..1] to I_OrderProcessingGroup        as _OrderProcessingGroup       on  $projection.ControllingArea      = _OrderProcessingGroup.ControllingArea
                                                                                     and $projection.OrderProcessingGroup = _OrderProcessingGroup.OrderProcessingGroup
  association [0..1] to I_WBSElementByInternalKey     as _WBSElement                 on  $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
  association [0..1] to I_ProjectByInternalKey        as _Project                    on  $projection.ProjectInternalID = _Project.ProjectInternalID
  association [0..*] to I_CostCenterText              as _ResponsibleCostCenterText  on  $projection.ControllingArea                  = _ResponsibleCostCenterText.ControllingArea
                                                                                     and $projection.ResponsibleCostCenter            = _ResponsibleCostCenterText.CostCenter
                                                                                     and _ResponsibleCostCenterText.ValidityStartDate <= $session.system_date
                                                                                     and _ResponsibleCostCenterText.ValidityEndDate   >= $session.system_date
  association [0..1] to I_PMContactCardEmployee       as _PMContactEmployee          on  $projection.PersonnelNumber = _PMContactEmployee.PersonnelNumber
  association [0..1] to I_PersonWorkAgreement_1       as _PersonWorkAgreement        on  $projection.PersonnelNumber = _PersonWorkAgreement.PersonWorkAgreement
  association [0..1] to I_MaintOrderHasOpenMainWork   as _MaintOrderHasOpenMainWork  on  $projection.MaintenanceOrder = _MaintOrderHasOpenMainWork.MaintenanceOrder

  association [0..1] to E_MaintenanceOrder            as _MaintenanceOrderExtension  on  $projection.MaintenanceOrder = _MaintenanceOrderExtension.MaintenanceOrder

  association [0..1] to I_MaintenancePlanPlant        as _MaintenancePlanPlant       on  $projection.MaintenancePlanningPlant = _MaintenancePlanPlant.MaintenancePlanningPlant

  association [0..1] to I_EAMProcessPhase             as _EAMProcessPhase            on  $projection.MaintOrdProcessPhaseCode = _EAMProcessPhase.EAMProcessPhaseCode
  association [0..1] to I_EAMProcessSubPhase          as _EAMProcessSubPhase         on  $projection.MaintOrdProcessSubPhaseCode = _EAMProcessSubPhase.EAMProcessSubPhaseCode

  association [0..1] to I_CtrlgObjectSettlementRule   as _CtrlgObjectSettlementRule  on  $projection.MaintenanceOrderInternalID = _CtrlgObjectSettlementRule.ControllingObject
  association [0..1] to I_CostingSheetProcedure       as _CostingSheetProcedure      on  $projection.ConditionUsage       = _CostingSheetProcedure.ConditionUsage
                                                                                     and $projection.ConditionApplication = _CostingSheetProcedure.ConditionApplication
                                                                                     and $projection.CostingSheet         = _CostingSheetProcedure.CostingSheetProcedure
  association [0..1] to I_InternalOrderOverheadCodeVH as _OverheadCode               on  $projection.MaintenanceOrderOverheadCode = _OverheadCode.OverheadCode
  association [1..1] to I_CostingVariant              as _PlannedCostingVariant      on  $projection.PlannedCostsCostingVariant = _PlannedCostingVariant.CostingVariant
  association [1..1] to I_CostingVariant              as _ActualCostingVariant       on  $projection.ActualCostsCostingVariant = _ActualCostingVariant.CostingVariant
  
  association [0..1] to I_WrkPmtMaintOrderRelevance   as _WrkPmtMaintOrderRelevance  on  $projection.MaintenanceOrderInternalID = _WrkPmtMaintOrderRelevance.MaintenanceOrderInternalID 
{
      /* Fields */
      @ObjectModel.text.element:  [ 'MaintenanceOrderDesc' ]
      //      @ObjectModel.foreignKey.association: '_MaintOrderHasOpenMainWork'

  key _OrderBasic.MaintenanceOrder,

      @ObjectModel.foreignKey.association: '_MaintenancePriorityType'
      _OrderBasic.MaintPriorityType,

      @ObjectModel.foreignKey.association: '_MaintenancePriority'
      _OrderBasic.MaintPriority,

      @ObjectModel.foreignKey.association: '_MaintenanceOrderPhase'
      _OrderBasic.MaintenanceProcessingPhase,

      @ObjectModel.foreignKey.association: '_LocationAccountAssignment'
      _OrderBasic.MaintObjectLocAcctAssgmtNmbr,

      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaintNotifStdVH',
                     element: 'MaintenanceNotification' }
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_MaintenanceNotification'
      _OrderBasic.MaintenanceNotification,

      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_EquipmentStdVH',
                     element: 'Equipment' }
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_Equipment'
      _OrderBasic.Equipment,

      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaterialStdVH',
                     element: 'Material' }
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_Assembly'
      _OrderBasic.Assembly,

      _OrderBasic.SerialNumber,

      @ObjectModel.foreignKey.association: '_MaintenancePlanPlant'
      _OrderBasic.MaintenancePlanningPlant,

      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaintPlnrGrpStdVH',
                     element: 'MaintenancePlannerGroup' },
          additionalBinding: [{ localElement: 'MaintenancePlanningPlant',
                                element: 'MaintenancePlanningPlant' }]
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_MaintenancePlannerGroup'
      _OrderBasic.MaintenancePlannerGroup,

      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaintenanceRevisionStdVH',
                     element: 'MaintenanceRevision' },
          additionalBinding: [{ localElement: 'MaintenancePlanningPlant',
                                element: 'MaintenancePlanningPlant' }]
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_MaintenanceRevision'
      _OrderBasic.MaintenanceRevision,
      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaintenancePlanStdVH',
                     element: 'MaintenancePlan' }
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_MaintenancePlan'
      _OrderBasic.MaintenancePlan,

      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaintenanceItemStdVH',
                     element: 'MaintenanceItem' }
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_MaintenanceItem'
      _OrderBasic.MaintenanceItem,

      //--[ GENERATED:012:GFBfhxvv7kY4nH9{xKJeWG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_MaintActyTypeStdVH',
                     element: 'MaintenanceActivityType' }
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_MaintenanceActivityType'
      _OrderBasic.MaintenanceActivityType,

      @ObjectModel.foreignKey.association: '_MainWorkCenter'
      _OrderBasic.WorkCenterInternalID,

      @ObjectModel.foreignKey.association: '_WorkCenterType'
      _OrderBasic.WorkCenterTypeCode,

      _OrderBasic.MaintOrderReferenceDate,
      _OrderBasic.MaintOrderReferenceTime,

      _OrderBasic.MainWorkCompletedDateTime,

      @ObjectModel.foreignKey.association: '_MaintOrdPlngDegreeCode'
      _OrderBasic.MaintenanceOrderPlanningCode,

      @ObjectModel.foreignKey.association: '_OperationSystemCondition'
      _OrderBasic.OperationSystemCondition,

      _OrderBasic.ReferenceElement,

      _OrderBasic.MaintenanceItemObjectList,

      _OrderBasic.MaintenanceOrderObjectList,

      _OrderBasic.PersonnelNumber,
      /* Fields to be renamed from I_LogisticsOrder (AUFK, AFKO) */

      _OrderBasic.MaintOrdProcmtIntegScenario,

      _OrderBasic.Material,

      _OrderBasic.MaintOrderRoutingNumber,

      @ObjectModel.foreignKey.association: '_BusinessArea'
      _OrderBasic.BusinessArea,
      @ObjectModel.foreignKey.association: '_FunctionalArea'
      _OrderBasic.FunctionalArea,

      @ObjectModel.foreignKey.association: '_MaintenanceOrderType'
      _OrderBasic.MaintenanceOrderType,

      @ObjectModel.foreignKey.association: '_MaintenanceOrderCategory'
      _OrderBasic.MaintenanceOrderCategory,

      @Semantics.text: true
      _OrderBasic.MaintenanceOrderDesc,

      @ObjectModel.foreignKey.association: '_ControllingArea'
      _OrderBasic.ControllingArea,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } } ]
      @ObjectModel.foreignKey.association: '_CompanyCode'
      _OrderBasic.CompanyCode,

      @ObjectModel.foreignKey.association: '_ResponsibleCostCenter'
      @ObjectModel.text.association: '_ResponsibleCostCenterText'
      _OrderBasic.ResponsibleCostCenter,

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProfitCenterStdVH', element: 'ProfitCenter' } } ]
      @ObjectModel.foreignKey.association: '_ProfitCenter'
      _OrderBasic.ProfitCenter,

      @ObjectModel.foreignKey.association: '_ControllingObjectClass'
      _OrderBasic.ControllingObjectClass,

      _OrderBasic.TechnicalCompletionDate,

      @ObjectModel.foreignKey.association: '_BasicSchedulingType'
      _OrderBasic.BasicSchedulingType,

      _OrderBasic.OrdIsNotSchedldAutomatically,

      _OrderBasic.MaintOrdBasicStartDate,
      _OrderBasic.MaintOrdBasicStartTime,

      _OrderBasic.MaintOrdBasicEndDate,
      _OrderBasic.MaintOrdBasicEndTime,

      _OrderBasic.ScheduledBasicStartDate,
      _OrderBasic.ScheduledBasicStartTime,
      _OrderBasic.ScheduledBasicEndDate,
      _OrderBasic.ScheduledBasicEndTime,

      -- will require DPP protection (todo CE2008)
      _OrderBasic.MaintOrdPersonResponsible,

      _OrderBasic.MaintenanceOrderInternalID,

      _OrderBasic.TaskListGroup,
      _OrderBasic.TaskListType,
      _OrderBasic.TaskListGroupCounter,

      @ObjectModel.foreignKey.association: '_LocationPlant'
      _OrderBasic.MaintenancePlant,

      @Semantics.systemDate.createdAt: true
      _OrderBasic.CreationDate,
      @Semantics.systemTime.createdAt: true
      _OrderBasic.CreationTime,
      @Semantics.user.createdBy: true
      _OrderBasic.CreatedByUser,

      @ObjectModel.foreignKey.association: '_OrderHasLongText'
      _OrderBasic.OrderHasLongText,

      @Semantics.user.lastChangedBy: true
      _OrderBasic.LastChangeByUser,
      @ObjectModel.readOnly: true
      _OrderBasic.LastChangeDateTime,

      _OrderBasic.AdditionalDeviceData,

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_WBSElmntByIntKeyStdVH', element: 'WBSElementInternalID' } } ]
      @ObjectModel.foreignKey.association: '_WBSElement'
      _OrderBasic.WBSElementInternalID,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProjectByInternalKeyStdVH', element: 'ProjectInternalID' } } ]
      @ObjectModel.foreignKey.association: '_Project'
      _OrderBasic.ProjectInternalID,
      @ObjectModel.foreignKey.association: '_OrderProcessingGroup'
     _OrderBasic.OrderProcessingGroup,
      _OrderBasic.SuperiorProjectNetwork,
      _OrderBasic.MainWorkCenter,
      _OrderBasic.MainWorkCenterPlant,
      _OrderBasic.CostingSheet,
      _OrderBasic.Currency,

      // IME: 2002 LACD

     _OrderBasic.LatestAcceptableCompletionDate,
      // IME:2002 LACD

  
      //

      @ObjectModel.foreignKey.association: '_EAMProcessPhase'
      _OrderBasic.MaintOrdProcessPhaseCode,
      @ObjectModel.foreignKey.association: '_EAMProcessSubPhase'
      _OrderBasic.MaintOrdProcessSubPhaseCode,

      _OrderBasic.MaintOrderProcessingContext,
      _OrderBasic.ServiceDocumentType,
      _OrderBasic.ServiceDocument,
      _OrderBasic.ServiceDocumentItem,
      /* Control Parameters*/
      _OrderBasic.ConditionUsage,
      _OrderBasic.ConditionApplication,
      _OrderBasic.MaintenanceOrderOverheadCode,
      _OrderBasic.PlannedCostsCostingVariant,
      _OrderBasic.ActualCostsCostingVariant,
      /* maintenance plan */
      _OrderBasic.MaintenanceCall,
      _OrderBasic.LeadingOrder,
      _OrderBasic.PrevLtstAccptblCompletionDate,
      /* Associations */
      _Order,
      _MaintenanceOrderCategory,
      _MaintenanceOrderType,
      _ControllingArea,
      _ResponsibleCostCenter,
      _LocationPlant,
      _BasicSchedulingType,
      _LocationAccountAssignment,
      _MaintenanceNotification,
      _Equipment,
      _CompanyCode,
      _MaintenancePlan,
      _MaintenanceItem,
      _OrderItem,
      _MaintenanceTaskList,
      _MaintenancePriorityType,
      _MaintenancePriority,
      _MaintenanceOrderPhase,
      _StatusObject,
      _MaintenanceOrderOperation,
      _MaintenanceOrderComponent,
      _MainWorkCenter,
      _BusinessArea,
      _FunctionalArea,
      _MaintenancePartner,
      _MaintenanceActivityType,
      _MaintenancePlannerGroup,
      _StatusObjectStatus,
      _MaintenancePlanningPlant,
      _Assembly,
      _OperationSystemCondition,
      _MaintenanceOrderCost,
      _WorkCenterType,
      _OrderHasLongText,
      _MaintOrdPlngDegreeCode,
      _MaintenanceRevision,
      _MaintOrderTypeControlParam,
      _StatusObjectActiveStatus,
      _CreatedByUser,
      _MaintenanceItemObject,
      _ResponsibleCostCenterText,
      _ProfitCenter,
      _ControllingObjectClass,
      _OrderProcessingGroup,
      _WBSElement,
      _Project,
      _PMContactEmployee,
      _PersonWorkAgreement,
      _MaintOrderHasOpenMainWork,
      _MaintenancePlanPlant,
      _MaintenanceOrderObjectList,
      _EAMProcessPhase,
      _EAMProcessSubPhase,
      _CtrlgObjectSettlementRule,
      _CostingSheetProcedure,
      _OverheadCode,
      _PlannedCostingVariant,
      _ActualCostingVariant,
      _WrkPmtMaintOrderRelevance
}