I_LogisticsOrder

@AbapCatalog.sqlViewName: 'ILOGISTCSORDER'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.privilegedAssociations: ['_CreatedByUser', '_LastChangedByUser', '_CreatedByUserContactCard', '_LastChgdByUserContactCard', '_LongText',
                                        '_ProductionSupervisor', '_MRPController', '_StatusObject', '_StatusObjectStatus', '_MaintenanceObjectLocation', '_StatusObject']                                        
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE]
@ObjectModel.representativeKey: 'OrderID'
@ObjectModel.semanticKey: ['OrderID']
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Logistics Order'
// basic view for orders of logistics categories (AUFTYP=10,20,30,40)


/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view I_LogisticsOrder
  as select from           I_OrderBasic          as aufk
    left outer to one join I_LogisticsOrderBasic as afko on afko.OrderID = aufk.OrderID

  association [0..1] to I_OrdInternalBillOfOperations as _OrdInternalBillOfOperations on  $projection.OrderInternalBillOfOperations = _OrdInternalBillOfOperations.OrderInternalBillOfOperations
  association [0..1] to I_OrderInternalID             as _OrderInternalID             on  $projection.OrderInternalBillOfOperations = _OrderInternalID.OrderInternalID
  association [1..1] to I_OrderCategory               as _OrderCategory               on  $projection.OrderCategory = _OrderCategory.OrderCategory
  association [1..1] to I_OrderType                   as _OrderType                   on  $projection.OrderType = _OrderType.OrderType
  association [1..1] to I_OrderTypeDetails            as _OrderTypeDetails            on  $projection.OrderType = _OrderTypeDetails.OrderType
                                                                                      and $projection.Plant     = _OrderTypeDetails.Plant
  association [0..1] to I_Order                       as _ReferenceOrder              on  $projection.ReferenceOrder = _ReferenceOrder.OrderID
  association [0..1] to I_Order                       as _LeadingOrder                on  $projection.LeadingOrder = _LeadingOrder.OrderID
  association [0..1] to I_Order                       as _SuperiorOrder               on  $projection.MfgOrderSuperiorMfgOrder = _SuperiorOrder.OrderID
  association [0..*] to I_OrderItem                   as _OrderItem                   on  $projection.OrderID = _OrderItem.OrderID
  association [0..1] to I_OrderItem                   as _OrderMainItem               on  $projection.OrderID = _OrderMainItem.OrderID
                                                                                      and _OrderMainItem.OrderItem = '0001'
  association [0..*] to I_OrderSequence               as _OrderSequence               on  $projection.OrderInternalBillOfOperations = _OrderSequence.OrderInternalID
  association [0..*] to I_OrderOperation              as _OrderOperation              on  $projection.OrderInternalBillOfOperations = _OrderOperation.OrderInternalID
  association [0..*] to I_OrderComponent              as _OrderComponent              on  $projection.Reservation = _OrderComponent.Reservation
  association [0..1] to I_OrderLongText               as _LongText                    on  $projection.OrderID = _LongText.OrderID
  association [0..1] to I_LogisticsOrderPriority      as _OrderPriority               on  $projection.PriorityCode = _OrderPriority.PriorityCode
  association [1..1] to I_User                        as _CreatedByUser               on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                        as _LastChangedByUser           on  $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [1..1] to I_UserContactCard             as _CreatedByUserContactCard    on  $projection.CreatedByUser = _CreatedByUserContactCard.ContactCardID
  association [0..1] to I_UserContactCard             as _LastChgdByUserContactCard   on  $projection.LastChangedByUser = _LastChgdByUserContactCard.ContactCardID
  association [0..1] to I_Language                    as _LongTextLanguage            on  $projection.LongTextLanguage = _LongTextLanguage.Language
  association [0..1] to I_UnitOfMeasure               as _BaseUnit                    on  $projection.BaseUnit = _BaseUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure               as _MaterialBaseUnit            on  $projection.MaterialBaseUnit = _MaterialBaseUnit.UnitOfMeasure
  association [0..1] to I_Currency                    as _Currency                    on  $projection.Currency = _Currency.Currency
  association [1..1] to I_Plant                       as _Plant                       on  $projection.Plant = _Plant.Plant
  association [0..1] to I_Plant                       as _MainWorkCenterPlant         on  $projection.MainWorkCenterPlant = _MainWorkCenterPlant.Plant
  association [0..1] to I_Plant                       as _LocationPlant               on  $projection.LocationPlant = _LocationPlant.Plant
  association [0..1] to I_ConfirmationGroup           as _ConfirmationGroup           on  $projection.MfgOrderConfirmation = _ConfirmationGroup.ConfirmationGroup
  association [0..1] to I_ReservationDocumentHeader   as _Reservation                 on  $projection.Reservation = _Reservation.Reservation
  association [0..1] to I_ReservationDocumentHeader   as _SettlementReservation       on  $projection.SettlementReservation = _SettlementReservation.Reservation
  association [0..1] to I_SalesOrder                  as _SalesOrder                  on  $projection.SalesOrder = _SalesOrder.SalesOrder
  association [0..1] to I_SalesOrderItem              as _SalesOrderItem              on  $projection.SalesOrder     = _SalesOrderItem.SalesOrder
                                                                                      and $projection.SalesOrderItem = _SalesOrderItem.SalesOrderItem
  association [0..1] to I_WBSElementByInternalKey     as _WBSElement                  on  $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
  association [0..1] to I_WBSElementBasicData         as _WBSElementBasicData         on  $projection.WBSElementInternalID = _WBSElementBasicData.WBSElementInternalID
  association [0..1] to I_WBSElementBasicData         as _WBSElementBasicData2        on  $projection.WBSElementInternalID_2 = _WBSElementBasicData2.WBSElementInternalID
  association [0..1] to I_ProjectByInternalKey        as _Project                     on  $projection.ProjectInternalID = _Project.ProjectInternalID
  association [0..1] to I_ProjectBasicData            as _ProjectBasicData            on  $projection.ProjectInternalID = _ProjectBasicData.ProjectInternalID
  association [0..1] to I_ProjectBasicData            as _ProjectBasicData2           on  $projection.ProjectInternalID_2 = _ProjectBasicData2.ProjectInternalID
  association [0..1] to I_ProjectNetwork              as _SuperiorProjectNetwork      on  $projection.SuperiorProjectNetwork = _SuperiorProjectNetwork.ProjectNetwork
  association [0..1] to I_ProductionSupervisor        as _ProductionSupervisor        on  $projection.Plant                = _ProductionSupervisor.Plant
                                                                                      and $projection.ProductionSupervisor = _ProductionSupervisor.ProductionSupervisor
  association [0..1] to I_ProductionSchedulingProfile as _ProductionSchedulingProfile on  $projection.Plant                       = _ProductionSchedulingProfile.Plant
                                                                                      and $projection.ProductionSchedulingProfile = _ProductionSchedulingProfile.ProductionSchedulingProfile
  association [0..1] to I_ResponsiblePlannerGroup     as _ResponsiblePlannerGroup     on  $projection.Plant                   = _ResponsiblePlannerGroup.Plant
                                                                                      and $projection.ResponsiblePlannerGroup = _ResponsiblePlannerGroup.ResponsiblePlannerGroup
  association [0..1] to I_MRPController               as _MRPController               on  $projection.Plant         = _MRPController.Plant
                                                                                      and $projection.MRPController = _MRPController.MRPController
  association [0..1] to I_WorkCenterBySemanticKey     as _WorkCenter                  on  $projection.MainWorkCenter      = _WorkCenter.WorkCenter
                                                                                      and $projection.MainWorkCenterPlant = _WorkCenter.Plant
  association [0..1] to I_CapacityRequirement         as _CapacityRequirement         on  $projection.CapacityRequirement = _CapacityRequirement.CapacityRequirement
  association [0..1] to I_Location                    as _MaintenanceObjectLocation   on  $projection.LocationPlant             = _MaintenanceObjectLocation.Plant
                                                                                      and $projection.MaintenanceObjectLocation = _MaintenanceObjectLocation.Location
  association [0..1] to I_ChangeMaster                as _ChangeNumber                on  $projection.ChangeNumber = _ChangeNumber.ChangeNumber
  association [0..1] to I_BillOfOperationsType        as _BillOfOperationsType        on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType
  association [0..1] to I_BillOfOperationsGroup       as _BillOfOperationsGroup       on  $projection.BillOfOperationsType = _BillOfOperationsGroup.BillOfOperationsType
                                                                                      and $projection.BillOfOperations     = _BillOfOperationsGroup.BillOfOperationsGroup
  association [0..1] to I_BillOfOperationsGroup       as _BillOfOperationsGroup2      on  $projection.BillOfOperationsType  = _BillOfOperationsGroup2.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup = _BillOfOperationsGroup2.BillOfOperationsGroup
  association [0..1] to I_BillOfOperations            as _BillOfOperations            on  $projection.BillOfOperationsType    = _BillOfOperations.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup   = _BillOfOperations.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant
  association [0..1] to I_BillOfOperationsChangeState as _BillOfOperationsChangeState on  $projection.BillOfOperationsType      = _BillOfOperationsChangeState.BillOfOperationsType
                                                                                      and $projection.BillOfOperationsGroup     = _BillOfOperationsChangeState.BillOfOperationsGroup
                                                                                      and $projection.BillOfOperationsVariant   = _BillOfOperationsChangeState.BillOfOperationsVariant
                                                                                      and $projection.BOOInternalVersionCounter = _BillOfOperationsChangeState.BOOInternalVersionCounter
  association [0..1] to I_BOOApplication              as _BillOfOperationsApplication on  $projection.BillOfOperationsApplication = _BillOfOperationsApplication.BillOfOperationsApplication
  association [0..1] to I_BillOfOperationsUsage       as _BillOfOperationsUsage       on  $projection.BillOfOperationsUsage = _BillOfOperationsUsage.BillOfOperationsUsage
  association [0..1] to I_InspectionLot               as _InspectionLot               on  $projection.InspectionLot = _InspectionLot.InspectionLot
  association [0..1] to I_StatusObject                as _StatusObject                on  $projection.ObjectInternalID = _StatusObject.StatusObject   
  association [0..*] to I_StatusObjectStatus          as _StatusObjectStatus          on  $projection.ObjectInternalID = _StatusObjectStatus.StatusObject
                                                                                      and _StatusObjectStatus.StatusIsInactive = ''
  association [0..1] to I_CompanyCode                 as _CompanyCode                 on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_BusinessArea                as _BusinessArea                on  $projection.BusinessArea = _BusinessArea.BusinessArea
  association [0..*] to I_ProfitCenter                as _ProfitCenter                on  $projection.ControllingArea = _ProfitCenter.ControllingArea
                                                                                      and $projection.ProfitCenter    = _ProfitCenter.ProfitCenter
  association [0..*] to I_CostCenter                  as _CostCenter                  on  $projection.ControllingArea = _CostCenter.ControllingArea
                                                                                      and $projection.CostCenter      = _CostCenter.CostCenter
  association [0..*] to I_CostCenter                  as _ResponsibleCostCenter       on  $projection.ControllingArea       = _ResponsibleCostCenter.ControllingArea
                                                                                      and $projection.ResponsibleCostCenter = _ResponsibleCostCenter.CostCenter
  association [0..1] to I_GLAccount                   as _GLAccount                   on  $projection.GLAccount   = _GLAccount.GLAccount
                                                                                      and $projection.CompanyCode = _GLAccount.CompanyCode
  association [0..1] to I_ProductCostCtrlgOrder       as _ProductCostCollector        on  $projection.ProductCostCollector = _ProductCostCollector.OrderID 
  association [0..1] to I_ControllingArea             as _ControllingArea             on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_ControllingObjectClass      as _ControllingObjectClass      on  $projection.ControllingObjectClass = _ControllingObjectClass.ControllingObjectClass
  association [0..1] to I_FunctionalArea              as _FunctionalArea              on  $projection.FunctionalArea = _FunctionalArea.FunctionalArea
  association [0..1] to I_OrderProcessingGroup        as _OrderProcessingGroup        on  $projection.ControllingArea = _OrderProcessingGroup.ControllingArea
                                                                                      and $projection.OrderProcessingGroup = _OrderProcessingGroup.OrderProcessingGroup
  association [0..1] to I_SchedulingType              as _BasicSchedulingType         on  $projection.BasicSchedulingType = _BasicSchedulingType.SchedulingType
  association [0..1] to I_SchedulingType              as _ForecastSchedulingType      on  $projection.ForecastSchedulingType = _ForecastSchedulingType.SchedulingType
  association [0..1] to I_SchedulingFloatProfile      as _SchedulingFloatProfile      on  $projection.Plant                  = _SchedulingFloatProfile.Plant
                                                                                      and $projection.SchedulingFloatProfile = _SchedulingFloatProfile.SchedulingFloatProfile
  association [0..1] to I_RequestOrderType            as _RequestOrderType            on  $projection.RequestOrderType = _RequestOrderType.RequestOrderType
  association [0..1] to I_RFM_MasterProductOrder      as _RFM_MasterProductOrder      on  $projection.MasterProductionOrder = _RFM_MasterProductOrder.MasterProductionOrder
  -- to Extension view
  association [1..1] to E_LogisticsOrder              as _Extension                   on  aufk.OrderID = _Extension.OrderID
{
      // Key

//    @ObjectModel.text.element: ['OrderDescription']

  key aufk.OrderID,

      // Category and Type

      @ObjectModel.foreignKey.association: '_OrderCategory'
      aufk.OrderCategory,
      @ObjectModel.foreignKey.association: '_OrderType'
      aufk.OrderType,

      // Text

      @Semantics.text: true
      aufk.OrderDescription,
      aufk.OrderHasLongText,
      @ObjectModel.foreignKey.association: '_LongTextLanguage'
      aufk.LongTextLanguage,

      // Attributes

      aufk.IsMarkedForDeletion,
      aufk.IsStatisticalOrder,
      aufk.OrderHasMultipleItems                                 as MfgOrderHasMultipleItems,
      afko.MfgOrderIsPartOfCollvOrder,
      aufk.OrderIsRefurbishmentOrder,
      @ObjectModel.foreignKey.association: '_OrderPriority'
      afko.PriorityCode,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'OrderHierarchyLevelValue'
      afko.MfgOrderHierarchyLevel,
      afko.OrderHierarchyLevelValue,
      afko.OrderHierarchyPathValue,
      afko.ProdnProcgIsFlexible,
      afko.OrderIsNotCostedAutomatically,
      afko.OrdIsNotSchedldAutomatically,

      // Admin

      @Semantics.systemDate.createdAt: true
      aufk.CreationDate,
      @Semantics.systemTime.createdAt: true
      aufk.CreationTime,
      @Semantics.user.createdBy: true
      aufk.CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      aufk.LastChangeDate,
      @Semantics.systemTime.lastChangedAt: true
      aufk.LastChangeTime,
      @Semantics.user.lastChangedBy: true
      aufk.LastChangedByUser,

      // Assignments

      @ObjectModel.foreignKey.association: '_OrdInternalBillOfOperations'
      afko.OrderInternalID                                       as OrderInternalBillOfOperations,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_LogisticsOrderStdVH', element: 'OrderID' } } ]
      @ObjectModel.foreignKey.association: '_ReferenceOrder'
      aufk.ReferenceOrder,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_LogisticsOrderStdVH', element: 'OrderID' } } ]
      @ObjectModel.foreignKey.association: '_LeadingOrder'
      afko.LeadingOrder,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_LogisticsOrderStdVH', element: 'OrderID' } } ]
      @ObjectModel.foreignKey.association: '_SuperiorOrder'
      afko.MfgOrderSuperiorMfgOrder,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlantStdVH', element: 'Plant' } } ]
      @ObjectModel.foreignKey.association: '_Plant'
      aufk.Plant,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_WrkCtrBySemanticKeyStdVH', element: 'WorkCenter' } } ]
      @ObjectModel.foreignKey.association: '_WorkCenter'
      aufk.MainWorkCenter,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlantStdVH', element: 'Plant' } } ]
      @ObjectModel.foreignKey.association: '_MainWorkCenterPlant'
      aufk.MainWorkCenterPlant,
      @ObjectModel.foreignKey.association: '_MaintenanceObjectLocation'
      aufk.MaintenanceObjectLocation,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlantStdVH', element: 'Plant' } } ]
      @ObjectModel.foreignKey.association: '_LocationPlant'
      aufk.LocationPlant,
      @ObjectModel.foreignKey.association: '_MRPController'
      afko.MRPController,
      @ObjectModel.foreignKey.association: '_ProductionSupervisor'
      afko.ProductionSupervisor,
      @ObjectModel.foreignKey.association: '_ProductionSchedulingProfile'
      afko.ProductionSchedulingProfile,
      @ObjectModel.foreignKey.association: '_ResponsiblePlannerGroup'
      afko.ResponsiblePlannerGroup,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_SalesOrderStdVH', element: 'SalesOrder' } } ]
      @ObjectModel.foreignKey.association: '_SalesOrder'
      aufk.SalesOrder,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_SalesOrderItemStdVH', element: 'SalesOrderItem' } } ]  
      @ObjectModel.foreignKey.association: '_SalesOrderItem'
      aufk.SalesOrderItem,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'WBSElementInternalID_2'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_WBSElmntByIntKeyStdVH', element: 'WBSElementInternalID' } } ]  
      @ObjectModel.foreignKey.association: '_WBSElement'
      aufk.WBSElementInternalID,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_WBSElementBasicDataStdVH', element: 'WBSElementInternalID' } } ]  
      @ObjectModel.foreignKey.association: '_WBSElementBasicData2'
      aufk.WBSElementInternalID_2,  // w/o conversion exit

      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'ProjectInternalID_2'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProjectByInternalKeyStdVH', element: 'ProjectInternalID' } } ]
      @ObjectModel.foreignKey.association: '_Project'
      cast(afko.ProjectInternalID as ps_psp_pro preserving type) as ProjectInternalID,       // with conversion exit

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProjectByInternalKeyStdVH', element: 'ProjectInternalID' } } ]
      @ObjectModel.foreignKey.association: '_ProjectBasicData2'
      afko.ProjectInternalID                                     as ProjectInternalID_2,     // w/o conversion exit  

--    @ObjectModel.foreignKey.association: '_SuperiorProjectNetwork'
      afko.SuperiorProjectNetwork,
      @ObjectModel.foreignKey.association: '_Reservation'
      afko.Reservation,
      @ObjectModel.foreignKey.association: '_SettlementReservation'    
      afko.SettlementReservation,
      @ObjectModel.foreignKey.association: '_ConfirmationGroup'
      afko.MfgOrderConfirmation,
      afko.MfgOrderConfirmationCount,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CapacityRequirementStdVH', element: 'CapacityRequirement' } } ]
      @ObjectModel.foreignKey.association: '_CapacityRequirement'
      afko.CapacityRequirement,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_InspectionLotStdVH', element: 'InspectionLot' } } ]
      @ObjectModel.foreignKey.association: '_InspectionLot'
      afko.InspectionLot,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ChangeMasterStdVH', element: 'ChangeNumber' } } ]
      @ObjectModel.foreignKey.association: '_ChangeNumber'
      afko.ChangeNumber,
      afko.ChangeNumber                                         as EngineeringChangeOrder, // kept for compatibility

      @ObjectModel.foreignKey.association: '_BasicSchedulingType'
      afko.BasicSchedulingType,
      @ObjectModel.foreignKey.association: '_ForecastSchedulingType'
      afko.ForecastSchedulingType,
      afko.ProdAvailyCheckPlanningType,
      afko.SchedulingIsAllowingForBreaks,
      aufk.ProjInterestCalcProfile,
      afko.NtwkAccountAssignmentCode,
      afko.NetworkProfile,
      @ObjectModel.foreignKey.association: '_StatusObject'
      aufk.ObjectInternalID,
      afko.ProductConfiguration,
      aufk.ConditionApplication,
      aufk.ExternalOrder,
      @ObjectModel.foreignKey.association: '_RequestOrderType'
      afko.RequestOrderType,
      afko.CapacityActiveVersion,
      afko.CapacityRqmtHasNotToBeCreated,
      afko.OrderSequenceNumber,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'MaterialRevisionLevel_2'
      cast(afko.MaterialRevisionLevel as revlv preserving type) as MaterialRevisionLevel,    // with conversion exit

      afko.MaterialRevisionLevel                                as MaterialRevisionLevel_2, // w/o conversion exit

      afko.MfgOrderSplitStatus,

      // Fashion Manufacturing Fields     

      afko.MasterProductionOrder,
      
      // Assignments FI/CO

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BusinessAreaStdVH', element: 'BusinessArea' } } ]
      @ObjectModel.foreignKey.association: '_BusinessArea'
      aufk.BusinessArea,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } } ]
      @ObjectModel.foreignKey.association: '_CompanyCode'
      aufk.CompanyCode,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } } ]
      aufk.RequestingCompanyCode,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ControllingAreaStdVH', element: 'ControllingArea' } } ]      
      @ObjectModel.foreignKey.association: '_ControllingArea'
      aufk.ControllingArea,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProfitCenterStdVH', element: 'ProfitCenter' } } ]
      @ObjectModel.foreignKey.association: '_ProfitCenter'
      aufk.ProfitCenter,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CostCenterStdVH', element: 'CostCenter' } } ]
      @ObjectModel.foreignKey.association: '_CostCenter'
      aufk.CostCenter,
      aufk.RequestingCostCenter,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CostCenterStdVH', element: 'CostCenter' } } ]
      @ObjectModel.foreignKey.association: '_ResponsibleCostCenter'
      aufk.ResponsibleCostCenter,
      aufk.CostElement,
      @ObjectModel.foreignKey.association: '_GLAccount'
      aufk.GLAccount,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProductCostCtrlgOrderStdVH', element: 'OrderID' } } ]  
      @ObjectModel.foreignKey.association: '_ProductCostCollector'      
      aufk.ProductCostCollector,
      aufk.CostingSheet,
      @ObjectModel.foreignKey.association: '_ControllingObjectClass'
      aufk.ControllingObjectClass,
      @ObjectModel.foreignKey.association: '_FunctionalArea'
      aufk.FunctionalArea,
      aufk.OverheadCode,
      aufk.ResultAnalysisInternalID,
      aufk.VarianceKey,
      aufk.JointVenture,
      aufk.JointVentureClass,
      aufk.JointVentureSubClass,
      aufk.JointVentureOriginalCostObject,
      aufk.JointVentureObjectType,
      aufk.TaxJurisdiction,
      aufk.InvestmentReason,
      aufk.EnvironmentalInvestmentReason,
      afko.ActualCostsCostingVariant,
      afko.PlannedCostsCostingVariant,
      @ObjectModel.foreignKey.association: '_OrderProcessingGroup'
      aufk.OrderProcessingGroup, 
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'EventBasedPostingMethod'
      aufk.EventBasedPostingMethod                              as OrderIsEventBasedPosting,
      aufk.EventBasedPostingMethod,
      aufk.EventBasedProcessingKey,
      aufk.OrderSettlementTriggerType,

      // Assignments BOO

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
      afko.Material,
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
      afko.BillOfOperationsType,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
      @VDM.lifecycle.status: #DEPRECATED                // default data element change -> deprecated to avoid RTT2 error in ATC

      @VDM.lifecycle.successor: 'BillOfOperationsGroup'
      afko.BillOfOperationsGroup                                as BillOfOperations,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup2'
      afko.BillOfOperationsGroup,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BillOfOperationsStdVH', element: 'BillOfOperationsVariant' } } ]
      @ObjectModel.foreignKey.association: '_BillOfOperations'
      afko.BillOfOperationsVariant,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BOOChgStateStdVH', element: 'BOOInternalVersionCounter' } } ]
      @ObjectModel.foreignKey.association: '_BillOfOperationsChangeState'
      afko.BOOInternalVersionCounter,
      @ObjectModel.foreignKey.association: '_BillOfOperationsApplication'
      afko.BillOfOperationsApplication,
      @ObjectModel.foreignKey.association: '_BillOfOperationsUsage'
      afko.BillOfOperationsUsage,
      afko.BillOfOperationsVersion,
      afko.BOOExplosionDate,
      afko.BOOValidityStartDate,

      // Assignments BOM

      afko.BillOfMaterialCategory,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'BillOfMaterialInternalID'
      cast(afko.BillOfMaterial as stnum preserving type)        as  BillOfMaterial,           // with conv. exit NUMCV

      afko.BillOfMaterial                                       as  BillOfMaterialInternalID, // with conv. exit ALPHA

      afko.BillOfMaterialVariant,
      afko.BillOfMaterialVariantUsage,
      afko.BillOfMaterialVersion,
      afko.BOMExplosionDate,
      afko.BOMValidityStartDate,

      // Floats

      @ObjectModel.foreignKey.association: '_SchedulingFloatProfile'
      afko.SchedulingFloatProfile,
      afko.FloatBeforeProductionInWrkDays,
      afko.FloatAfterProductionInWorkDays,
      afko.ReleasePeriodInWorkDays,

      // Dates and Times

      afko.ChangeToScheduledDatesIsMade,
      -- planned/basic dates
      afko.PlannedStartDate,
      afko.PlannedStartTime,
      afko.PlannedEndDate,
      afko.PlannedEndTime,
      cast(case aufk.PlannedReleaseDate
             when '' then afko.PlannedReleaseDate 
                     else aufk.PlannedReleaseDate
           end        as fis_co_ftrmp preserving type)          as PlannedReleaseDate,
      -- scheduled dates      
      afko.ScheduledBasicStartDate,
      afko.ScheduledBasicStartTime,
      afko.ScheduledBasicEndDate,
      afko.ScheduledBasicEndTime,
      afko.ScheduledReleaseDate,
      -- confirmed/actual dates      
      afko.ActualStartDate,
      afko.ActualStartTime,
      afko.ConfirmedEndDate,
      afko.ConfirmedEndTime,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'ActualDeliveryDate'  
      afko.ActualEndDate,  // wrong GFN, it's the delivery date

      afko.ActualDeliveryDate,
      afko.ActualReleasedDate,
      -- forecast dates      
      afko.ScheduledForecastedStartDate,
      afko.ScheduledForecastedStartTime,
      afko.ScheduledForecastedEndDate,
      afko.ScheduledForecastedEndTime,
      afko.ScheduledFcstdReleaseDate,
      afko.ForecastedStartDate,
      afko.ForecastedStartTime,
      afko.ForecastedEndDate,
      afko.ForecastedEndTime,
      -- other dates      
      afko.TotalCommitmentDate,
      afko.LastScheduledDate,
      aufk.PlannedCompletionDate,
      aufk.TechnicalCompletionDate,

      // Quantities and UoM

      @ObjectModel.foreignKey.association: '_BaseUnit'
      @Semantics.unitOfMeasure: true
      afko.BaseUnit,  // Order Unit

      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      afko.OrderPlannedTotalQty,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      afko.OrderPlannedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      afko.OrderConfirmedYieldQty,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      afko.OrderConfirmedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #SUM
      afko.MfgOrderConfirmedReworkQty,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #MIN
      afko. MaterialFromLotSizeQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @Aggregation.default: #MAX
      afko.MaterialToLotSizeQuantity,

      @ObjectModel.foreignKey.association: '_MaterialBaseUnit'
      @Semantics.unitOfMeasure: true
      afko.MaterialBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      @Aggregation.default: #SUM
      afko.PlannedTotalQtyInBaseUnit,

      // Amount and Currency

      @ObjectModel.foreignKey.association: '_Currency'
      @Semantics.currencyCode: true
      aufk.Currency,
      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'Currency'
      aufk.EstimatedTotalOrderCost,

      // Associations

      _OrderCategory,
      _OrderType,
      _OrderTypeDetails,
      _OrderItem,
      _OrderMainItem,
      _OrderSequence,
      _OrderOperation,
      _OrderComponent,
      _OrderPriority,
      _ReferenceOrder,
      _LeadingOrder,
      _SuperiorOrder,
      _CreatedByUser,
      _LastChangedByUser,
      _CreatedByUserContactCard,
      _LastChgdByUserContactCard,
      _BaseUnit,
      _MaterialBaseUnit,
      _LongTextLanguage,
      _Currency,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_OrderInternalID'
      _OrdInternalBillOfOperations,
      _OrderInternalID,
      _BillOfOperationsType,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_BillOfOperationsGroup2'
      _BillOfOperationsGroup,
      _BillOfOperationsGroup2,
      _BillOfOperations,
      _BillOfOperationsChangeState,
      _BillOfOperationsApplication,
      _BillOfOperationsUsage,
      _ConfirmationGroup,
      _Reservation,
      _SettlementReservation,
      _Plant,
      _WorkCenter,
      _MainWorkCenterPlant,
      _LocationPlant,
      _MaintenanceObjectLocation,
      _ChangeNumber,
      _CapacityRequirement,
      _SalesOrder,
      _SalesOrderItem,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_WBSElementBasicData2'
      _WBSElement,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_WBSElementBasicData2' 
      _WBSElementBasicData,
      _WBSElementBasicData2,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_ProjectBasicData2'
      _Project,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_ProjectBasicData2'
      _ProjectBasicData,
      _ProjectBasicData2,
      _SuperiorProjectNetwork,
      _ProductionSupervisor,
      _ProductionSchedulingProfile,
      _ResponsiblePlannerGroup,
      _MRPController,
      _InspectionLot,
      _StatusObject,
      _StatusObjectStatus,
      _BusinessArea,
      _ProfitCenter,
      _CostCenter,
      _ResponsibleCostCenter,
      _GLAccount,
      _ProductCostCollector,
      _ControllingArea,
      _ControllingObjectClass,
      _CompanyCode,
      _FunctionalArea,
      _OrderProcessingGroup,
      _BasicSchedulingType,
      _ForecastSchedulingType,
      _SchedulingFloatProfile,
      _RequestOrderType,
      _LongText,
      _RFM_MasterProductOrder
}
where aufk.OrderCategory = '10'
   or aufk.OrderCategory = '20'
   or aufk.OrderCategory = '30'
   or aufk.OrderCategory = '40';