C_MaintOrderWorkflowTaskCard

DDL: C_MAINTORDERWORKFLOWTASKCARD Type: view_entity CONSUMPTION Package: EAM_WFL_MO

Maintenance Order Workflow Task Card

C_MaintOrderWorkflowTaskCard is a Consumption CDS View that provides data about "Maintenance Order Workflow Task Card" in SAP S/4HANA. It reads from 1 data source (I_MaintenanceOrder) and exposes 17 fields with key field MaintenanceOrder. It has 1 association to related views. Part of development package EAM_WFL_MO.

1 data source(s) 17 fields

Data Sources (1)

SourceAliasJoin Type
I_MaintenanceOrder _MaintenanceOrder from

Associations (1)

CardinalityTargetAliasCondition
[0..1] C_TechObjMaintenanceOrder _TechobjMaintenanceOrder _TechobjMaintenanceOrder.MaintenanceOrder = $projection.MaintenanceOrder and _TechobjMaintenanceOrder.TechnicalObject <> ''

Annotations (7)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
AccessControl.personalData.blocking #NOT_REQUIRED view
EndUserText.label Maintenance Order Workflow Task Card view
ObjectModel.usageType.serviceQuality #X view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #MIXED view
VDM.viewType #CONSUMPTION view

Fields (17)

KeyFieldSource TableSource FieldDescription
KEY MaintenanceOrder I_MaintenanceOrder MaintenanceOrder
MaintenanceOrderDesc I_MaintenanceOrder MaintenanceOrderDesc
MaintenanceOrderType I_MaintenanceOrder MaintenanceOrderType
MaintPriority I_MaintenanceOrder MaintPriority
MaintenancePlanningPlant I_MaintenanceOrder MaintenancePlanningPlant
MaintenancePlannerGroup I_MaintenanceOrder MaintenancePlannerGroup
MaintOrdBasicStartDate I_MaintenanceOrder MaintOrdBasicStartDate Basic Start Date
MaintOrdBasicEndDate I_MaintenanceOrder MaintOrdBasicEndDate Basic End Date
MaintenanceOrderInternalID I_MaintenanceOrder MaintenanceOrderInternalID
Currency I_MaintenanceOrder Currency
TechnicalObjectendasTechnicalObject
TechObjIsEquipOrFuncnlLocDesc _TechobjMaintenanceOrder TechObjIsEquipOrFuncnlLocDesc Technical Object Type
TechnicalObjectDescription _TechobjMaintenanceOrder TechnicalObjectDescription
OrderTypeName
MaintPriorityDesc
MaintenancePlanningPlantName
MaintenancePlannerGroupName 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Maintenance Order Workflow Task Card'
@ObjectModel.usageType:{
    serviceQuality: #X,
    sizeCategory: #L,
    dataClass: #MIXED
}
@VDM.viewType: #CONSUMPTION
@Workflow: { enabledFor: [ #CUSTOM_TASK_ATTRIBUTES ] }

define view entity C_MaintOrderWorkflowTaskCard
  as select from I_MaintenanceOrder as _MaintenanceOrder

  association [0..1] to C_TechObjMaintenanceOrder as _TechobjMaintenanceOrder on  _TechobjMaintenanceOrder.MaintenanceOrder = $projection.MaintenanceOrder
                                                                              and _TechobjMaintenanceOrder.TechnicalObject  <> ''
{

  key _MaintenanceOrder.MaintenanceOrder,

      _MaintenanceOrder.MaintenanceOrderDesc,

      @ObjectModel.text.element: ['OrderTypeName']
      _MaintenanceOrder.MaintenanceOrderType,

      @ObjectModel.text.element: ['MaintPriorityDesc']
      _MaintenanceOrder.MaintPriority,

      @ObjectModel.text.element: ['MaintenancePlanningPlantName']
      _MaintenanceOrder.MaintenancePlanningPlant,

      @ObjectModel.text.element: ['MaintenancePlannerGroupName']
      _MaintenanceOrder.MaintenancePlannerGroup,

      @EndUserText.label: 'Basic Start Date'
      _MaintenanceOrder.MaintOrdBasicStartDate,

      @EndUserText.label: 'Basic End Date'
      _MaintenanceOrder.MaintOrdBasicEndDate,

      _MaintenanceOrder.MaintenanceOrderInternalID,

      _MaintenanceOrder.Currency,

      @ObjectModel.text.element: ['TechnicalObjectDescription']

      case
          when _TechobjMaintenanceOrder.TechObjIsEquipOrFuncnlLoc = 'EAMS_EQUI'
          then ltrim(_TechobjMaintenanceOrder.TechnicalObject, '0')
          else _TechobjMaintenanceOrder.TechnicalObject
          end                                                                                               as TechnicalObject,


      @EndUserText.label: 'Technical Object Type'
      _TechobjMaintenanceOrder.TechObjIsEquipOrFuncnlLocDesc,

      @Semantics.text: true
      _TechobjMaintenanceOrder.TechnicalObjectDescription,

      _MaintenanceOrder._MaintenanceOrderType._Text[1:Language = $session.system_language].OrderTypeName    as OrderTypeName,
      _MaintenanceOrder._MaintenancePriority._Text[1:Language = $session.system_language].MaintPriorityDesc as MaintPriorityDesc,
      _MaintenanceOrder._MaintenancePlanningPlant.PlantName                                                 as MaintenancePlanningPlantName,
      _MaintenanceOrder._MaintenancePlannerGroup.MaintenancePlannerGroupName

}

Learn More