I_ChmlCmplncMktReq

@EndUserText.label: 'Chemical Compliance Market Request'

@AbapCatalog:
{
  sqlViewName: 'ICCMKTREQ',
  compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #CHECK,
  privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser' ]
}

@VDM.viewType: #BASIC

@ObjectModel:
{
  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #L,
    serviceQuality: #B
  }
}

@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_ChmlCmplncMktReq
  as select from ehfndv_cci_mreq
  association [1..1] to I_ChmlCmplncInfo      as _ChmlCmplncInfo    on _ChmlCmplncInfo.ChmlCmplncInfoUUID = $projection.ChmlCmplncInfoUUID
  association [0..1] to I_User                as _CreatedByUser     on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                as _LastChangedByUser on $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [1..1] to I_Country             as _Country           on $projection.Country = _Country.Country
  association [1..1] to I_ChmlCmplncMktReqSts as _ReqStsProdn       on $projection.ChmlCmplncProdnIsReqd = _ReqStsProdn.ChmlCmplncReqStatus
  association [1..1] to I_ChmlCmplncMktReqSts as _ReqStsExprt       on $projection.ChmlCmplncExprtIsReqd = _ReqStsExprt.ChmlCmplncReqStatus
  association [1..1] to I_ChmlCmplncMktReqSts as _ReqStsImprt       on $projection.ChmlCmplncImprtIsReqd = _ReqStsImprt.ChmlCmplncReqStatus
  association [1..1] to I_ChmlCmplncMktReqSts as _ReqStsSales       on $projection.ChmlCmplncSalesIsReqd = _ReqStsSales.ChmlCmplncReqStatus

{
  key chmlcmplncmktrequuid                                                    as ChmlCmplncMktReqUUID,
      chmlcmplncinfouuid                                                      as ChmlCmplncInfoUUID,

      @Semantics.systemDateTime.createdAt: true
      cast(creationutcdatetime as ehfnd_bo_crea_date_time preserving type )   as CreationUTCDateTime,
      @Semantics.user.createdBy: true
      cast(createdbyuser as ehfnd_bo_crea_uname preserving type )             as CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      cast(lastchangeutcdatetime as ehfnd_bo_lchg_date_time preserving type ) as LastChangeUTCDateTime,
      @Semantics.user.lastChangedBy: true
      cast(lastchangedbyuser as ehfnd_bo_lchg_uname preserving type )         as LastChangedByUser,

      @ObjectModel.foreignKey.association: '_Country'
      cast (country as ehfnd_cntr_code)                                       as Country,
      @ObjectModel.foreignKey.association: '_ReqStsProdn'
      chmlcmplncprodnisreqd                                                   as ChmlCmplncProdnIsReqd,
      @ObjectModel.foreignKey.association: '_ReqStsExprt'
      chmlcmplncexprtisreqd                                                   as ChmlCmplncExprtIsReqd,
      @ObjectModel.foreignKey.association: '_ReqStsImprt'
      chmlcmplncimprtisreqd                                                   as ChmlCmplncImprtIsReqd,
      @ObjectModel.foreignKey.association: '_ReqStsSales'
      chmlcmplncsalesisreqd                                                   as ChmlCmplncSalesIsReqd,


      -- associations
      _ChmlCmplncInfo,
      _CreatedByUser,
      _LastChangedByUser,
      _Country,
      _ReqStsProdn,
      _ReqStsExprt,
      _ReqStsImprt,
      _ReqStsSales
}