I_MaintenanceItemObject

@AbapCatalog.sqlViewName: 'IMTITMOBJ'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: ['_LocationAccountAssignment']
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Maintenance Item Object List'
@ObjectModel: {
    representativeKey: [ 'MaintenanceItemObject' ],
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #B,
        sizeCategory: #XL
    }
}
@VDM.viewType: #BASIC


define view I_MaintenanceItemObject
  as select from objk
  association [0..1] to I_MaintenanceItem           as _MaintenanceItem           on _MaintenanceItem.MaintenanceItemObjectList = $projection.MaintenanceItemObjectList
  association [0..1] to I_LocationAccountAssignment as _LocationAccountAssignment on _LocationAccountAssignment.MaintObjectLocAcctAssgmtNmbr = $projection.MaintObjectLocAcctAssgmtNmbr
  association [0..1] to I_PMNotifMaintenanceData    as _PMNotifMaintenanceData    on _PMNotifMaintenanceData.MaintenanceNotification = $projection.MaintenanceNotification
  association [0..1] to I_MaintenanceNotification   as _MaintenanceNotification   on _MaintenanceNotification.MaintenanceNotification = $projection.MaintenanceNotification
  association [0..1] to I_Equipment                 as _Equipment                 on _Equipment.Equipment = $projection.Equipment
  association [0..1] to I_FunctionalLocation        as _FunctionalLocation        on _FunctionalLocation.FunctionalLocation = $projection.FunctionalLocation
  association [0..1] to I_Material                  as _Assembly                  on _Assembly.Material = $projection.Assembly
  association [0..1] to I_Material                  as _Material                  on _Material.Material = $projection.Material
  association [0..1] to I_Product                   as _Product                   on $projection.Product = _Product.Product
{
  key objk.obknr                                                                                                                       as MaintenanceItemObjectList,

  key objk.obzae                                                                                                                       as MaintenanceItemObject,

      @ObjectModel.foreignKey.association: '_Equipment'
      coalesce( _PMNotifMaintenanceData.Equipment, objk.equnr  )                                                                        as Equipment,

      @ObjectModel.foreignKey.association: '_FunctionalLocation'
      coalesce( _LocationAccountAssignment.FunctionalLocation, _PMNotifMaintenanceData._LocationAccountAssignment.FunctionalLocation ) as FunctionalLocation,

      @Consumption.valueHelpDefinition: [{
        entity: {
            name: 'I_MaterialStdVH',
            element: 'Material'
        }
      }]
      @ObjectModel.foreignKey.association: '_Assembly'
      coalesce( _PMNotifMaintenanceData.Assembly, objk.bautl )                                                                         as Assembly,

      objk.sernr                                                                                                                       as SerialNumber,

      @Consumption.valueHelpDefinition: [{
        entity: {
            name: 'I_MaterialStdVH',
            element: 'Material'
        }
      }]
      @ObjectModel.foreignKey.association: '_Material'
      objk.matnr                                                                                                                       as Material,

      @ObjectModel.foreignKey.association: '_MaintenanceNotification'
      objk.ihnum                                                                                                                       as MaintenanceNotification,

      @ObjectModel.foreignKey.association: '_LocationAccountAssignment'
      objk.iloan                                                                                                                       as MaintObjectLocAcctAssgmtNmbr,

      objk.sortf                                                                                                                       as SortField,

      //needed for BW Extractor

      @UI.hidden: true
      objk.datum                                                                                                                       as CreationDate,

      objk.bearb                                                                                                                       as MaintObjListEntryIsProcessed,
      @ObjectModel.foreignKey.association: '_Product'
      objk.product                                                                                                                     as Product,

      // Associations

      _MaintenanceItem,
      _Assembly,
      _Equipment,
      _FunctionalLocation,
      _LocationAccountAssignment,
      _MaintenanceNotification,
      _Material,
      _Product
}