C_MaintOrderOutputParamDetn

@AbapCatalog.sqlViewName: 'CMNTORDPRMDR'
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Maintenance Order Output Management Parameter Determination'

@ObjectModel: {
   compositionRoot: false,
   usageType: {
    serviceQuality:#C,
    sizeCategory: #L,
    dataClass: #TRANSACTIONAL
   }
}

define view C_MaintOrderOutputParamDetn
  as select from I_MaintenanceOrder
  association [0..1] to I_LocationAccountAssignment as _LocationAccountAssignment on $projection.MaintObjectLocAcctAssgmtNmbr = _LocationAccountAssignment.MaintObjectLocAcctAssgmtNmbr
  association [0..1] to I_Equipment                 as _Equipment                 on $projection.Equipment = _Equipment.Equipment
  association [0..1] to E_MaintenanceOrder          as _MaintenanceOrderExtension on $projection.MaintenanceOrder = _MaintenanceOrderExtension.MaintenanceOrder
{

  key MaintenanceOrder,
      MaintenanceOrderType,
      MaintPriority,

      MaintenancePlant,
      MaintenancePlanningPlant,
      MaintenancePlannerGroup,
      _LocationAccountAssignment.PlantSection                                   as PlantSection,
      MainWorkCenter,

      Equipment,
      _Equipment.EquipmentCategory                                              as EquipmentCategory,
      _LocationAccountAssignment.FunctionalLocation                             as FunctionalLocation,
      _LocationAccountAssignment._FunctionalLocation.FunctionalLocationCategory as FunctionalLocationCategory,
      Assembly,
      BusinessArea,

      MaintObjectLocAcctAssgmtNmbr,

      _LocationAccountAssignment.ABCIndicator,
      MaintenanceActivityType,
      cast ( MaintenanceProcessingPhase as eam_opd_ord_status preserving type ) as MaintenanceProcessingPhase,
      MaintOrdProcessPhaseCode,
      MaintOrdProcessSubPhaseCode,

      _Equipment,
      _LocationAccountAssignment

}