I_MAINTENANCEORDERBASIC
Maintenance Order
I_MAINTENANCEORDERBASIC is a CDS View in S/4HANA. Maintenance Order. It contains 85 fields. 3 CDS views read from this table.
CDS Views using this table (3)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| I_MaintenanceOrder | view | from | BASIC | Maintenance Order |
| I_MaintenanceOrderSituation | view_entity | from | COMPOSITE | Maintenance Order Situation handling |
| I_MaintOrderOpPhaseControl | view | inner | COMPOSITE | Maintenance Order Op Phase Controls |
Fields (85)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | MaintenanceOrder | MaintenanceOrder | 1 |
| ActualCostsCostingVariant | ActualCostsCostingVariant | 1 | |
| AdditionalDeviceData | AdditionalDeviceData | 1 | |
| Assembly | Assembly | 1 | |
| BasicSchedulingType | BasicSchedulingType | 1 | |
| BusinessArea | BusinessArea | 1 | |
| CompanyCode | CompanyCode | 1 | |
| ConditionApplication | ConditionApplication | 1 | |
| ConditionUsage | ConditionUsage | 1 | |
| ControllingArea | ControllingArea | 1 | |
| ControllingObjectClass | ControllingObjectClass | 1 | |
| CostingSheet | CostingSheet | 1 | |
| CreatedByUser | CreatedByUser | 1 | |
| CreationDate | CreationDate | 1 | |
| CreationTime | CreationTime | 1 | |
| Currency | Currency | 1 | |
| Equipment | Equipment | 1 | |
| FunctionalArea | FunctionalArea | 1 | |
| LastChangeByUser | LastChangeByUser | 1 | |
| LastChangeDateTime | LastChangeDateTime | 1 | |
| LatestAcceptableCompletionDate | LatestAcceptableCompletionDate | 1 | |
| LeadingOrder | LeadingOrder | 1 | |
| MaintenanceActivityType | MaintenanceActivityType | 1 | |
| MaintenanceCall | MaintenanceCall | 1 | |
| MaintenanceItem | MaintenanceItem | 1 | |
| MaintenanceItemObjectList | MaintenanceItemObjectList | 1 | |
| MaintenanceNotification | MaintenanceNotification | 1 | |
| MaintenanceOrderCategory | MaintenanceOrderCategory | 1 | |
| MaintenanceOrderDesc | MaintenanceOrderDesc | 1 | |
| MaintenanceOrderInternalID | MaintenanceOrderInternalID | 1 | |
| MaintenanceOrderObjectList | MaintenanceOrderObjectList | 1 | |
| MaintenanceOrderOverheadCode | MaintenanceOrderOverheadCode | 1 | |
| MaintenanceOrderPlanningCode | MaintenanceOrderPlanningCode | 1 | |
| MaintenanceOrderType | MaintenanceOrderType | 2 | |
| MaintenancePlan | MaintenancePlan | 1 | |
| MaintenancePlannerGroup | MaintenancePlannerGroup | 1 | |
| MaintenancePlanningPlant | MaintenancePlanningPlant | 2 | |
| MaintenancePlant | MaintenancePlant | 1 | |
| MaintenanceProcessingPhase | MaintenanceProcessingPhase | 1 | |
| MaintenanceRevision | MaintenanceRevision | 1 | |
| MaintObjectLocAcctAssgmtNmbr | MaintObjectLocAcctAssgmtNmbr | 1 | |
| MaintOrdBasicEndDate | MaintOrdBasicEndDate | 1 | |
| MaintOrdBasicEndTime | MaintOrdBasicEndTime | 1 | |
| MaintOrdBasicStartDate | MaintOrdBasicStartDate | 1 | |
| MaintOrdBasicStartTime | MaintOrdBasicStartTime | 1 | |
| MaintOrderProcessingContext | MaintOrderProcessingContext | 1 | |
| MaintOrderReferenceDate | MaintOrderReferenceDate | 1 | |
| MaintOrderReferenceTime | MaintOrderReferenceTime | 1 | |
| MaintOrderRoutingNumber | MaintOrderRoutingNumber | 1 | |
| MaintOrdProcessPhaseCode | MaintOrdProcessPhaseCode | 1 | |
| MaintOrdProcessSubPhaseCode | MaintOrdProcessSubPhaseCode | 1 | |
| MaintOrdProcmtIntegScenario | MaintOrdProcmtIntegScenario | 1 | |
| MaintPriority | MaintPriority | 1 | |
| MaintPriorityType | MaintPriorityType | 1 | |
| MainWorkCenter | MainWorkCenter | 1 | |
| MainWorkCenterPlant | MainWorkCenterPlant | 1 | |
| MainWorkCompletedDateTime | MainWorkCompletedDateTime | 1 | |
| Material | Material | 1 | |
| OperationSystemCondition | OperationSystemCondition | 1 | |
| OrderHasLongText | OrderHasLongText | 1 | |
| OrderProcessingGroup | OrderProcessingGroup | 1 | |
| OrdIsNotSchedldAutomatically | OrdIsNotSchedldAutomatically | 1 | |
| PersonnelNumber | PersonnelNumber | 1 | |
| PlannedCostsCostingVariant | PlannedCostsCostingVariant | 1 | |
| PrevLtstAccptblCompletionDate | PrevLtstAccptblCompletionDate | 1 | |
| ProfitCenter | ProfitCenter | 1 | |
| ProjectInternalID | ProjectInternalID | 1 | |
| ReferenceElement | ReferenceElement | 1 | |
| ResponsibleCostCenter | ResponsibleCostCenter | 1 | |
| ScheduledBasicEndDate | ScheduledBasicEndDate | 1 | |
| ScheduledBasicEndTime | ScheduledBasicEndTime | 1 | |
| ScheduledBasicStartDate | ScheduledBasicStartDate | 1 | |
| ScheduledBasicStartTime | ScheduledBasicStartTime | 1 | |
| SerialNumber | SerialNumber | 1 | |
| ServiceDocument | ServiceDocument | 1 | |
| ServiceDocumentItem | ServiceDocumentItem | 1 | |
| ServiceDocumentType | ServiceDocumentType | 1 | |
| SuperiorProjectNetwork | SuperiorProjectNetwork | 1 | |
| TaskListGroup | TaskListGroup | 1 | |
| TaskListGroupCounter | TaskListGroupCounter | 1 | |
| TaskListType | TaskListType | 1 | |
| TechnicalCompletionDate | TechnicalCompletionDate | 1 | |
| WBSElementInternalID | WBSElementInternalID | 1 | |
| WorkCenterInternalID | WorkCenterInternalID | 1 | |
| WorkCenterTypeCode | WorkCenterTypeCode | 1 |
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Maintenance Order'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
serviceQuality: #A,
sizeCategory: #XL,
dataClass: #TRANSACTIONAL
}
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AccessControl.privilegedAssociations:['_LocationAccountAssignment']
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ObjectModel.representativeKey: 'MaintenanceOrder'
@ObjectModel.semanticKey: [ 'MaintenanceOrder' ]
@ObjectModel.sapObjectNodeType.name: 'MaintenanceOrder'
@ObjectModel.supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
define view entity I_MaintenanceOrderBasic as select from afih
left outer to one join aufk on aufk.aufnr = afih.aufnr
left outer to one join afko on afko.aufnr = afih.aufnr
association [0..1] to I_PMNotificationPriorityType as _MaintenancePriorityType on $projection.MaintPriorityType = _MaintenancePriorityType.MaintPriorityType
association [0..1] to I_PMNotificationPriority as _MaintenancePriority on $projection.MaintPriority = _MaintenancePriority.MaintPriority
and $projection.MaintPriorityType = _MaintenancePriority.MaintPriorityType
association [0..1] to I_MaintenanceOrderPhase as _MaintenanceOrderPhase on $projection.MaintenanceProcessingPhase = _MaintenanceOrderPhase.MaintenanceProcessingPhase
association [0..1] to I_LocationAccountAssignment as _LocationAccountAssignment on $projection.MaintObjectLocAcctAssgmtNmbr = _LocationAccountAssignment.MaintObjectLocAcctAssgmtNmbr
association [0..1] to I_MaintenanceNotification as _MaintenanceNotification on $projection.MaintenanceNotification = _MaintenanceNotification.MaintenanceNotification
association [0..1] to I_Equipment as _Equipment on $projection.Equipment = _Equipment.Equipment
association [0..1] to I_Material as _Assembly on $projection.Assembly = _Assembly.Material
association [0..1] to I_MaintenancePlanPlant as _MaintenancePlanPlant on $projection.MaintenancePlanningPlant = _MaintenancePlanPlant.MaintenancePlanningPlant
association [0..1] to I_EAMProcessPhase as _EAMProcessPhase on $projection.MaintOrdProcessPhaseCode = _EAMProcessPhase.EAMProcessPhaseCode
association [0..1] to I_EAMProcessSubPhase as _EAMProcessSubPhase on $projection.MaintOrdProcessSubPhaseCode = _EAMProcessSubPhase.EAMProcessSubPhaseCode
association [0..1] to I_MaintenancePlannerGroup as _MaintenancePlannerGroup on $projection.MaintenancePlannerGroup = _MaintenancePlannerGroup.MaintenancePlannerGroup
and $projection.MaintenancePlanningPlant = _MaintenancePlannerGroup.MaintenancePlanningPlant
association [0..1] to I_MaintenanceRevision as _MaintenanceRevision on $projection.MaintenancePlanningPlant = _MaintenanceRevision.MaintenancePlanningPlant
and $projection.MaintenanceRevision = _MaintenanceRevision.MaintenanceRevision
association [0..1] to I_MaintenancePlanBasic as _MaintenancePlan on $projection.MaintenancePlan = _MaintenancePlan.MaintenancePlan
association [0..1] to I_MaintenanceItem as _MaintenanceItem on $projection.MaintenanceItem = _MaintenanceItem.MaintenanceItem
association [0..1] to I_WorkCenter as _MainWorkCenter on $projection.WorkCenterInternalID = _MainWorkCenter.WorkCenterInternalID and $projection.WorkCenterTypeCode = _MainWorkCenter.WorkCenterTypeCode
association [1..1] to I_WorkCenterType as _WorkCenterType on $projection.WorkCenterTypeCode = _WorkCenterType.WorkCenterTypeCode
association [0..1] to I_MaintenanceActivityType as _MaintenanceActivityType on $projection.MaintenanceActivityType = _MaintenanceActivityType.MaintenanceActivityType
association [0..1] to I_MaintOperationSystCondition as _OperationSystemCondition on $projection.OperationSystemCondition = _OperationSystemCondition.OperationSystemCondition
association [0..1] to I_MaintOrdPlngDegreeCode as _MaintOrdPlngDegreeCode on $projection.MaintenanceOrderPlanningCode = _MaintOrdPlngDegreeCode.MaintenanceOrderPlanningCode
association [0..1] to I_BusinessArea as _BusinessArea on $projection.BusinessArea = _BusinessArea.BusinessArea
association [0..1] to I_FunctionalArea as _FunctionalArea on $projection.FunctionalArea = _FunctionalArea.FunctionalArea
association [1..1] to I_OrderCategory as _MaintenanceOrderCategory on $projection.MaintenanceOrderCategory = _MaintenanceOrderCategory.OrderCategory
association [1..1] to I_OrderType as _MaintenanceOrderType on $projection.MaintenanceOrderType = _MaintenanceOrderType.OrderType
association [0..1] to I_ControllingArea as _ControllingArea on $projection.ControllingArea = _ControllingArea.ControllingArea
association [0..1] to I_ControllingObjectClass as _ControllingObjectClass on $projection.ControllingObjectClass = _ControllingObjectClass.ControllingObjectClass
association [0..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [0..*] to I_CostCenter as _ResponsibleCostCenter on $projection.ControllingArea = _ResponsibleCostCenter.ControllingArea and $projection.ResponsibleCostCenter = _ResponsibleCostCenter.CostCenter
association [0..*] to I_ProfitCenter as _ProfitCenter on $projection.ControllingArea = _ProfitCenter.ControllingArea
and $projection.ProfitCenter = _ProfitCenter.ProfitCenter
association [0..*] to I_CostCenterText as _ResponsibleCostCenterText on $projection.ControllingArea = _ResponsibleCostCenterText.ControllingArea
association [0..1] to I_SchedulingType as _BasicSchedulingType on $projection.BasicSchedulingType = _BasicSchedulingType.SchedulingType
association [0..1] to I_Plant as _LocationPlant on $projection.MaintenancePlant = _LocationPlant.Plant
association [0..1] to I_Indicator as _OrderHasLongText on $projection.OrderHasLongText = _OrderHasLongText.IndicatorValue
association [0..1] to I_WBSElementByInternalKey as _WBSElement on $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
association [0..1] to I_ProjectByInternalKey as _Project on $projection.ProjectInternalID = _Project.ProjectInternalID
association [0..1] to I_OrderProcessingGroup as _OrderProcessingGroup on $projection.ControllingArea = _OrderProcessingGroup.ControllingArea
and $projection.OrderProcessingGroup = _OrderProcessingGroup.OrderProcessingGroup
association [0..1] to I_MaintOrderTypeControlParam as _MaintOrderTypeControlParam on $projection.MaintenanceOrderType = _MaintOrderTypeControlParam.OrderType
association [0..1] to I_LogisticsOrder as _Order on _Order.OrderID = $projection.MaintenanceOrder
{
@ObjectModel.text.element: [ 'MaintenanceOrderDesc' ]
key afih.aufnr as MaintenanceOrder,
@ObjectModel.foreignKey.association: '_MaintenancePriorityType'
afih.artpr as MaintPriorityType,
@ObjectModel.foreignKey.association: '_MaintenancePriority'
afih.priok as MaintPriority,
@ObjectModel.foreignKey.association: '_MaintenanceOrderPhase'
afih.iphas as MaintenanceProcessingPhase,
@ObjectModel.foreignKey.association: '_LocationAccountAssignment'
afih.iloan as MaintObjectLocAcctAssgmtNmbr,
@ObjectModel.foreignKey.association: '_MaintenanceNotification'
afih.qmnum as MaintenanceNotification,
@ObjectModel.foreignKey.association: '_Equipment'
afih.equnr as Equipment,
@ObjectModel.foreignKey.association: '_Assembly'
afih.bautl as Assembly,
afih.serialnr as SerialNumber,
@ObjectModel.foreignKey.association: '_MaintenancePlanPlant'
afih.iwerk as MaintenancePlanningPlant,
@ObjectModel.foreignKey.association: '_MaintenancePlannerGroup'
afih.ingpr as MaintenancePlannerGroup,
@ObjectModel.foreignKey.association: '_MaintenanceRevision'
afih.revnr as MaintenanceRevision,
@ObjectModel.foreignKey.association: '_MaintenancePlan'
afih.warpl as MaintenancePlan,
@ObjectModel.foreignKey.association: '_MaintenanceItem'
afih.wapos as MaintenanceItem,
@ObjectModel.foreignKey.association: '_MaintenanceActivityType'
cast( afih.ilart as eam_maint_activity_type preserving type ) as MaintenanceActivityType,
@ObjectModel.foreignKey.association: '_MainWorkCenter'
afih.gewrk as WorkCenterInternalID,
@ObjectModel.foreignKey.association: '_WorkCenterType'
afih.pm_objty as WorkCenterTypeCode,
afih.addat as MaintOrderReferenceDate,
afih.aduhr as MaintOrderReferenceTime,
afih.mainworkcompleteddatetime as MainWorkCompletedDateTime,
@ObjectModel.foreignKey.association: '_MaintOrdPlngDegreeCode'
afih.plknz as MaintenanceOrderPlanningCode,
@ObjectModel.foreignKey.association: '_OperationSystemCondition'
afih.anlzu as OperationSystemCondition,
afih.adpsp as ReferenceElement,
afih.obknr as MaintenanceItemObjectList,
cast(afih.obknr as objknr preserving type ) as MaintenanceOrderObjectList,
cast(afih.aning as pernr_d ) as PersonnelNumber,
afih.maintordprocmtintegscenario as MaintOrdProcmtIntegScenario,
afih.sermat as Material,
afko.aufpl as MaintOrderRoutingNumber,
@ObjectModel.foreignKey.association: '_BusinessArea'
aufk.gsber as BusinessArea,
@ObjectModel.foreignKey.association: '_FunctionalArea'
aufk.func_area as FunctionalArea,
@ObjectModel.foreignKey.association: '_MaintenanceOrderType'
aufk.auart as MaintenanceOrderType,
@ObjectModel.foreignKey.association: '_MaintenanceOrderCategory'
aufk.autyp as MaintenanceOrderCategory,
@Semantics.text: true
aufk.ktext as MaintenanceOrderDesc,
@ObjectModel.foreignKey.association: '_ControllingArea'
aufk.kokrs as ControllingArea,
@ObjectModel.foreignKey.association: '_CompanyCode'
aufk.bukrs as CompanyCode,
@ObjectModel.foreignKey.association: '_ResponsibleCostCenter'
@ObjectModel.text.association: '_ResponsibleCostCenterText'
cast(aufk.kostv as pph_kostl preserving type) as ResponsibleCostCenter,
@ObjectModel.foreignKey.association: '_ProfitCenter'
aufk.prctr as ProfitCenter,
@ObjectModel.foreignKey.association: '_ControllingObjectClass'
cast(aufk.scope as pph_scope preserving type) as ControllingObjectClass,
aufk.idat2 as TechnicalCompletionDate,
@ObjectModel.foreignKey.association: '_BasicSchedulingType'
afko.terkz as BasicSchedulingType,
@Semantics.booleanIndicator:true
afko.nauterm as OrdIsNotSchedldAutomatically,
afko.gstrp as MaintOrdBasicStartDate,
afko.gsuzp as MaintOrdBasicStartTime,
afko.gltrp as MaintOrdBasicEndDate,
afko.gluzp as MaintOrdBasicEndTime,
afko.gstrs as ScheduledBasicStartDate,
afko.gsuzs as ScheduledBasicStartTime,
afko.gltrs as ScheduledBasicEndDate,
afko.gluzs as ScheduledBasicEndTime,
-- will require DPP protection (todo CE2008)
afih.maintordpersonresponsible as MaintOrdPersonResponsible,
aufk.objnr as MaintenanceOrderInternalID,
cast(afko.plnnr as billofoperations preserving type) as TaskListGroup,
cast(afko.plnty as billofoperationstype preserving type) as TaskListType,
cast(afko.plnal as billofoperationsvariant preserving type) as TaskListGroupCounter,
@ObjectModel.foreignKey.association: '_LocationPlant'
aufk.sowrk as MaintenancePlant,
@Semantics.systemDate.createdAt: true
aufk.erdat as CreationDate,
@Semantics.systemTime.createdAt: true
aufk.erfzeit as CreationTime,
@Semantics.user.createdBy: true
aufk.ernam as CreatedByUser,
@ObjectModel.foreignKey.association: '_OrderHasLongText'
cast( case when aufk.ltext = '' then ''
else 'X' end as pph_aufltxt preserving type) as OrderHasLongText,
@Semantics.user.lastChangedBy: true
aufk.aenam as LastChangeByUser,
afih.changeddatetime as LastChangeDateTime,
afih.deviceid as AdditionalDeviceData,
@ObjectModel.foreignKey.association: '_WBSElement'
cast( aufk.pspel as vdm_wbs_element_internal preserving type ) as WBSElementInternalID,
@ObjectModel.foreignKey.association: '_Project'
cast( afko.pronr as ps_s4_proj_pspnr preserving type) as ProjectInternalID,
@ObjectModel.foreignKey.association: '_OrderProcessingGroup'
aufk.abkrs as OrderProcessingGroup,
afko.aufnt as SuperiorProjectNetwork,
aufk.vaplz as MainWorkCenter,
aufk.wawrk as MainWorkCenterPlant,
aufk.kalsm as CostingSheet,
aufk.waers as Currency,
cast(afih.lacd_date as vdm_lacd_date preserving type ) as LatestAcceptableCompletionDate,
@ObjectModel.foreignKey.association: '_EAMProcessPhase'
afih.maintordovrlprocphase as MaintOrdProcessPhaseCode,
@ObjectModel.foreignKey.association: '_EAMProcessSubPhase'
afih.maintordovrlprocsubphase as MaintOrdProcessSubPhaseCode,
afih.maintorderprocessingcontext as MaintOrderProcessingContext,
afih.service_doc_type as ServiceDocumentType,
afih.service_doc_id as ServiceDocument,
afih.service_doc_item_id as ServiceDocumentItem,
/* Control Parameters*/
aufk.kvewe as ConditionUsage,
aufk.kappl as ConditionApplication,
aufk.zschl as MaintenanceOrderOverheadCode,
afko.klvarp as PlannedCostsCostingVariant,
afko.klvari as ActualCostsCostingVariant,
/* maintenance plan */
afih.abnum as MaintenanceCall,
afih.laufn as LeadingOrder,
afih.old_lacd_date as PrevLtstAccptblCompletionDate,
_MaintenancePriorityType,
_MaintenancePriority,
_MaintenanceOrderPhase,
_LocationAccountAssignment,
_MaintenanceNotification,
_Equipment,
_Assembly,
_MaintenancePlanPlant,
_EAMProcessPhase ,
_EAMProcessSubPhase ,
_MaintenancePlannerGroup,
_MaintenanceRevision ,
_MaintenancePlan ,
_MaintenanceItem,
_MainWorkCenter,
_WorkCenterType ,
_MaintenanceActivityType,
_OperationSystemCondition,
_MaintOrdPlngDegreeCode ,
_BusinessArea ,
_FunctionalArea ,
_MaintenanceOrderCategory,
_MaintenanceOrderType ,
_ControllingArea ,
_ControllingObjectClass ,
_CompanyCode ,
_ResponsibleCostCenter,
_ProfitCenter ,
_ResponsibleCostCenterText ,
_BasicSchedulingType,
_LocationPlant,
_OrderHasLongText,
_WBSElement ,
_Project,
_OrderProcessingGroup,
_MaintOrderTypeControlParam,
_Order
}