I_CtrlgObjectSettlementRule

@AbapCatalog.sqlViewName: 'ICTRLGOBJSETRULE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #BASIC
@EndUserText.label: 'Settlement rules for controlling objects'
@ClientHandling.type: #CLIENT_DEPENDENT
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass: #MASTER
define view I_CtrlgObjectSettlementRule
  as select from cobra
  association [0..*] to I_CtrlgObjSettlmtDistrRule     as _CtrlgObjSettlmtDistrRule     on  $projection.ControllingObject = _CtrlgObjSettlmtDistrRule.ControllingObject
  association [0..1] to I_ControllingObject            as _ControllingObject            on  $projection.ControllingObject = _ControllingObject.ControllingObject
  association [0..1] to I_AllocationStructure          as _AllocationStructure          on  $projection.AllocationStructure = _AllocationStructure.AllocationStructure
  association [0..1] to I_UserContactCard              as _CreatedByUser                on  $projection.CreatedByUser = _CreatedByUser.ContactCardID

  association [0..1] to I_UserContactCard              as _LastChangedByUser            on  $projection.LastChangedByUser = _LastChangedByUser.ContactCardID
  association [0..1] to I_ControllingSettlementProfile as _ControllingSettlementProfile on  $projection.ControllingSettlementProfile = _ControllingSettlementProfile.ControllingSettlementProfile
  association [0..1] to I_SettlmtAutomGnrtnStrgySqnc   as _SettlmtAutomGnrtnStrgySqnc   on  $projection.SettlmtRuleAutoGnrtnStrgySqnc = _SettlmtAutomGnrtnStrgySqnc.SettlmtRuleAutoGnrtnStrgySqnc
  association [0..1] to I_PrftbltyAcctgTransfStructure as _PrftbltyAcctgTransfStructure on  $projection.ProfitabilityAcctgTransfStruc = _PrftbltyAcctgTransfStructure.ProfitabilityAcctgTransfStruc
  association [0..1] to I_ControllingStructure         as _SourceStructure              on  _SourceStructure.ControllingStructureType = 'U'
                                                                                        and $projection.SettlementSourceStructure     = _SourceStructure.ControllingStructure
  association [0..1] to I_SettlmtWithFreeDfndCurrency  as _SettlmtWithFreeDfndCurrency  on  $projection.SettlmtWithFreeDefinedCurrency = _SettlmtWithFreeDfndCurrency.SettlmtWithFreeDefinedCurrency
{


      @ObjectModel.foreignKey.association: '_ControllingObject'
  key objnr                                              as ControllingObject,
      @ObjectModel.foreignKey.association: '_CreatedByUser'
      cast(ernam as fin_usnam preserving type )          as CreatedByUser,
      erdat                                              as CreationDate,
      @ObjectModel.foreignKey.association: '_LastChangedByUser'
      aenam                                              as LastChangedByUser,
      aedat                                              as LastChangeDate,
      ktext                                              as CtrlgObjectSettlementRuleName,
      @ObjectModel.foreignKey.association: '_AllocationStructure'
      cast(absch as fco_brgabsch preserving type )       as AllocationStructure,
      kstar                                              as SettlementGLAccount,
      @ObjectModel.foreignKey.association: '_SourceStructure'
      cast(ursch as fco_ursch preserving type)           as SettlementSourceStructure,
      analg                                              as SettlementIsProportional,
      ersav                                              as SettlementRuleHasUpdateError,
      @ObjectModel.foreignKey.association: '_ControllingSettlementProfile'
      cast(aprof  as fco_aprof preserving type )         as ControllingSettlementProfile,
      abrnr                                              as SettlementSequentialNumber,
      cast(bzdat  as fco_bzdat preserving type)          as AssetValueDate,
      @ObjectModel.foreignKey.association: '_PrftbltyAcctgTransfStructure'
      cast(ersch as fco_ersch preserving type )          as ProfitabilityAcctgTransfStruc,
      letpe                                              as SettlmtRuleLastUsgeFsclPeriod,
      letja                                              as SettlmtRuleLastUsageFiscalYear,
      cast(hienr as fco_brghienr preserving type)        as SettlmtRuleProcessingSequence,
      cast(timestmp as tzntstmpl )                       as SettlementRuleCreationDateTime,
      @ObjectModel.foreignKey.association: '_SettlmtAutomGnrtnStrgySqnc'
      cast(srslist as fco_sr_slist preserving type )     as SettlmtRuleAutoGnrtnStrgySqnc,
      @ObjectModel.foreignKey.association: '_SettlmtWithFreeDfndCurrency'

      cast(addcurr as fco_abr_addcurr preserving type  ) as SettlmtWithFreeDefinedCurrency,
      last_changed_at as LastChangeDateTime,
      
      _CtrlgObjSettlmtDistrRule,
      _ControllingObject,
      _AllocationStructure,
      _CreatedByUser,
      _LastChangedByUser,
      _ControllingSettlementProfile,
      _SettlmtAutomGnrtnStrgySqnc,
      _PrftbltyAcctgTransfStructure,
      _SourceStructure,
      _SettlmtWithFreeDfndCurrency

}