I_ChmlCmplncApplAssgmt

@EndUserText.label: 'Chemical Compliance Application Assignment'

@AbapCatalog:
{
  sqlViewName: 'ICCAPPLASSGMT',
  compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #CHECK
}

@VDM.viewType: #BASIC

@ObjectModel:
{
  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #L,
    serviceQuality: #B
  }
}

@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_ChmlCmplncApplAssgmt
  as select from ehfndv_cci_appl
  association [1..1] to I_ChmlCmplncInfo        as _ChmlCmplncInfo on $projection.ChmlCmplncInfoUUID = _ChmlCmplncInfo.ChmlCmplncInfoUUID
  association [1..1] to I_ChmlCmplncApplication as _Application    on $projection.ChmlCmplncApplication = _Application.ChmlCmplncApplication

{

  key chmlcmplncappluuid                                                            as ChmlCmplncApplUUID,
      chmlcmplncinfouuid                                                            as ChmlCmplncInfoUUID,

      @Semantics.systemDateTime.createdAt: true
      cast(creationutcdatetime as ehfnd_bo_crea_date_time preserving type )         as CreationUTCDateTime,
      @Semantics.user.createdBy: true
      cast(createdbyuser as ehfnd_bo_crea_uname preserving type )                   as CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      cast(lastchangeutcdatetime as ehfnd_bo_lchg_date_time preserving type )       as LastChangeUTCDateTime,
      @Semantics.user.lastChangedBy: true
      cast(lastchangedbyuser as ehfnd_bo_lchg_uname preserving type )               as LastChangedByUser,

      @ObjectModel.foreignKey.association: '_Application'
      cast(chmlcmplncapplication as ehfnd_cci_application_nce preserving type )     as ChmlCmplncApplication,

      _ChmlCmplncInfo,
      _Application

}