C_ChmlCmplncInfoWorkView

@AbapCatalog: {
  sqlViewName: 'CCCIWV',
  compiler.compareFilter: true
}

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED

@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
  usageType:  {
    dataClass: #MIXED,
    sizeCategory: #L,
    serviceQuality: #C
  }
}

@EndUserText.label: 'Chemical Compliance Info Work Perspective'
@Search.searchable: true
@Metadata.allowExtensions: true

@UI.presentationVariant: [{requestAtLeast: [
      'AnalyticCmpstnNavgnLinkUUID',
      'AnalyticCmpstnIsActive',
      'ChmlCmplncInfoNavgnLink'
]
}]


define view C_ChmlCmplncInfoWorkView

  as select from I_ChmlCmplncInfo
  
  association [0..*] to C_WorkViewCmplncData           as _WorkViewCmplncData        on $projection.ChmlCmplncInfoUUID = _WorkViewCmplncData.ChmlCmplncInfoUUID
                                                                                       
  -- Material Data for Primary Material
  association [0..1] to C_ChmlCmplncPrimMatl           as _MaterialDataPrimary       on _MaterialDataPrimary.ChmlCmplncInfoUUID = $projection.ChmlCmplncInfoUUID


  -- Compositions
  association [0..*] to C_AssociatedProductComposition as _Composition               on _Composition.ChmlCmplncInfoUUID = $projection.ChmlCmplncInfoUUID
  association [0..1] to P_AssociatedAnlytlCmpstnProd   as _AnlytlCmpstn              on $projection.ChmlCmplncInfoUUID = _AnlytlCmpstn.ChmlCmplncInfoUUID
  association [0..1] to P_AssociatedMatlCmpstnProd     as _MatlBsdCmpstn             on $projection.ChmlCmplncInfoUUID = _MatlBsdCmpstn.ChmlCmplncInfoUUID

  -- Properties
  association [0..*] to C_ChmlCmplncInfoAssgdPCPrpty   as _Properties                on _Properties.ChmlCmplncInfoUUID = $projection.ChmlCmplncInfoUUID
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] } */
  association [0..1] to P_ChmlCmplncInfoAssgdPCSfty    as _ChmlCmplncInfoAssgdPCSfty on $projection.ChmlCmplncInfoUUID = _ChmlCmplncInfoAssgdPCSfty.ChmlCmplncInfoUUID

  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] } */
  association [0..1] to P_ChmlCmplncInfoAssgdPCEctx    as _ChmlCmplncInfoAssgdPCEctx on $projection.ChmlCmplncInfoUUID = _ChmlCmplncInfoAssgdPCEctx.ChmlCmplncInfoUUID

  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] } */
  association [0..1] to P_ChmlCmplncInfoAssgdPCPhys    as _ChmlCmplncInfoAssgdPCPhys on $projection.ChmlCmplncInfoUUID = _ChmlCmplncInfoAssgdPCPhys.ChmlCmplncInfoUUID

  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] } */
  association [0..1] to P_ChmlCmplncInfoAssgdPCTx      as _ChmlCmplncInfoAssgdPCTx   on $projection.ChmlCmplncInfoUUID = _ChmlCmplncInfoAssgdPCTx.ChmlCmplncInfoUUID

