C_EnvrmtWastePartMatlParamVH

@EndUserText.label: 'Waste Partner Material Asgmt VH'

@AbapCatalog:
{
 sqlViewName: 'CEWSTPRTMATPRMVH',
 compiler.compareFilter: true,
 preserveKey: true
}

@Metadata: {
  allowExtensions: true
}

@AccessControl:
{
  authorizationCheck: #MANDATORY,
  personalData.blocking: #REQUIRED
}

@VDM.viewType: #CONSUMPTION

@ObjectModel:
{
  representativeKey: 'ChmlCmplncInfoUUID',

  dataCategory: #VALUE_HELP,
  usageType:
  {
    dataClass: #MIXED,
    sizeCategory: #L,
    serviceQuality: #C
  }
}

@Metadata.ignorePropagatedAnnotations: true

@Search.searchable : true

@ClientHandling.algorithm: #SESSION_VARIABLE

define view C_EnvrmtWastePartMatlParamVH
  with parameters
    P_EnvrmtWastePartnerUUID : sysuuid_x

  as select from           I_ChmlCmplncInfo       as _ChmlCmplncInfo

  --Join data from primary material assignment
    left outer to one join I_ChmlCmplncMatlAssgmt as PrimaryMaterial on  _ChmlCmplncInfo.ChmlCmplncInfoUUID  = PrimaryMaterial.ChmlCmplncInfoUUID
                                                                     and PrimaryMaterial.MatlAssgmtIsPrimary = 'X'
  --Join data from from primary material
    left outer to one join I_Product              as MaterialData    on PrimaryMaterial.Material = MaterialData.Product

  //  --Join data with draft Env Waste Partner root

  //    inner join              I_EnvrmtWastePartnerDraft  as _WastePartnerDraft     on _WastePartnerDraft.EnvrmtWastePartnerUUID = $parameters.P_EnvrmtWastePartnerUUID


  //  --Join data of draft Waste Partner Matl Assgmt that are already assigned

  //    left outer to many join I_EnvrmtWastePartMatlDraft as _WastePartnerMatlDraft on  _WastePartnerMatlDraft.ChmlCmplncInfoUUID     = _ChmlCmplncInfo.ChmlCmplncInfoUUID

  //                                                                                 and _WastePartnerMatlDraft.EnvrmtWastePartnerUUID = $parameters.P_EnvrmtWastePartnerUUID


{
      @UI.hidden: true
  key $parameters.P_EnvrmtWastePartnerUUID                                    as EnvrmtWastePartnerUUID,

      @UI.hidden: true
  key _ChmlCmplncInfo.ChmlCmplncInfoUUID,

      @Search:
      {
         defaultSearchElement: true,
         fuzzinessThreshold: 1,
         ranking: #HIGH
      }
      @UI.lineItem: [{ position: 10 }]
      @EndUserText.label: 'Internal Name'
      @Semantics.text: true
      _ChmlCmplncInfo.ChmlCmplncInternalName,

      @UI.lineItem: [{ position: 20 }]
      PrimaryMaterial.MatlAssgmtIsPrimary                                     as MatlAssgmtIsPrimary,

      @Search:
      {
         defaultSearchElement: true,
         fuzzinessThreshold: 1,
         ranking: #MEDIUM
      }
      @UI.lineItem: [{ position: 30 }]
      @EndUserText.label: 'Product'
      @EndUserText.quickInfo: 'Product'
      PrimaryMaterial.Material,

      @UI.lineItem: [{ position: 40 }]
      @EndUserText.label: 'Product Description'
      @EndUserText.quickInfo: 'Product Description'
      MaterialData._Text[1: Language = $session.system_language ].ProductName as ProductName,

      @UI.lineItem: [{ position: 50 }]
      @EndUserText.label: 'Waste Codes'
      @ObjectModel:{ readOnly: true,
                     virtualElement: true,
                     virtualElementCalculatedBy: 'CL_EHEWA_CALC_EXIT_WASTECODE'}
      cast('' as abap.sstring(1000))                                          as EnvrmtWasteCodeString,

      @UI.hidden: true
      _ChmlCmplncInfo.MaterialIsDisposed,

      @UI.hidden: true
      _ChmlCmplncInfo.ProdStewardshipRespUnit,

      @EndUserText.label: 'Packaged Material'
      @EndUserText.quickInfo: 'Packaged Material'
      @UI.lineItem: [{ position: 60 }]
      cast( case
      when _ChmlCmplncInfo.ChmlCmplncInfoType = 'PP'
      then 'X'
      else ' ' end as ehfnd_boolean preserving type)                          as ProductIsPackaged

}
where
  (
       _ChmlCmplncInfo.ChmlCmplncInfoType = 'BU'
    or _ChmlCmplncInfo.ChmlCmplncInfoType = 'PP'
  )
  and  _ChmlCmplncInfo.MaterialIsDisposed = 'X'
//  and _WastePartnerMatlDraft.EnvrmtWastePartnerUUID is null