I_ChmlCmplncInfo

@EndUserText.label: 'Chemical Compliance Information'

@AbapCatalog:
{
  sqlViewName: 'ICCMPLCNINFO',
  compiler.compareFilter: true,
  preserveKey:true
}

@AccessControl:
{
  authorizationCheck: #CHECK,
  privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser' ]
}

@VDM.viewType: #BASIC

@ObjectModel:
{
  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #L,
    serviceQuality: #B
  },
  representativeKey: 'ChmlCmplncInfoUUID'
}

@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_ChmlCmplncInfo
  as select from ehfndv_cci

  association [0..*] to I_ChmlCmplncProdAssgmt      as _ProductAssignment             on  $projection.ChmlCmplncInfoUUID = _ProductAssignment.ChmlCmplncInfoUUID
  association [0..*] to I_ChmlCmplncPrpsAssgmt      as _PurposeAssignment             on  $projection.ChmlCmplncInfoUUID = _PurposeAssignment.ChmlCmplncInfoUUID
  association [0..*] to I_ChmlCmplncMktReq          as _MarketRequest                 on  $projection.ChmlCmplncInfoUUID = _MarketRequest.ChmlCmplncInfoUUID
  association [0..*] to I_ChmlCmplncMktCvrg         as _MarketCoverage                on  $projection.ChmlCmplncInfoUUID = _MarketCoverage.ChmlCmplncInfoUUID
  association [0..*] to I_ChmlCmplncMatlAssgmt      as _MaterialAssignment            on  $projection.ChmlCmplncInfoUUID = _MaterialAssignment.ChmlCmplncInfoUUID
  association [0..*] to I_ChmlCmplncApplAssgmt      as _Application                   on  $projection.ChmlCmplncInfoUUID = _Application.ChmlCmplncInfoUUID
  association [0..*] to I_ChmlCmplncSuplrMatlAssgmt as _SuplrMatlAssignment           on  $projection.ChmlCmplncInfoUUID = _SuplrMatlAssignment.ChmlCmplncInfoUUID
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_ChmlCmplncWasteData       as _WasteData                     on  $projection.ChmlCmplncInfoUUID = _WasteData.ChmlCmplncInfoUUID
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] } */
  association [0..1] to I_ChmlCmplncMatlAssgmt      as _PrimaryMaterial               on  $projection.ChmlCmplncInfoUUID       = _PrimaryMaterial.ChmlCmplncInfoUUID
                                                                                      and _PrimaryMaterial.MatlAssgmtIsPrimary = 'X'
  association [0..1] to I_User                      as _CreatedByUser                 on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                      as _LastChangedByUser             on  $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [1..1] to I_ResponsibleUnit           as _RespUnitForProductStewardship on  $projection.ProdStewardshipRespUnit = _RespUnitForProductStewardship.ResponsibleUnit
  association [1..1] to I_ResponsibleUnitDngrsGds   as _RespUnitForDangerousGoods     on  $projection.DngrsGdsRespUnit = _RespUnitForDangerousGoods.ResponsibleUnit

{
  key chmlcmplncinfouuid                                                      as ChmlCmplncInfoUUID,

      @Semantics.systemDateTime.createdAt: true
      cast(creationutcdatetime as ehfnd_bo_crea_date_time preserving type )   as CreationUTCDateTime,
      @ObjectModel.readOnly: true
      @Semantics.user.createdBy: true
      cast(createdbyuser as ehfnd_bo_crea_uname preserving type )             as CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      cast(lastchangeutcdatetime as ehfnd_bo_lchg_date_time preserving type ) as LastChangeUTCDateTime,
      @ObjectModel.readOnly: true
      @Semantics.user.lastChangedBy: true
      cast(lastchangedbyuser as ehfnd_bo_lchg_uname preserving type )         as LastChangedByUser,

      @ObjectModel.foreignKey.association: '_RespUnitForProductStewardship'
      prodstewardshiprespunit                                                 as ProdStewardshipRespUnit,

      @ObjectModel.foreignKey.association: '_RespUnitForDangerousGoods'
      dngrsgdsrespunit                                                        as DngrsGdsRespUnit,

      chmlcmplncinfotype                                                      as ChmlCmplncInfoType,
      chmlcmplncinternalname                                                  as ChmlCmplncInternalName,
      chmlcmplncprodcatztnphrsuuid                                            as ChmlCmplncProdCatztnPhrsUUID,
      materialisbaseproduct                                                   as MaterialIsBaseProduct,
      materialissold                                                          as MaterialIsSold,
      materialistransported                                                   as MaterialIsTransported,
      materialissourced                                                       as MaterialIsSourced,
      materialisproduced                                                      as MaterialIsProduced,
      materialisdisposed                                                      as MaterialIsDisposed,
      materialisemissionrelevant                                              as MaterialIsEmissionRelevant,
      specification                                                           as Specification,
      specificationinternalid                                                 as SpecificationInternalID,
      chmlcmplncprodisresearched                                              as ChmlCmplncProdIsResearched,
      matlismulticomponentproduct                                             as MatlIsMultiComponentProduct,

      -- indicators to disable essential checks
      matlisnotdngrsgdsrlvt                                                   as MatlIsNotDngrsGdsRlvt,
      matlisnotprodmarketabilityrlvt                                          as MatlIsNotProdMarketabilityRlvt,
      matlisnotprodsafetyrlvt                                                 as MatlIsNotProdSafetyRlvt,
      matlisnotsupplierrlvt                                                   as MatlIsNotSupplierRlvt,
      
      -- associations
      _ProductAssignment,
      _PurposeAssignment,
      _MarketRequest,
      _MarketCoverage,
      _MaterialAssignment,
      _PrimaryMaterial,
      _Application,
      _SuplrMatlAssignment,
      _WasteData,
      _CreatedByUser,
      _LastChangedByUser,
      _RespUnitForProductStewardship,
      _RespUnitForDangerousGoods
}