{
  key ChmlCmplncInfoUUID,

      // Field "ChmlCmplncInfoNavgnLink" is required for some of the "CCI"-related navigation links

      // of the "Logistics Roles" smart link to be visible, because it is defined as a parameter in

      // the respective target mappings (e.g. "UnpackagedChemicalInfo-manageBasicData" defined in

      // technical catalog "SAP_TC_PSS_MA_APPS")

      @ObjectModel.readOnly: true
      ChmlCmplncInfoUUID                                                                                                             as ChmlCmplncInfoNavgnLink,

      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
      ChmlCmplncInternalName,
      ProdStewardshipRespUnit,
      //      _WorkViewCmplncData.ComplianceRequirement,


      --Primary Material of Chemical Compliance Information (assigned in material assignment)
      @ObjectModel.readOnly: true
      _MaterialDataPrimary.Material,

      --Material Group of Primary Material
      @ObjectModel:
      {
        readOnly: true,
        text.element:  [ 'MaterialGroupName' ]
      }
      _MaterialDataPrimary._MaterialData.ProductGroup                                                                                as MaterialGroup,

      --Name of Chemical Compliance Information (either material name of primary material or internal name)
      @ObjectModel.readOnly: true
      _MaterialDataPrimary.ChmlCmplncInfoCombinedName,

      --Description of Material Group
      @ObjectModel.readOnly: true
      @Semantics.text: true
      _MaterialDataPrimary._MaterialData._ProductGroup_2._ProductGroupText[1: Language = $session.system_language ].ProductGroupName as MaterialGroupName,

      --Specification with intent-based navigation
      @ObjectModel.readOnly: true
      Specification,


      -- Chemical Compliance Information --
      @ObjectModel.readOnly: true
      ChmlCmplncInfoType,
      @ObjectModel.readOnly: true
      ChmlCmplncProdIsResearched,
      @ObjectModel.readOnly: true
      MaterialIsSold,
      @ObjectModel.readOnly: true
      MaterialIsTransported,
      @ObjectModel.readOnly: true
      MaterialIsSourced,
      @ObjectModel.readOnly: true
      MaterialIsProduced,
      @ObjectModel.readOnly: true
      MaterialIsEmissionRelevant,      
      -- needed for Navigation to the CCI manage basic data app
      //@ObjectModel.readOnly: true

      //ChmlCmplncInfoUUID                     as ChmlCmplncInfoNavgnLink,


      -------------------------------------------------------------------------------------------------------
      /*Navigation Links: PhysChem, EcoTox, SafetyRelated*/
      -------------------------------------------------------------------------------------------------------
      // UUID for Navigation into PhysChem Property

      @ObjectModel.readOnly: true
      _ChmlCmplncInfoAssgdPCPhys.PCPrptyNavgnLinkUUID                                                                                as PCPhysPrptyNavgnLinkUUID,

      // Active Indicator of Phys-Chem Property (needed for navigation)

      @ObjectModel.readOnly: true
      _ChmlCmplncInfoAssgdPCPhys.PCPrptyIsActive                                                                                     as PCPhysPrptyIsActive,

      // UUID for Navigation into PhysChem Property

      @ObjectModel.readOnly: true
      _ChmlCmplncInfoAssgdPCEctx.PCPrptyNavgnLinkUUID                                                                                as PCEctxPrptyNavgnLinkUUID,

      // Active Indicator of Phys-Chem Property (needed for navigation)

      @ObjectModel.readOnly: true
      _ChmlCmplncInfoAssgdPCEctx.PCPrptyIsActive                                                                                     as PCEctxPrptyIsActive,

      // UUID for Navigation into PhysChem Property

      @ObjectModel.readOnly: true
      _ChmlCmplncInfoAssgdPCSfty.PCPrptyNavgnLinkUUID                                                                                as PCSftyPrptyNavgnLinkUUID,

      // Active Indicator of Phys-Chem Property (needed for navigation)

      @ObjectModel.readOnly: true
      _ChmlCmplncInfoAssgdPCSfty.PCPrptyIsActive                                                                                     as PCSftyPrptyIsActive,

      // UUID for Navigation into PhysChem Property

      @ObjectModel.readOnly: true
      _ChmlCmplncInfoAssgdPCTx.PCPrptyNavgnLinkUUID                                                                                  as PCPrptyNavgnLinkUUID,

      // Active Indicator of Phys-Chem Property (needed for navigation)

      @ObjectModel.readOnly: true
      _ChmlCmplncInfoAssgdPCTx.PCPrptyIsActive                                                                                       as PCPrptyIsActive,

      -------------------------------------------------------------------------------------------------------
      /*Navigation Links: Composition*/
      -------------------------------------------------------------------------------------------------------

      // UUID for Navigation into Analytical Composition

      @ObjectModel.readOnly: true
      _AnlytlCmpstn.ChmlCmpstnNavgnLinkUUID                                                                                          as AnalyticCmpstnNavgnLinkUUID,

      // Active Indicator of Analytical Composition (needed for navigation)

      @ObjectModel.readOnly: true
      _AnlytlCmpstn.ChmlCmpstnIsActive                                                                                               as AnalyticCmpstnIsActive,

      // UUID for Navigation into Material Based Composition

      @ObjectModel.readOnly: true
      _MatlBsdCmpstn.ChmlCmpstnNavgnLinkUUID                                                                                         as MatlBsdCmpstnNavgnLinkUUID,

      // Active Indicator of Material Based Composition (needed for navigation)

      @ObjectModel.readOnly: true
      _MatlBsdCmpstn.ChmlCmpstnIsActive                                                                                              as MatlBsdCmpstnIsActive,

      _WorkViewCmplncData
}

where
         ChmlCmplncInfoType      = 'BU'
  and( 
         //Up product

         (
           MaterialIsSold        = 'X'
           or MaterialIsProduced = 'X'
         )
    //Raw material

    or  MaterialIsSourced       = 'X'
    or  MaterialIsEmissionRelevant = 'X' 
    
  )