I_MaintenancePlannerGroup

DDL: I_MAINTENANCEPLANNERGROUP Type: view_entity BASIC Package: IEQM

Maintenance Planner Group

I_MaintenancePlannerGroup is a Basic CDS View (Dimension) that provides data about "Maintenance Planner Group" in SAP S/4HANA. It reads from 1 data source (t024i) and exposes 9 fields with key fields MaintenancePlannerGroup, MaintenancePlanningPlant. Part of development package IEQM.

1 data source(s) 9 fields

Data Sources (1)

SourceAliasJoin Type
t024i t024i from

Annotations (15)

NameValueLevelField
EndUserText.label Maintenance Planner Group view
Analytics.dataCategory #DIMENSION view
Analytics.dataExtraction.enabled true view
Analytics.dataExtraction.delta.changeDataCapture.automatic true view
Analytics.technicalName IMAINTPLGRP view
VDM.viewType #BASIC view
AccessControl.authorizationCheck #CHECK view
ObjectModel.representativeKey MaintenancePlannerGroup view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #S view
Metadata.ignorePropagatedAnnotations true view
Metadata.allowExtensions true view
ObjectModel.sapObjectNodeType.name MaintenancePlannerGroup view
ObjectModel.objectIdentifier.oidElement MaintenancePlannerGroupOID view

Fields (9)

KeyFieldSource TableSource FieldDescription
KEY MaintenancePlannerGroup
KEY MaintenancePlanningPlant t024i iwerk
MaintenancePlannerGroupName
MaintPlannerGroupPhoneNumber t024i intel
MaintenanceOrderType t024i auart_wp
EmailAddress t024i smtp_addr
MaintenancePlannerGroupOID
_MaintenancePlanningPlant _MaintenancePlanningPlant
_MaintenancePlanPlant _MaintenancePlanPlant 
@EndUserText.label: 'Maintenance Planner Group'
@Analytics: { dataCategory: #DIMENSION, 
  dataExtraction : { enabled: true , 
  delta.changeDataCapture.automatic: true } 
}
@Analytics.technicalName: 'IMAINTPLGRP'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK

@ObjectModel.representativeKey:  'MaintenancePlannerGroup'

@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions: true
@ObjectModel.sapObjectNodeType.name : 'MaintenancePlannerGroup'
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #EXTRACTION_DATA_SOURCE]
@ObjectModel.alternativeKey:[{id:'OID',element:['MaintenancePlannerGroupOID']}] 
@ObjectModel.objectIdentifier.oidElement:'MaintenancePlannerGroupOID' 

define view entity I_MaintenancePlannerGroup as select from t024i
//Obsolete-C1 released association not intended to used and replaced with I_MaintenancePlanPlant

association[0..1] to I_Plant as _MaintenancePlanningPlant on $projection.MaintenancePlanningPlant = _MaintenancePlanningPlant.Plant
//////////////////////////////////////////////////////////////////////////////

association[0..1] to I_MaintenancePlanPlant  as _MaintenancePlanPlant on $projection.MaintenancePlanningPlant = _MaintenancePlanPlant.MaintenancePlanningPlant
{

    @ObjectModel.text.element:  [ 'MaintenancePlannerGroupName' ]
    key cast( t024i.ingrp as eam_planner_group preserving type ) as MaintenancePlannerGroup, 
    
    @ObjectModel.foreignKey.association: '_MaintenancePlanPlant'     
    key t024i.iwerk as MaintenancePlanningPlant, 
    
    @Semantics.text: true
    cast( t024i.innam as eam_planner_group_name preserving type ) as MaintenancePlannerGroupName, 
    @Semantics.telephone.type:[#PREF]
    t024i.intel as MaintPlannerGroupPhoneNumber, 
    t024i.auart_wp as MaintenanceOrderType, 
    @Semantics.eMail.address : true
    t024i.smtp_addr as EmailAddress,
    
    //MDI/ODM

      @ObjectModel.filter.enabled:false
      @ObjectModel.sort.enabled:false
      
      cast( t024i.ingrp as maintenanceplannergroup_oid ) as MaintenancePlannerGroupOID, //use your own OID field name

    
    _MaintenancePlanningPlant,  //Obsolete association

    _MaintenancePlanPlant
}

Learn More