C_ChmlCmplncPrimMatl

@EndUserText.label: 'Chemical Compliance Primary Material'

@AbapCatalog:
{
  sqlViewName: 'CCCMATLPRIM',
  compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #MANDATORY,
  // blocking of personal data not required (no personal data fields exposed for material)

  personalData.blocking: #NOT_REQUIRED
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #COMPOSITE

@ObjectModel:
{
  semanticKey:  [ 'Material' ],
  representativeKey: 'ChmlCmplncInfoUUID',
  usageType:
  {
    dataClass: #MIXED,
    sizeCategory: #L,
    serviceQuality: #C
  }

}
@Analytics:{
    dataCategory: #DIMENSION
}
@Metadata.allowExtensions:true
define view C_ChmlCmplncPrimMatl
  --Select data from master table 'Chemical Compliance Info'
  as select from           I_ChmlCmplncInfo             as ChemicalComplianceInfo

  --Is Researched DTEL Text
    left outer to one join I_ChmlCmplncIsResearchedText as ProdIsResearchedText on ProdIsResearchedText.Language = $session.system_language

  --Join data from primary material assignment
    left outer to one join I_ChmlCmplncMatlAssgmt       as PrimaryMaterial      on  ChemicalComplianceInfo.ChmlCmplncInfoUUID = PrimaryMaterial.ChmlCmplncInfoUUID
                                                                                and PrimaryMaterial.MatlAssgmtIsPrimary       = 'X'
  --Join data from product name
    left outer to one join I_ProductText                as MaterialData         on  PrimaryMaterial.Material = MaterialData.Product
                                                                                and MaterialData.Language    = $session.system_language

  association [1..1] to I_ChmlCmplncInfo as _ChmlCmplncInfo on _ChmlCmplncInfo.ChmlCmplncInfoUUID = $projection.ChmlCmplncInfoUUID


  -- provide additional product data via exposed association
  association [1..1] to I_Product        as _MaterialData   on PrimaryMaterial.Material = _MaterialData.Product
{
      --UUID of Chemical Compliance Info
      @ObjectModel.text.element: [ 'ChmlCmplncInfoCombinedName' ]
  key ChemicalComplianceInfo.ChmlCmplncInfoUUID,

      --Material
      PrimaryMaterial.Material                                                   as Material,

      --Material Name
      MaterialData.ProductName                                                   as MaterialName,

      case ChmlCmplncProdIsResearched
        when 'X' then
           cast(
             concat_with_space( concat_with_space( coalesce( MaterialData.ProductName, ChemicalComplianceInfo.ChmlCmplncInternalName ), '-', 2 ),
                                ProdIsResearchedText.ChmlCmplncRnDSampleText, 2 )
           as ehfnd_cci_product_name )
        when '' then
          cast( coalesce( MaterialData.ProductName, ChemicalComplianceInfo.ChmlCmplncInternalName ) as ehfnd_cci_product_name )
      end                                                                        as ChmlCmplncInfoCombinedName,

      -- Needed in PCE monitor app like Initiating object ID
      coalesce( PrimaryMaterial.Material, ChemicalComplianceInfo.Specification ) as ChmlCmplncInfoCombinedID,


      ChemicalComplianceInfo.ChmlCmplncInfoType,

      ChemicalComplianceInfo.ChmlCmplncInternalName,

      --Roles and Responsible Unit for DCL
      MaterialIsProduced,
      MaterialIsSold,
      MaterialIsSourced,
      MaterialIsTransported,
      MaterialIsDisposed,
      MaterialIsEmissionRelevant,

      ProdStewardshipRespUnit,

      /* Associations */
      _ChmlCmplncInfo,
      _MaterialData
}