C_EnvrmtWastePartDsplMatlVH

DDL: C_ENVRMTWASTEPARTDSPLMATLVH Type: view CONSUMPTION Package: EHEWA_CNS_ENV_WASTEPARTNER

Waste Partner Disposal MaterialVH

C_EnvrmtWastePartDsplMatlVH is a Consumption CDS View that provides data about "Waste Partner Disposal MaterialVH" in SAP S/4HANA. It reads from 1 data source (I_ChmlCmplncInfo) and exposes 9 fields with key field ChmlCmplncInfoUUID. Part of development package EHEWA_CNS_ENV_WASTEPARTNER.

1 data source(s) 9 fields

Data Sources (1)

SourceAliasJoin Type
I_ChmlCmplncInfo _ChmlCmplncInfo from

Annotations (16)

NameValueLevelField
EndUserText.label Waste Partner Disposal MaterialVH view
AbapCatalog.sqlViewName CEWSTDSPMATVH view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
Metadata.allowExtensions true view
AccessControl.authorizationCheck #MANDATORY view
AccessControl.personalData.blocking #REQUIRED view
VDM.viewType #CONSUMPTION view
ObjectModel.representativeKey ChmlCmplncInfoUUID view
ObjectModel.dataCategory #VALUE_HELP view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.serviceQuality #C view
Metadata.ignorePropagatedAnnotations true view
Search.searchable true view
ClientHandling.algorithm #SESSION_VARIABLE view

Fields (9)

KeyFieldSource TableSource FieldDescription
KEY ChmlCmplncInfoUUID I_ChmlCmplncInfo ChmlCmplncInfoUUID
ChmlCmplncMatlAssgmtUUID PrimaryMaterial ChmlCmplncMatlAssgmtUUID
ChmlCmplncInternalName I_ChmlCmplncInfo ChmlCmplncInternalName Internal Name
MatlAssgmtIsPrimary PrimaryMaterial MatlAssgmtIsPrimary
Material PrimaryMaterial Material Material Number
ProductName Material Name
EnvrmtWasteCodeString Waste Codes
MaterialIsDisposed I_ChmlCmplncInfo MaterialIsDisposed
ProdStewardshipRespUnit I_ChmlCmplncInfo ProdStewardshipRespUnit 
@EndUserText.label: 'Waste Partner Disposal MaterialVH'

@AbapCatalog:
{
 sqlViewName: 'CEWSTDSPMATVH',
 compiler.compareFilter: true,
 preserveKey: true
}

@Metadata: {
  allowExtensions: true
}

@AccessControl:
{
  authorizationCheck: #MANDATORY,
  personalData.blocking: #REQUIRED
}

@VDM.viewType: #CONSUMPTION

@ObjectModel:
{
  representativeKey: 'ChmlCmplncInfoUUID',
  semanticKey: ['ChmlCmplncInternalName'],
  dataCategory: #VALUE_HELP,
  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #L,
    serviceQuality: #C
  }
}

@Metadata.ignorePropagatedAnnotations: true

@Search.searchable : true

@ClientHandling.algorithm: #SESSION_VARIABLE

define view C_EnvrmtWastePartDsplMatlVH
  //  as select from I_ChmlCmplncInfoVH

  as select from           I_ChmlCmplncInfo       as _ChmlCmplncInfo
  --Join data from primary material assignment
    left outer to one join I_ChmlCmplncMatlAssgmt as PrimaryMaterial on  _ChmlCmplncInfo.ChmlCmplncInfoUUID  = PrimaryMaterial.ChmlCmplncInfoUUID
                                                                     and PrimaryMaterial.MatlAssgmtIsPrimary = 'X'
  --Join data from from primary material
    left outer to one join I_Product              as MaterialData    on PrimaryMaterial.Material = MaterialData.Product

{

        @UI.hidden: true
  key   _ChmlCmplncInfo.ChmlCmplncInfoUUID,

        @UI.hidden: true
        PrimaryMaterial.ChmlCmplncMatlAssgmtUUID,

        @Search:
        {
           defaultSearchElement: true,
           fuzzinessThreshold: 1,
           ranking: #HIGH
        }
        @UI.lineItem: [{ position: 10 }]
        @EndUserText.label: 'Internal Name'
        @Semantics.text: true
        _ChmlCmplncInfo.ChmlCmplncInternalName,

        @UI.lineItem: [{ position: 20 }]
        PrimaryMaterial.MatlAssgmtIsPrimary                                     as MatlAssgmtIsPrimary,

        @Search:
        {
           defaultSearchElement: true,
           fuzzinessThreshold: 1,
           ranking: #MEDIUM
        }
        @UI.lineItem: [{ position: 30 }]
        @EndUserText.label: 'Material Number'
        PrimaryMaterial.Material,

        @UI.lineItem: [{ position: 40 }]
        @EndUserText.label: 'Material Name'
        MaterialData._Text[1: Language = $session.system_language ].ProductName as ProductName,

        @UI.lineItem: [{ position: 50 }]
        @EndUserText.label: 'Waste Codes'
        @ObjectModel:{ readOnly: true,
                       virtualElement: true,
                       virtualElementCalculatedBy: 'CL_EHEWA_CALC_EXIT_WASTECODE'}
        cast('' as abap.sstring(1000))                                          as EnvrmtWasteCodeString,

        @UI.hidden: true
        _ChmlCmplncInfo.MaterialIsDisposed,

        @UI.hidden: true
        _ChmlCmplncInfo.ProdStewardshipRespUnit

}
where
  (
       _ChmlCmplncInfo.ChmlCmplncInfoType = 'BU'
    or _ChmlCmplncInfo.ChmlCmplncInfoType = 'PP'
  )
  and  _ChmlCmplncInfo.MaterialIsDisposed = 'X'

Learn More